повторяющиеся значения в combobox

[ondar]

Заполняю таблицу в Excel при помощи VBA-приложения.
Из textbox-a и combobox-а данные нормально заносятся в таблицу на первом листе.
Не могу исключить повторяющиеся значения в combobox-е!!!
Значения я получаю из столбца второго листа.
Я, вообще-то, с VBA никак не встречался до вчерашнего дня.
И программирую на других языках - pascal/delphi, с++, php.

[VictorM]

Посмотрите здесь:
Как удалить все повторяющиеся элементы списка ListBox, ComboBox ?

[ondar]

ладно, разберёмся!
Но вопрос пока не закрыт.
Ведь интересно же, как другие люди находят решение.

[VictorM]

Так вот так и находят))

Для того, чтобы удалить все повторяющиеся элементы списка и в результате получить список, содержащий только уникальные значения, достаточно воспользоваться процедурой UniqueItems

Private Sub UniqueItems()
    With Me.ComboBox1 'ListBox1
         iMassiv = .List
         For iCount& = .ListCount - 1 To 0 Step -1
             If iCount& <> Application.Match(iMassiv( _
             iCount&, 0), iMassiv, 0) - 1 Then .RemoveItem iCount&
         Next
    End With
End Sub

Комментарий : Подобный подход применим только к тем элементам управления (ComboBox/ListBox), которые заполнялись с помощью свойства List или Column

[R Dmitry]

посмотрите это подойдет
' ZVI:2009-10-17 http://www.planetaexcel.ru/forum.php?thread_id=10602
' Функция возвращает одномерный массив уникальных отсортированных значений диапазона Rng
Function NoDups(Rng As Range)
Dim Arr(), i&, s$, x
' Считать данные в массив, для удобства ограничиться последней строкой данных листа
Arr = Intersect(Rng.Parent.UsedRange, Rng).Value
' Создать список
On Error Resume Next
With New Collection
For Each x In Arr()
s = Trim(x)
If Len(s) > 0 Then
If IsEmpty(.Item(s)) Then
' Оригинальный достаточно быстрый вариант добавления значения в коллекцию с сортировкой (from PGC01)
For i = 1 To .Count
If s < .Item(i) Then Exit For
Next
If i > .Count Then .Add s, s Else .Add s, s, Before:=i
End If
End If
Next
' Скопировать из коллекции в массив
ReDim Arr(1 To .Count)
For i = 1 To .Count
Arr(i) = .Item(i)
Next
End With
' Вернуть массив
NoDups = Arr()
End Function
Sub nodups_next()
Dim Rng As Range
Set Rng = Sheet1.Columns(1) ' <- чтобы не париться, можно задать весь столбец, NoDups ограничит его по UsedRange
ListBox1.List = NoDups(Rng)
ComboBox1.List = ListBox1.List ' или ComboBox1.List = NoDups(Rng)
Label1.Caption = "Всего элементов: " & WorksheetFunction.CountA(Rng)
Label2.Caption = "Уникальных элементов: " & ListBox1.ListCount
End Sub

[ondar]

Спасибо за информацию!
Вроде разобрался.