Как избавиться от (Error 91)

[r0tten]

Итак задача(необходимо выполнить в VBA):
Нужно в Excel-файле найти на 1-ом Листе, значение формата: "################" (16 цифр).
Затем в строке где оно присутствует найти: "*##.##" либо "*##,##"
И записать эти значения в текстовый файл.

Вот что написал я:

Sub ExcelObrab(PathFile, PathDir) 'PathFile и PathDir пути к Excel-документу и к папке содержащую этот файл
    Dim oExcel As New Excel.Application
    Dim oWbk As Workbook
    Dim c As Range
    Dim c2 As Range
    Dim cForFind As Range
    Dim c2ForFind As Range
    Dim FN As Integer
    Dim Text As String
    Dim Text2 As String
    FN = FreeFile
    Open PathDir & "\outputfile.txt" For Output As FN
    
    Set oWbk = Workbooks.Open(PathFile)
    Set cForFind = Worksheets(1).Cells
    Set c2ForFind = Worksheets(1).Rows
    With cForFind
       Set c = .Find("????????????????", LookIn:=xlValues, LookAt:=xlWhole) ' поиск 1-го значения
       If Not c Is Nothing Then
        firstAddress = c.Address
        c2ForFind = c.Row
        Do
            With c2ForFind 'поиск 2-го значения
                Set c2 = .Find("??.??", LookIn:=xlValues, LookAt:=xlPart)
                If Not c2 Is Nothing Then
                    Text = c
                    Text2 = c2
                    Print #1, Text & "    " & Text2 'запись в файл
                Else
                    Set c2 = .Find("??,??", LookIn:=xlValues, LookAt:=xlPart)
                    If Not c2 Is Nothing Then
                        Text = c
                        Text2 = c2
                        Print #1, Text & "    " & Text2 'запись в файл
                    End If
                End If
            End With
            Set c = .FindNext(c)
        Loop While (Not c Is Nothing) And (c.Address <> firstAddress) 'здесь выскакивает ошибка 
        
       End If
    End With
    ActiveWorkbook.Close
    Excel.Application.Quit
    Close FN
End Sub

Выскакивает ошибка Object variable or With block variable not set (Error 91) в выделенной строчке.

[Xpoft]

Set c = .Find("????????????????", LookIn:=xlValues, LookAt:=xlWhole) ' поиск 1-го значения
По моему если у вас ничего не нашлось то с is nothing и проблема возникает вот с этим:
c.Address <> firstAddress , c.Address не понятно что такое вот и ошибка

[The_Prist]

Изначальная причина ошибки здесь

Set c2 = .Find("??,??", LookIn:=xlValues, LookAt:=xlPart)

Т.к. Вы во второй раз ведете поиск и меняете значение для поиска, то далее вот эта строка

Set c = .FindNext(c)

будет искать именно по второму занчению - "??,??". И конечно значение с в указанной строке будет равно - ничто. И таки да - в таком случае c.Address вызовет ошибку.

[r0tten]

Спасибо большое!
Не подскажете как лучше избавиться от этой ошибки? Создать отдельную процедуру для поиска второго значения?

Хм... по моему проблема есть в этой строчке:

c2ForFind = c.Row

значение не присваивается... что тут неверно? и как тогда сделать поиск по нужной строчке?

[The_Prist]

Сообщение от r0tten

по моему проблема есть в этой строчке:

c2ForFind = c.Row

Set c2ForFind = c.Row

Если все равно не получится - при первом цикле просто записывайте адреса найденных строк в строковую переменную. Затем присвойе переменной значение диапазона из этой строковой переменной. А вторым циклом ищите в этом диапазоне значения.

[SAS888]

1. The_Prist абсолютно прав. Если Вы используете метод Find, то метод FindNext будет использовать последние определенные опции. Поэтому, при такой организации поиска, от FindNext нужно отказаться.
2. Т.к. переменная c2ForFind имеет тип Range (что правильно), то присваивать ей нужно не число, а устанавливать диапазон. Хотя, я считаю, что эту переменную использовать вообще ни к чему.
3. В Вашем условии выхода из цикла есть лишняя проверка. Т.к. в цикл мы входим при условии, что If Not c Is Nothing, то зачем проверять это при выходе?
4. Учитывая все вышесказанное, фрагмент Вашего кода, определенный методом With, нужно изменить. Например, так:

With cForFind
    Set c = .Find("????????????????", LookIn:=xlValues, LookAt:=xlWhole) ' поиск 1-го значения
    If Not c Is Nothing Then
        firstAddress = c.Address
        Do
            Set c2 = Rows(c.Row).Find("??.??", LookIn:=xlValues, LookAt:=xlPart) 'поиск 2-го значения
            If Not c2 Is Nothing Then
                Text = c
                Text2 = c2
                Print #1, Text & "    " & Text2 'запись в файл
            Else
                Set c2 = Rows(c.Row).Find("??,??", LookIn:=xlValues, LookAt:=xlPart)
                If Not c2 Is Nothing Then
                    Text = c
                    Text2 = c2
                    Print #1, Text & "    " & Text2 'запись в файл
                End If
            End If
            Set c = .Find("????????????????", after:=c, LookIn:=xlValues, LookAt:=xlWhole)
        Loop While c.Address <> firstAddress
    End If
End With

[r0tten]

Большое спасибо всем отписавшимся.

SAS888
Вам я очень благодарен за приведённый код.)