Регулярные выражения. найти заменить по условию

[bdfy]

есть вот такое вот к примеру выражение в виде строки.

(" & [5!$B$83] & "·(" & [5!$B$98] & "+" & [5!$B$99] & "+" & [5!$B$100] & "))/(" & [5!$B$97] & "+" & [5!$B$98] & "+" & [5!$B$99] & "+" & [5!$B$100] & ")+(" & [5!$B$89] & "·(" & [5!$B$99] & "+" & [5!$B$100] & ")+" & [5!$B$94] & "·" & [5!$B$100] & ")/(" & [5!$B$97] & "+" & [5!$B$98] & "+" & [5!$B$99] & "+" & [5!$B$100] & ")

[5!$B$98] и т.п. это ссылки на ячейки. необходимо сделать следующие:
посмотреть что в ячейке и если там записано комплексное число взять в скобки. наваял следующий код

objRegExp.Pattern = "\[[^\[\]]+\]" 'Шаблон поиска
                  Set objSubMatches = objRegExp.Execute(s)
                  
                  
            For j = objSubMatches.Count - 1 To 0 Step -1
                     Set s1 = objSubMatches(j)
                     s2 = Right(Left(s1, Len(s1) - 1), Len(s1) - 2)
                     'Debug.Print "!!!!s1 " & s1
                     s3 = ActiveWorkbook.ActiveSheet.Evaluate("=" & s2)
                     If InStr(s3, "j") > 0 Then
                       ' Debug.Print "!!!! s3 " & s3
                        objRegExp.Pattern = "[^ 0-9A-Z]"
                        s4 = objRegExp.Replace(s1, "\$&")
                      '  Debug.Print "!!!! s4 " & s4
                        objRegExp.Pattern = s4
                        s = objRegExp.Replace(s, Chr(34) & "("" & " & "$&" & " & "")" & Chr(34))
                     End If
                     
            Next

проблема вот в чем - в таком виде добавление скобок происходит каждый раз ко всем одинаковым выражениям. и в итоге если [5!$B$83] встречается 4 раза, то и скобки лишние будут четырежды

[Watcher_1]

Не сильно вникая в ваш макрос пришло на ум следующее
просто при каждом цикле заменяйте двойные скобки (( и )) на ( и )

[bdfy]

ну просто двойные скобки менять нельзя - ибо они могут вполне по делу стоять например
((a+jb)-(v+jd))*b

[Watcher_1]

А если сделать поиск того выражения которое вы хотите вставить если оно уже есть в определенной позиции то не вставлять?

[bdfy]

плохо представляю синтаксис для этого. там слишком много кавычек.
вот если бы regex отлавливал только первое уникальное имя... добавить массив уже просмотренных ссылок и с ним сверять ? как то неизящно. знатоки regex - может проще есть решение ?

[bdfy]

собственно сделал. за мозговой штурм спасибо

 Dim found As String
 
            For j = objSubMatches.Count - 1 To 0 Step -1
                     Set s1 = objSubMatches(j)
                     s2 = Right(Left(s1, Len(s1) - 1), Len(s1) - 2)
                     'Debug.Print "!!!!s1 " & s1
                     s3 = ActiveWorkbook.ActiveSheet.Evaluate("=" & s2)
                     If InStr(s3, "j") > 0 And InStr(found, s3) = 0 Then
                        found = found & s3
                        'Debug.Print "!!!! s3 " & s3
                        objRegExp.Pattern = "[^ 0-9A-Z]"
                        s4 = objRegExp.Replace(s1, "\$&")
                        'Debug.Print "!!!! s4 " & s4
                        objRegExp.Pattern = s4
                        s = objRegExp.Replace(s, Chr(34) & "("" & " & "$&" & " & "")" & Chr(34))
                        Debug.Print "ñêîáêè " & s
                     End If
                     
            Next

[Казанский]

Я не спец по Regexp, но ИМХО достаточно применить его один раз, а потом работать с коллекцией совпадений. Вот программа на этапе разработки:

Sub bb()
Dim s$, objMatches As Object, x As Object, s1$, i&
Dim objRegExp As New RegExp             'подключите "Microsoft VBScript Regual Expressions"
                                        'в Tools-References, чтобы работал IntelliSense на этапе разработки программы

s = "([5!$B$83]·([5!$B$98]+[5!$B$99]+[5!$B$100]))/([5!$B$97]+[5!$B$98]+[5!$B$99]+[5!$B$100]+([5!$B$89]·([5!$B$99]+[5!$B$100])+[5!$B$94]·[5!$B$100])/([5!$B$97]+[5!$B$98]+[5!$B$99]+[5!$B$100])"

objRegExp.Pattern = "\[([^\[\]]+)\]"    'Шаблон поиска, в скобках - "Submatch"
objRegExp.Global = True                 'найти все вхождения
i = 1                                   'номер текущей позиции в исходной строке
Debug.Print s

Set objMatches = objRegExp.Execute(s)
For Each x In objMatches
    s1 = s1 & Mid$(s, i, x.FirstIndex + 1 - i)  'перенести текст между предыдущим и текущим вхождением
'Debug.Print s1
    If InStr(Evaluate(x.SubMatches(0)), "j") > 0 Then
        s1 = s1 & "(" & x & ")"         'добавить Match со скобками
    Else
        s1 = s1 & x                     'добавить Match без скобок
    End If
'Debug.Print s1
    i = x.FirstIndex + x.Length + 1
Next
s1 = s1 & Mid$(s, i)                    'перенести остаток текста
Debug.Print s1
End Sub

Окончательный вид:

Sub bb1()
Dim s$, x, s1$, i&

s = "([5!$B$83]·([5!$B$98]+[5!$B$99]+[5!$B$100]))/([5!$B$97]+[5!$B$98]+[5!$B$99]+[5!$B$100]+([5!$B$89]·([5!$B$99]+[5!$B$100])+[5!$B$94]·[5!$B$100])/([5!$B$97]+[5!$B$98]+[5!$B$99]+[5!$B$100])"

With CreateObject("vbscript.regexp")
    .Pattern = "\[([^\[\]]+)\]"    'Шаблон поиска, в скобках - "Submatch"
    .Global = True                 'найти все вхождения
    For Each x In .Execute(s)
        s1 = s1 & Mid$(s, i + 1, x.FirstIndex - i)  'перенести текст между предыдущим и текущим вхождением
        If InStr(Evaluate(x.SubMatches(0)), "j") > 0 Then
            s1 = s1 & "(" & x & ")"         'добавить Match со скобками
        Else
            s1 = s1 & x                     'добавить Match без скобок
        End If
        i = x.FirstIndex + x.Length
    Next
    s1 = s1 & Mid$(s, i + 1)                  'перенести остаток текста
End With
Debug.Print s1
End Sub

[bdfy]

спасибо. красивое решение.