QBasic

[artemon999]

Нужна помощь в прoграммировании на QBasic...
Задача такая:
Дан массив из целых чисел Сij, где i=1,2,3,4,5,6; j=1,2,3,4,5,6. Найти максимальное отрицательное и минимальное положительное элементы в каждой строке. Заменить их соответсвующими этой строке элементами главной диагонали. Вывести на печать все промежуточные и окончательные значения.

ввел данные через операторы read, data и дальше не сображу как делать, если кто понимает, напиши плиз)))

cls
dim с(i,j)
data 1,4,-6,8,-3,7
data 5,-1,6,12,-7,2
data -10,5,-4,3,8,-6
data 9,-,5,4,1,-9,9
data 4,7,-3,-1,4,9
data 5,9,4,-1,-7,-5
for i=1 to 6
for j=1 to 6
read c(i,j)
print c(i,j)
next j
print
next i
.
.
.

[Sazary]

Ничего сложного нет. Вполне могли бы написать и сами..

CLS
DIM i, j AS INTEGER
DIM C(6, 6) AS INTEGER
DIM maxot, minpol AS INTEGER
DATA 1,4,-6,8,-3,7
DATA 5,-1,6,12,-7,2
DATA -10,5,-4,3,8,-6
DATA 9,-,5,4,1,-9,9
DATA 4,7,-3,-1,4,9
DATA 5,9,4,-1,-7,-5
FOR i = 1 TO 6
 FOR j = 1 TO 6
 READ C(i, j)
 PRINT USING "####"; C(i, j);
 NEXT j
PRINT
NEXT i
PRINT
'----------
FOR i = 1 TO 6
maxot = -1
minpol = -1
 FOR j = 1 TO 6
  IF C(i, j) > 0 THEN
   IF minpol = -1 THEN
    minpol = j
   ELSEIF C(i, j) < C(i, minpol) THEN
    minpol = j
   END IF
  ELSEIF C(i, j) < 0 THEN
   IF maxot = -1 THEN
    maxot = j
   ELSEIF C(i, j) > C(i, maxot) THEN
    maxot = j
   END IF

 END IF

 NEXT j

PRINT USING "Stroka #:  "; i;
PRINT USING "min pol = ##, max otr= ##, el na diag= ##"; C(i, minpol); C(i, maxot); C(i, i)
C(i, minpol) = C(i, i)
C(i, maxot) = C(i, i)

NEXT i

PRINT
FOR i = 1 TO 6
 FOR j = 1 TO 6
  PRINT USING "####"; C(i, j);
 NEXT j
 PRINT
NEXT i
END

[artemon999]

огромное спасибо за помощь)