insert вместе с returning в vba

[ivan.tiran]

Добрый день. Нужно вернуть id по результатам insert. Так не работает.

Private Sub WriteMessageIn(Item As Outlook.MailItem, hType As HeaderType, databaseName As String, databaseUser As String, databaseUserPassword As String)
    Dim strSql As String
    Dim driverParameters As String
    Dim con As Object
    Dim oCmd As Object
    Dim rs As ADODB.Recordset
        
        
    driverParameters = "Provider=OraOLEDB.oracle;USER ID=" & databaseUser & ";Password=" & databaseUserPassword & ";Data Source=" & databaseName
    strSql = "INSERT INTO MESSAGE_IN(NAME_S) VALUES(?) RETURNING MESSAGE_IN.ID_MES INTO ?"
    
    Set con = CreateObject("ADODB.connection")
    con.ConnectionString = driverParameters
    con.Open
    Set oCmd = CreateObject("ADODB.Command")
    oCmd.ActiveConnection = con
    oCmd.CommandText = strSql
    oCmd.CommandType = adCmdTable

    oCmd.NamedParameters = False
    
    oCmd.Prepared = True
    
    MsgBox "qwerty0"
    
    oCmd.Parameters.Append oCmd.CreateParameter(NAME_S, adVarChar, adParamInput, Len("test"), "test")
    
    MsgBox "qwerty1"
    Set rs = oCmd.Execute
    MsgBox "qwerty2"
    
    rs.Close
    Set rs = Nothing
    Set oCmd = Nothing
    con.Close
    Set con = Nothing
    
    MsgBox "end"
    
End Sub

execute не проходит. Что я делаю не так?

oCmd.CommandType пробовал разный ставить

[ivan.tiran]

Private Sub WriteMessageIn(Item As Outlook.MailItem, hType As HeaderType, databaseName As String, databaseUser As String, databaseUserPassword As String)
    Dim strSql As String
    Dim driverParameters As String
    Dim con As Object
    Dim oCmd As Object
    Dim rs As ADODB.Recordset
        
        
    driverParameters = "Provider=OraOLEDB.oracle;USER ID=" & databaseUser & ";Password=" & databaseUserPassword & ";Data Source=" & databaseName
    strSql = "begin insert into message_in(NAME_S) VALUES('ÈÇÌÈÐÀÍ') returning message_in.id_mes into :id; end;"
    
    Set con = CreateObject("ADODB.connection")
    con.ConnectionString = driverParameters
    con.Open
    Set oCmd = CreateObject("ADODB.Command")
    oCmd.ActiveConnection = con
    oCmd.CommandText = strSql
    oCmd.CommandType = adCmdText

    oCmd.NamedParameters = True
    
    oCmd.Prepared = True
    
    MsgBox "qwerty0"
    
    oCmd.Parameters.Append oCmd.CreateParameter(NAME_S, adVarChar, adParamInput, Len("test"), "test")
    
    MsgBox "qwerty1"
    Set rs = oCmd.Execute
    MsgBox "qwerty2"
    
    rs.MoveFirst
    
    MsgBox "qwerty3"
    
    MsgBox rs(":id")
    
    'rs.Close
    'Set rs = Nothing
    Set oCmd = Nothing
    con.Close
    Set con = Nothing
    
    MsgBox "end"
    
End Sub

Так прошёл execute, но не работает rs.MoveFirst

[ivan.tiran]

Кому интересно, как я вернул id из insert, вот мой код

