Проблема с переходом (bat)

[JonMagon]

Это опять я, с прошлой проблемой уже разобрался, но, возникла новая проблема, надо проверять если есть файл, то переносить на строку такую-то, а если нету файла, то переносить на строку другую-то, но тут возникла проблема, а именно - если ставить переход goto, то она блокирует то что будешь дальше, и сразу переносит на другую строку. Помогите решить проблему, весь код файла

@echo off
title Тестовый файл
echo Тестовый файл
:LAUNCH
echo.
echo 1) Запустить файл
echo 2) О программе
echo 3) Выход
echo.
set /P l="Введите номер действия: " 

IF %l%==1 ( echo. 
:ERROR
echo Список файлов:
echo.
DIR /B "%CD%"
echo.
set /P d="Введите наименование файла: " 
goto OVER
:LISTING
echo проверка

)

IF %l%==2 ( echo.
echo /////////////////////////////
echo /// бла-бла-бла           ///
echo /// бла-бла-бла           ///
echo /////////////////////////////
goto LAUNCH
)

IF %l%==3 (echo. 
exit
)

:OVER
if not exist %d% echo Файла "%d%" не существует
goto ERROR
if exist %d% goto LISTING


Pause

а эта часть которая должна отвечать за проверку файла на существование

:OVER
if not exist %d% echo Файла "%d%" не существует
goto ERROR
if exist %d% goto LISTING

Короче врядли кто нибудь знает как сделать, хотя...
Зарание спасибо за любой ответ

[Serge_Bliznykov]

опять Вы странным образом решаете странные задачи...

в принципе у Вас всё правильно было написано.
я себе позволил только блоки местами переставить (ну у вас же goto error выполнялась ВСЕГДА, вне зависимости от того, есть файл или нет!

посмотрите такой код:

@echo off
title Тестовый файл

echo.
set /P d="Введите наименование файла: " 

if not exist %d% goto Error 

rem LISTING
echo Тут у Вас будет листинг....

goto BAT_END


:Error
echo.
echo Файла "%d%" не существует
echo.


rem а это конец батника...
:BAT_END
pause

[JonMagon]

Спасибо, посмотрел как Вы предложили, и сделал без переходов этих. Теперь новая проблема появилась, почему-то в первый раз не передает значение переменной, выдает ошибку, и написать еще раз, то передает, если уже файл будет сущестовать то все нормально пролетает, не пойму почему он в первый раз не передает значение переменной
Помогите решить проблему, сам код

@echo off
title Тестовый файл
echo Тестовый файл
:LAUNCH
echo.
echo 1) Запустить файл
echo 2) О программе
echo 3) Выход
echo.
set /P l="Введите номер действия: " 

IF %l%==1 ( echo. 
:ERROR
echo Список файлов:
echo.
DIR /B "%CD%"
echo.
set /P d="Введите наименование файла: " 
goto PROTECTED


)

IF %l%==2 ( echo.
echo /////////////////////////////
echo /// бла-бла-бла            ///
echo /// бла-бла-бла           ///
echo /////////////////////////////
goto LAUNCH
)

IF %l%==3 (echo. 
exit
)

:PROTECTED
if not exist %d% (echo Файла "%d%" не существует
goto ERROR)
if exist %d% (echo проверка)

Pause

[Serge_Bliznykov]

Вы не поверите, но ваш код работает нормально!

Единственное, что если вводите имя файла, которое содержит пробелы, то ОБЯЗАТЕЛЬНО нужно вводить это имя в двойных кавычках!

Давайте скриншоты, в каком случае у Вас не работает!

[JonMagon]

А нет, все работает действительно, просто если почему-то не указывать действие, а сразу писать название файла, то он будет выдавать ошибку.

[Serge_Bliznykov]

просто если почему-то не указывать действие, а сразу писать название файла, то он будет выдавать ошибку.

ну, это несложно (и даже желательно) побороть:

....
IF %l%==3 (echo. 
exit
)

echo Вы ввели недопустимый номер (%l%)! 
pause
goto LAUNCH

:PROTECTED
....

а вот как побороть вылет, если ввести несколько параметров, разделённых пробелом(ами) - я не знаю...

[JonMagon]

Serge_Bliznykov, о спасибо еще раз

[Serge_Bliznykov]

а вот как побороть вылет, если ввести несколько параметров, разделённых пробелом(ами) - я не знаю...

вроде разобрался чуток..
а, проблема была не в строчке ввода. там вводится всё классно.
а вот при использовании возникали проблемы.

JonMagon
вот ещё вариант.
вроде так получше чуток. (и, йоохо!, теперь двойные кавычки вводить не обязательно!!! )
Это пример опять с "моими любимыми" метками, захотите, перепишете через группировку команд в круглых скобках, как это Вы любите

@echo off
title Тестовый файл
echo Тестовый файл

:LAUNCH
echo.
echo 1) Запустить файл
echo 2) О программе
echo 3) Выход
echo.
set /P l="Введите номер действия: " 


if "%l%" equ "1" goto:pDoing
if "%l%" equ "2" goto:pAbout
if "%l%" equ "3" goto:pExit

echo Вы ввели недопустимый номер (%l%)! 
pause
goto LAUNCH

:pDoing
echo. 
:ERROR
echo Список файлов:
echo.
DIR /B "%CD%"
echo.
set "d=" 
set /P d="Введите наименование файла: " 
set "d=%d:"=%"
goto PROTECTED

:pAbout
echo.
echo /////////////////////////////
echo /// бла-бла-бла            ///
echo /// бла-бла-бла           ///
echo /////////////////////////////
goto LAUNCH

:pExit
echo. 
exit


:PROTECTED
if not exist "%d%" (echo Файла "%d%" не существует
goto ERROR)
if exist "%d%" (echo проверка)

Pause

p.s. обратите внимание на следующие четыре факта.
1) как теперь проверяется введённый номер
2) на строчку set "d=%d:"=%"
это не я придумал. взял на форуме ру-боарда, там есть обалденное обсуждение программирования на BAT файлах. так вот, эта строчка удалит все двойные кавычки из имени файла.
3) имя файла в команде EXIST (NOT EXIST) указано в двойных кавычках. Это и решает проблему с пробелами в имени файла
4) выделенное фиолетовым можно смело убрать! Раз мы не ушли на метку ERROR по несущестованию файла, значит файл существует! Можно уже и не проверять!

успехов в учёбе.

[JonMagon]

у меня не столь большой проект, поэтому и пишу на батнике.

успехов в учёбе.

Спасибо