Как из пути файла вытянуть его последнюю папку

[viter.alex]

Есть, к примеру, путь D:\FirstFolder\SecondFolder\mytable .xls. Как из него вытянуть только SecondFolder?

[viter.alex]

Сам спросил, сам ответил.

Function GetLastFolder(FullPath As String) As String
  If FullPath = "" Then Exit Function
  Dim i As Integer
  Dim result As String
  FullPath = StrReverse(FullPath)
  For i = InStr(FullPath, Application.PathSeparator) + 1 To Len(FullPath)
    If Mid(FullPath, i, 1) <> Application.PathSeparator Then
      result = result & Mid(FullPath, i, 1)
    Else: Exit For
    End If
  Next i
  GetLastFolder = StrReverse(result)
End Function

[EducatedFool]

Sub test()
    TXT = ThisWorkbook.path
    MsgBox CreateObject("scripting.filesystemobject").GetFolder(TXT).Name
    
    'MsgBox CreateObject("scripting.filesystemobject").GetFolder(TXT).ParentFolder.Name
End Sub

Sub test2()
    TXT = ThisWorkbook.path
    MsgBox Mid$(TXT, InStrRev(TXT, "\") + 1)
End Sub

[viter.alex]

Нет слов. Одни выражения

[viter.alex]

Sub test2()
    TXT = ThisWorkbook.path
    MsgBox Mid$(TXT, InStrRev(TXT, "\") + 1)
End Sub

Почему-то все время возвращает «Мои документы» И первый код тоже.
ThisWorkbook.Path всегда возвращает «Мои документы», при этом ThisWorkbook.FullName возвращает то, что надо

[EducatedFool]

Почему-то все время возвращает «Мои документы»

Ну либо ты запускаешь макрос из файла, находящего в этой папке, либо Excel глючит...
Где-то на этом форуме я встречал тему, где обсуждался такой глюк - свойство path любого файла возвращало одно и то же значение.

Попробуй заменить ThisWorkbook.path на activeWorkbook.path

ThisWorkbook.Path всегда возвращает «Мои документы», при этом ThisWorkbook.FullName возвращает то, что надо

Попробуй так:

Sub test()
    txt = Replace(ThisWorkbook.FullName, "\" & ThisWorkbook.Name, "")
    If Len(txt) < 3 Or ThisWorkbook.Path = "" Then Exit Sub  ' файл не сохранён, или находится в корневом каталоге
    MsgBox Mid$(txt, InStrRev(txt, "\") + 1)
End Sub

[viter.alex]

Сообщение от EducatedFool

Ну либо ты запускаешь макрос из файла, находящего в этой папке, либо Excel глючит...
Где-то на этом форуме я встречал тему, где обсуждался такой глюк - свойство path любого файла возвращало одно и то же значение.

Попробуй заменить ThisWorkbook.path на activeWorkbook.path



Попробуй так:

Sub test()
    txt = Replace(ThisWorkbook.FullName, "\" & ThisWorkbook.Name, "")
    If Len(txt) < 3 Or ThisWorkbook.Path = "" Then Exit Sub  ' файл не сохранён, или находится в корневом каталоге
    MsgBox Mid$(txt, InStrRev(txt, "\") + 1)
End Sub

Внатуре глючит. Пойду дома пробовать. Глюк получается при сохранении под другим именем. Имя формируется из содержимого ячеек. Кстати, моя функция возвращает правильно, но сохраняет все равно в «Мои документы» и вылетает с ошибкой. Может это как-то связано с этим? Если не получится, буду искать обновления.

[SAS888]

Одно не понятно: при чем здесь ThisWorkbook.path?
Если есть строковая переменная, содержащая полный путь, то метод GetFolder объекта FileSystemObject, предложенный EducatedFool, обязан выдать требуемый результат.
Если же просто поработать с этой строкой, то могу предложить так:

Sub GetFolder()
    MyPath$ = "D:\FirstFolder\SecondFolder\mytable.xls"
    MsgBox Split(MyPath$, "\")(UBound(Split(MyPath, "\")) - 1)
End Sub