Помогите подправить код макроса для удаления строк....

[Kent_hd777]

Здравствуйте, такая ситуация, только начинаю осваивать макросы, дабы упростить себе работу, но дело идет медленно, и вот чуток хочу полегче сделать. В чем суть? в примере exel есть данные которые забиты туда через одно место. подскажите можно ли сделать так что бы отдельные строки остались а все остальные удалить. но есть нюанс выборку нужно сделать так чтобы учитывались только начальные символы. блин не знаю как объяснить, в примере покрасил строки в зеленый которые нужно оставить а красным что не нужно. так же там есть макрос который удаляет строки по слову. можно ли его подправить что бы удалял только те строки которые отмечены. exel с поддержкой макроса не могу выложить поэтому он написан на 2 листе.

[Aleksandr H.]

В чем именно проблема, не знаете что писать в ""по_этому_слову_нужно удалить"?
Тогда вручную красьте ячейки в красный цвет, строки которые надо удалять (как сделали в примере)

Sub DeleteRows()
    Dim DelColor
    Dim StayColor
    Dim LastRow As Integer
    Dim R As Integer
    LastRow = ActiveSheet.UsedRange.Rows.Count
    For R = LastRow To 1 Step -1
        With ActiveSheet
            If .Cells(R, "O").Interior.Color = 255 Then
                .Rows(R).EntireRow.Delete
            ElseIf .Cells(R, "O").Interior.Color = 4697456 Then
                'TODO SOME ACTIONS
            End If
        End With
    Next R
End Sub

[Serge_Bliznykov]

Сообщение от Kent_hd777

но есть нюанс выборку нужно сделать так чтобы учитывались только начальные символы. блин не знаю как объяснить, в примере покрасил строки в зеленый которые нужно оставить а красным что не нужно.

Вы по какому принципу выбирали строчки - сможете детально объяснить?

в начале строки есть несколько пробелов (строго от одного пробела до трёх пробелов) и цифра (остальное в строке не проверяем) - тогда эту строчку оставляем,
иначе - удаляем.
Так?

[Kent_hd777]

Совершенно верно, в любом случаи с начало будет два пробела, а там в зависимости от номера, будет либо ещё пробел либо уже цифра..

[Kent_hd777]

в начале строки есть несколько пробелов (строго от одного пробела до трёх пробелов) и цифра (остальное в строке не проверяем) - тогда эту строчку оставляем,
иначе - удаляем.
Так?

Совершенно точно. Вот я и не знаю как можно это дело упростить. чтобы через макрос, удалить лишнее и в дальнейшем использовать эти данные.

[Serge_Bliznykov]

Сообщение от Kent_hd777

Совершенно точно. Вот я и не знаю как можно это дело упростить. чтобы через макрос, удалить лишнее и в дальнейшем использовать эти данные

вот макрос, который оставит только те строчки, у которых в столбце A

Сообщение от Serge_Bliznykov

в начале строки есть несколько пробелов (строго от одного пробела до трёх пробелов) и цифра (остальное в строке не проверяем)

остальные строчки будут удалены

Sub DeleteBadRows()
    Dim LastRow As Integer
    Dim R As Integer
    Dim Ch As Range
    Dim regex As Object
    Set regex = CreateObject("VBScript.RegExp")
    regex.Pattern = "^\s{1,3}\d"
    regex.Global = True
    
    LastRow = ActiveWorkbook.ActiveSheet.UsedRange.Rows.Count
    For R = LastRow To 1 Step -1
        With ActiveWorkbook.ActiveSheet
            If Not regex.Test(.Cells(R, "A").Value) Then
                ' .Cells(R, "O").Interior.Color = 22
                .Rows(R).EntireRow.Delete
            End If
        End With
    Next R
End Sub

[Kent_hd777]

Спасибо огромное!!!! очень сильно выручили.....