Private Function WriteMessageIn(Item As Outlook.MailItem, hType As HeaderType, databaseName As String, databaseUser As String, databaseUserPassword As String) As Long
    Dim strSql As String
    Dim driverParameters As String
    Dim con As Object
    Dim oCmd As Object
    Dim commString As String
        
    driverParameters = "Provider=OraOLEDB.oracle;USER ID=" & databaseUser & ";Password=" & databaseUserPassword & ";Data Source=" & databaseName
    strSql = "begin insert into message_in(NAME_S,WAY,NAME_F,DATE_ENT,DATE_REC,DATE_DB,COMM,DEL_REC,KOD_REC) VALUES(?,?,?,?,?,?,?,?,?) returning message_in.id_mes into :id; end;"
    
    Set con = CreateObject("ADODB.connection")
    con.ConnectionString = driverParameters
    con.Open
    Set oCmd = CreateObject("ADODB.Command")
    oCmd.ActiveConnection = con
    oCmd.CommandText = strSql
    oCmd.CommandType = adCmdText
    oCmd.NamedParameters = True
    oCmd.Prepared = True
    
    If (hType = PROGNOZ) Then
        commString = "ôîðìàëèçîâàííûé òåêñò ïèñüìà"
    Else
        commString = getCommStringForMessageIn(Item, ",")
    End If
    
    oCmd.Parameters.Append oCmd.CreateParameter(NAME_S, adVarChar, adParamInput, Len("ÈÇÌÈÐÀÍ"), "ÈÇÌÈÐÀÍ")
    oCmd.Parameters.Append oCmd.CreateParameter(WAY, adVarChar, adParamInput, Len("e-mail"), "e-mail")
    oCmd.Parameters.Append oCmd.CreateParameter(NAME_F, adVarChar, adParamInput, Len(Item.Subject), Item.Subject)
    oCmd.Parameters.Append oCmd.CreateParameter(DATE_ENT, adDate, adParamInput, , Item.ReceivedTime)
    oCmd.Parameters.Append oCmd.CreateParameter(DATE_REC, adDate, adParamInput, , Now())
    oCmd.Parameters.Append oCmd.CreateParameter(DATE_DB, adDate, adParamInput, , Now())
    oCmd.Parameters.Append oCmd.CreateParameter(COMM, adVarChar, adParamInput, Len(commString), commString)
    oCmd.Parameters.Append oCmd.CreateParameter(DEL_REC, adBigInt, adParamInput, , 0)
    oCmd.Parameters.Append oCmd.CreateParameter(KOD_REC, adBigInt, adParamInput, , 0)
    
    oCmd.Parameters.Append oCmd.CreateParameter("id", adBigInt, adParamOutput)
    
    oCmd.Execute
    
    WriteMessageIn = oCmd.Parameters("id").Value
    Set oCmd = Nothing
    con.Close
    Set con = Nothing
End Function

[ivan.tiran]

Но, у меня новая проблема.
Когда я записываю дату таким образом в БД, всё проходит нормально.

oCmd.Parameters.Append oCmd.CreateParameter(DATE_DB, adDate, adParamInput, , Now())

Но, стоит мне в начале написать.

Dim beginDate As Date
beginDate = Now()

И попробовать вот так записать

oCmd.Parameters.Append oCmd.CreateParameter(DATE_DB, adDate, adParamInput, , beginDate)

то запись не проходит.

Как в итоге в параметры передать дату, которую я объявил раньше?

[Аватар]

Пишут, что тип результата now() - Variant(Date). Я в vba постольку поскольку, думаю что тип Date и Variant(Date) далеко не одно и то же. Отсюда бы и плясал

[Serge_Bliznykov]

Сообщение от Аватар

Я в vba постольку поскольку, думаю что тип Date и Variant(Date) далеко не одно и то же. Отсюда бы и плясал

т.е. надо попробывать:

Dim beginDate As Variant
beginDate = Now()

[ivan.tiran]

Сообщение от Serge_Bliznykov

т.е. надо попробывать:

Dim beginDate As Variant
beginDate = Now()

Спасибо. Работает!!!

[Serge_Bliznykov]

Сообщение от ivan.tiran

Спасибо. Работает!!!

Это не мне "спасибо", это Аватару спасибо!

[ivan.tiran]

Сообщение от Serge_Bliznykov

Это не мне "спасибо", это Аватару спасибо!

И Аватару спасибо!