Как удалить пустые строки с условиями?

[ru3000]

На странице создана таблица. Ее имя "Таблица1".
Внутри этой таблицы макросом надо удалить строки, ячейки которых удовлетворяют следующим требованиям:
ячейки с "A" по "J" пустые, а ячейки с "K" по "O" меньше или равны нулю.
Спасибо.

[EducatedFool]

Попробуйте так:

Function СтрокаПустая(ByRef ra As Range) As Boolean
    For Each cell In ra.Columns("a:g"): строка = строка & cell: Next
    If Trim(строка) <> "" Then Exit Function
    СтрокаПустая = Application.CountIf(ra.Columns("k:o"), ">0") = 0
End Function


Sub УдалениеПустыхСтрок()
    Dim ra As Range, delra As Range: Application.ScreenUpdating = False
    For Each ra In [Таблица1].Rows
        If СтрокаПустая(ra) Then
            If delra Is Nothing Then Set delra = ra Else Set delra = Union(delra, ra)
        End If
    Next
    If Not delra Is Nothing Then delra.Delete
End Sub

[ru3000]

Спасибо. Все работает.
Одно пожелание: как исключить из списка удаляемых строк строку с именем "AAA", т.к. она находится в таблице именно с такими параметрами, и макрос ее удаляет. А удалять ее не надо.

[EducatedFool]

Function СтрокаПустая(ByRef ra As Range) As Boolean
    For Each cell In ra.Columns("a:g"): строка = строка & cell: Next
    If Trim(строка) <> "" Or Not Intersect([aaa], ra) Is Nothing Then Exit Function
    СтрокаПустая = Application.CountIf(ra.Columns("k:o"), ">0") = 0
End Function

В моём коде все 3 символа aaa - латинские.

[ru3000]

Ок.
Только вот, при удалениие пустых строк в таблице, строка "AAA" остается недвижимой, в то время, как остальные строки (без имен) смещаются наверх, как и положено. Получается, что строка "AAA" полностью игнорируется и даже выходит за границы таблицы, если удалено много пустых ячеек.

[EducatedFool]

Прикрепите файл. Посмотрим, что можно сделать.

[ru3000]

Вот пример.
Строка "AAA" скрытая, по счету седьмая. Она является эталоном для создания строк.

[ru3000]

Может проблема в том, что строка скрытая? Хотя я макросом ее сначала отображаю, потом только удаляю пустые. А может это из-за имени строки? Млин, ничего не получается. А ведь задача-то элементарная.

[EducatedFool]

Вот так работает нормально:

Function СтрокаПустая(ByRef ra As Range) As Boolean
    For Each cell In ra.Columns("A:J"): строка = строка & cell: Next
    If Trim(строка) <> "" Then Exit Function
    СтрокаПустая = Application.CountIf(ra.Columns("K:O"), ">0") = 0
End Function

Sub Удалить_пустые_строки()
    Range("Таблица1").Find("шаблон").EntireRow.Hidden = False
    Dim ra As Range, delra As Range: Application.ScreenUpdating = False
    For Each ra In [Таблица1].Rows
        If СтрокаПустая(ra) Then
            If delra Is Nothing Then Set delra = ra Else Set delra = Union(delra, ra)
        End If
    Next
    If Not delra Is Nothing Then delra.Delete
    Range("Таблица1").Find("шаблон").EntireRow.Hidden = True
End Sub

Sub Создать_строку()
    Application.ScreenUpdating = False: On Error Resume Next
    Range("Таблица1").Find("шаблон").EntireRow.Hidden = False
    Range("Таблица1").Find("шаблон").EntireRow.Insert
    Range("Таблица1").Find("шаблон").Offset(-1).EntireRow.Resize(2).FillUp
    Range("Таблица1").Find("шаблон").ClearContents
    Range("Таблица1").Find("шаблон").EntireRow.Hidden = True
End Sub

Пример во вложении: (не удаляйте слово шаблон из первой ячейки скрытой строки-шаблона)

[ru3000]

Спасибо большое!