форматирование текста в ворде

[Deler85]

Сообщение от viter.alex

Вот так это можно сделать. Ищет только целые абзацы. Если абзац является списком, то номер учитывается. Пробуйте. А что, других средств конвертить в html нет? Вообще-то, для списков нужно делать <ol> или <ul>

Sub ReplaceIncludingListNumbers()
  Application.ScreenUpdating = False
  Dim rs As String
  rs = "<h2>\1</h2>\2"
  Selection.HomeKey wdStory
  With Selection.Find
    .ClearFormatting
    .Replacement.ClearFormatting
    .Text = "(<[A-Za-zА-яЁё]@*)(^0013)"
    .Forward = True
    .Wrap = wdFindContinue
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchWildcards = True
    .MatchSoundsLike = False
    .MatchAllWordForms = False
    While .Execute
      .Execute replacewith:=Replace(rs, "\1", .Parent.Range.ListFormat.ListString & " " & "\1"), Replace:=wdReplaceOne
      Selection.Collapse wdCollapseEnd
    Wend
  End With
  Application.ScreenUpdating = True: Application.ScreenRefresh
End Sub

код работает спасибо, но при этом при экспорте его из ворда получается двойная нумерация

"<p>однажды в студеную зимнюю пору</p>
1 <p>1 из лесу вышел </p>
2 <p>2 вечерело </p>"

возможно и от этого как-то избавится

[viter.alex]

Сообщение от Deler85

код работает спасибо, но при этом при экспорте его из ворда получается двойная нумерация

"<p>однажды в студеную зимнюю пору</p>
1 <p>1 из лесу вышел </p>
2 <p>2 вечерело </p>"

возможно и от этого как-то избавится

А может сначала экспортировать, а затем запускать макрос? Тогда можно использовать самый первый макрос.
или перед строкой Application.ScreenUpdating = True: Application.ScreenRefresh вставить такой код

  Dim oPar As Paragraph
  For Each oPar In ActiveDocument.Paragraphs
    oPar.Range.ListFormat.RemoveNumbers
  Next

[Deler85]

Сообщение от viter.alex

А может сначала экспортировать, а затем запускать макрос? Тогда можно использовать самый первый макрос.
или перед строкой Application.ScreenUpdating = True: Application.ScreenRefresh вставить такой код

  Dim oPar As Paragraph
  For Each oPar In ActiveDocument.Paragraphs
    oPar.Range.ListFormat.RemoveNumbers
  Next

Да работает, большое спасибо!
На этапе добавления форматировать нельзя, а в получающемся документе текст уже в коде.