Программно закрыть окно блокнота

[Crivel]

Здравствуйте! Я новичок в asm. Пишу на FASM. Решил в познавательных целях написать программу, которая будет закрывать окно блокнота. Код скомпилировался, но когда запускаю программу, то выходит что программа перестала работать и не отвечает.
Вот код:

format PE GUI 4.0

include 'INCLUDE\win32a.inc'

notepad db 'notepad'

invoke FindWindow,notepad,0
invoke SendMessage,FindWindow,$0010,0,0
invoke ExitProcess,0


data import

  library kernel32,'KERNEL32.DLL',\
         user32,'USER32.DLL'

 import kernel32,\
        ExitProcess,'ExitProcess'

 import user32,\
        FindWindow,'FindWindowA',\
        SendMessage,'SendMessageA'

end data

Как я уже писал - я новичок в asm. И вероятно где-то допустил ошибку в коде. Помогите пожалуйста найти ошибку. Я вообще программирую на Дельфи, но решил изучать asm.
Заранее благодарен.

[Stilet]

Как минимум:

invoke SendMessage,eax,$0010,0,0

[Crivel]

Stilet, спасибо, но всё равно не пашет.

[JTG]

Ужас

format PE GUI 4.0

include 'INCLUDE\win32a.inc'

; Выполнение программы начинается отсюда
; db 'notepad' будет исполнен как код 6E 6F 74 65 70 61 64
; 6E = OUTS DX,[BYTE ES:EDI]                                 
; первая же команда завалит программу

; Строки заканчиваются нулями
notepad db 'notepad'

invoke FindWindow,notepad,0
; Это вообще бред
invoke SendMessage,FindWindow,$0010,0,0
invoke ExitProcess,0

data import

  library kernel32,'KERNEL32.DLL',\
         user32,'USER32.DLL'

 import kernel32,\
        ExitProcess,'ExitProcess'

 import user32,\
        FindWindow,'FindWindowA',\
        SendMessage,'SendMessageA'

end data

Явно обьявляй секции, иначе фасм засунет всё в одну. Работать будет, но бывают исключения.

format PE GUI 4.0
entry start
include 'INCLUDE\win32a.inc'

section '.data' data readable writable

        notepad db 'notepad', 0

section '.code' code readable executable

start:
        invoke FindWindow, notepad, 0
        invoke SendMessage, eax, WM_CLOSE, 0, 0
        invoke ExitProcess, 0

section '.idata' import data readable   

        library kernel32,'KERNEL32.DLL',\
                 user32,'USER32.DLL'

        import kernel32,\
                 ExitProcess,'ExitProcess'

        import user32,\
                 FindWindow,'FindWindowA',\
                 SendMessage,'SendMessageA'

Есть ещё упрощённый синтаксис "на макросах", для этого надо подключить win32ax.inc. Удобно, но могут быть сложности с импортами.

format PE GUI 4.0
include 'win32ax.inc' 

.data  
        notepad db 'notepad', 0

.code
        start:
        invoke FindWindow, notepad, 0
        invoke SendMessage, eax, WM_CLOSE, 0, 0
        invoke ExitProcess, 0
.end start

Если подключить win32axp.inc, то фасм будет ещё и проверять количество параметров в функциях.
Вот это "import user32, FindWindow,'FindWindowA', SendMessage,'SendMessageA'" можно заменять на include 'api/user32.inc', 'api/kernel32.inc' и т.п.

И отступ в 8 пробелов - это святое

[Crivel]

Большое спасибо JTG! Всё работает!