Макрос поиска

[tanyshenka09]

Есть макрос, который позволяет искать слово или число в таблице Excel


Sub Finderer()
FD = InputBox("ВВЕДИТЕ ИСКОМОЕ СЛОВО ИЛИ ЧИСЛО", "Мой поиск")
If FD = "" Then Exit Sub ' если пользователь нажал кнопку ОТМЕНА - отказ от поиска
Dim cell As Range: Set cell = Range("A:A").Find(FD) ' собственно поиск
' если ничего не нашли - выход из макроса
If cell Is Nothing Then MsgBox "Искомые данные не найдены", vbExclamation: Exit Sub

MsgBox "Значение """ & FD & """ найдено в ячейке " & cell.Address, vbInformation
cell.Select
End Sub


Но такая ситуация, допустим в столбце A, по которому и производится поиск находится 2 одинаковых слова, как сделать так, что бы выделялись все 2 слово, а не одно верхнее?

[Казанский]

Искать дальше, т.е. использовать метод FindNext. В Справке приведен готовый код.

[19vitek]

Вариант многократного поиска цифры 2 в столбце А.

Sub n()
Dim lCount As Long
Dim rFoundCell As Range
    Set rFoundCell = Range("A1")
        For lCount = 1 To WorksheetFunction.CountIf(Columns(1), 2)
            Set rFoundCell = Columns(1).Find(What:=2, After:=rFoundCell, _
                LookIn:=xlValues, LookAt:=xlPart, SearchOrder:=xlByRows, _
                SearchDirection:=xlNext, MatchCase:=False)
             With rFoundCell
                 .ClearComments
                 .AddComment Text:="×èñëî 2 íàéäåíî"
             End With
        Next lCount
End Sub

[slan]

нужно повторитять поиск, пока есть найденное и накапливать результат в текстовой строке( или в диапазоне), потом выделить

[tanyshenka09]

Спасибо за ответы, но если можно поподробнее, я не очень сильна в программировании.Напишите конкретно, что куда писать.Заранее спасибо

[tanyshenka09]

Сообщение от 19vitek

Вариант многократного поиска цифры 2 в столбце А.

Sub n()
Dim lCount As Long
Dim rFoundCell As Range
    Set rFoundCell = Range("A1")
        For lCount = 1 To WorksheetFunction.CountIf(Columns(1), 2)
            Set rFoundCell = Columns(1).Find(What:=2, After:=rFoundCell, _
                LookIn:=xlValues, LookAt:=xlPart, SearchOrder:=xlByRows, _
                SearchDirection:=xlNext, MatchCase:=False)
             With rFoundCell
                 .ClearComments
                 .AddComment Text:="×èñëî 2 íàéäåíî"
             End With
        Next lCount
End Sub

Спасибо за ответ, но подскажите пожалуйста, что необходимо ввести здесь ""×èñëî 2 íàéäåíî"" у меня никак не хочет программа работать

[tanyshenka09]

Здравствуйте, вы мне сегодня отвечали в теме http://www.programmersforum.ru/showthread.php?t=177246 немогли бы вы объяснить куда вставлять find next ?

[19vitek]

"цифра 2 найдена". Можете заменить на любое нужное Вам сообщение.
Сообщение появится при наводке на ячейку с найденным символом.

[Казанский]

Sub Finderer()
Dim FD, firstAddress, adrs
FD = InputBox("ВВЕДИТЕ ИСКОМОЕ СЛОВО ИЛИ ЧИСЛО", "Мой поиск")
If FD = "" Then Exit Sub ' если пользователь нажал кнопку ОТМЕНА - отказ от поиска
Dim c As Range: Set c = Range("A:A").Find(FD) ' собственно поиск
' если ничего не нашли - выход из макроса
If c Is Nothing Then MsgBox "Искомые данные не найдены", vbExclamation: Exit Sub
firstAddress = c.Address
c.Select
Do
    adrs = adrs & vbLf & c.Address(0, 0)
    Union(Selection, c).Select
    Set c = Range("A:A").FindNext(c)
Loop While c.Address <> firstAddress

MsgBox "Значение """ & FD & """ найдено в ячейке (ячейках):" & adrs, vbInformation
End Sub

[tanyshenka09]

Спасибо Вам большое, очень выручили