Навигация в документе

[viter.alex]

Посмотри, мой макрос пропускает только те страницы, которые начинаются не с нового абзаца?

Добавлено позже
В общем фишка была в том, что фигура привязывается к началу первого абзаца из диапазона, заданного в качестве якоря. Поэтому, если текст на странице не совпадал с началом абзаца, то кнопка при вставке привязывалась к началу последнего абзаца предыдущей страницы. Я исправил это с помощью костыля. Также добавил явное задание шрифта для кнопки.

Sub AddButtonToPage(Anchor As Range, Name As String, Top As Single, Left As Single, Caption As String, MacroName As String)
  Dim btn As CommandButton
  'Добавление кнопки на страницу
  With ActiveDocument.Shapes.AddOLEControl("Forms.CommandButton.1", , , , , Anchor)
    Set btn = .OLEFormat.Object
    With btn
      .Name = Name
      .Caption = Caption
      .AutoSize = True
      .Font.Bold = False
      .Font.Size = 14
    End With
    .RelativeHorizontalPosition = wdRelativeHorizontalPositionPage
    .Left = Left
    .RelativeVerticalPosition = wdRelativeVerticalPositionPage
    .Top = Top - btn.Height
  End With
  
  'Добавление кода для кнопки в модуль ThisDocument
  Dim CodeModule As VBComponent
  Set CodeModule = Anchor.Document.VBProject.VBComponents(1)
  With CodeModule.CodeModule
    .InsertLines .CountOfDeclarationLines + .CountOfLines, String(2, vbCr)
    .InsertLines .CountOfDeclarationLines + .CountOfLines, "Private Sub " & Name & "_Click()" & vbCr & "Application.Run """ & MacroName & """" & vbCr & "End Sub"
  End With
End Sub

Sub Main()
  Dim oRng As Range
  Dim i As Long
  Dim n As Long
  
  n = ActiveDocument.Range.ComputeStatistics(wdStatisticPages)
  Set oRng = ActiveDocument.Range.GoTo(wdGoToPage, wdGoToAbsolute, 1)
  i = oRng.Information(wdActiveEndPageNumber)
  Do
    'Костыль: Если начало текста на странице не совпадает с началом абзаца, _
    то привязываем фигуру к следующему абзацу на странице
    If oRng.Paragraphs.First.Range.Start <> oRng.Start Then
      Set oRng = oRng.Paragraphs.First.Next.Range
    End If
    AddButtonToPage oRng, "Button" & i, oRng.Sections.First.PageSetup.TopMargin, oRng.Sections.First.PageSetup.LeftMargin, "К оглавлению", "WebGoBack"
    Set oRng = oRng.GoToNext(wdGoToPage)
    i = i + 1
    If i - 1 = n Then Exit Do
    DoEvents
  Loop
End Sub