Поиск ячейки соответствующую параметру с выделением

[andrey1]

Здравствуйте.Подскажите, пожалуйста,
есть вот такой макрос:

Sub ПОИСК()
Dim x As Range, a As String
a = ActiveCell.Value
Set x = [A:A].Find(a, LookAt:=xlWhole)
If Not x Is Nothing And x.Next > 0 Then x.Next.Select
End Sub

В столбце "А" наименования повторяются. Мне нужно чтобы если x.Next=0
строка пропускалась и поиск велся дальше пока не будет найдено положительное значение.
И еще один вопрос: Почему в этом макросе игнорируется ячейка "А1"

[IgorGO]

.Next - бежит вправо от исходной ячейки (по крайней мере так пишет документация). поэтому не представляю, как удавалось двигаться вниз по столбцу А, используя .Next.

начиная с
If Not x Is Nothing And x.Next > 0 Then x.Next.Select

замените на:
If Not x Is Nothing Then
x.select
Do
Selection.Offset(1).Select
Loop Until Selection <> 0
end if

[SAS888]

Если я правильно понял, то требуется выделить первую попавшуюся ячейку, которая удовлетворяет условиям поиска.
С использованием метода Find (FindNext), можно так:

Sub Main1()
    Dim x As Range, a As String
    Set x = [A:A].Find(what:=ActiveCell, LookAt:=xlWhole)
    If Not x Is Nothing Then
        a = x.Address
        Do
            If x.Next > 0 Then
                x.Next.Select: Exit Do
            End If
            Set x = [A:A].FindNext(x)
        Loop While a <> x.Address
    End If
End Sub

Необходимо заметить, что если поиск задавать в виде Set x = [A:A].Find..., то поиск в столбце "A" начнется со 2-й строки. И, если 1-е значение, удовлетворяющее поиску будет находиться в 1-й строке, то оно будет рассматриваться методом Find как последнее. Если в Вашем случае такой вариант возможен, то необходимо это учитывать.
Можно рассмотреть еще один, альтернативный вариант. В следующем макросе формируется диапазон ячеек 1-го столбца, удовлетворяющий критерию поиска (без цикла). Затем, в цикле просматриваются соседние ячейки только этого диапазона. Такой способ свободен от вышеуказанной проблемы.

Sub Main2()
    Dim x As Range, y As Range: Application.ScreenUpdating = False
    Set x = [A:A].Find(what:=ActiveCell, LookAt:=xlWhole)
    If Not x Is Nothing Then
        [A:A].ColumnDifferences(x).EntireRow.Hidden = True
        For Each y In [A:A].SpecialCells(xlCellTypeVisible)
            If y.Next > 0 Then
                y.Next.Select: Exit For
            End If
        Next: Rows.Hidden = False
    End If
End Sub

Выбирайте, что Вам лучше подходит.

[andrey1]

Спасибо SAS888. Все работает превосходно.