Определение сетевых характеристик ПК

[Юнлинг]

Доброго времени суток!

Как узнать с помощью VBA сетевые характеристики компьютера, а именно.
1. Имя компьютера.
2. Имя домена.
3. Логин пользователя.
4. Права пользователя.
5. IP адрес.
6. MAC адрес.

[VictorM]

Посмотрите вот это:

Для получения же списка всех доступных переменных среды Вашей операционной системы, можно воспользоваться нижеопубликованным макросом :

Private Sub CreateListEnvironVariables()
    Workbooks.Add xlWBATWorksheet '[2]
    
    Application.ScreenUpdating = False '[1]
    iCount% = 2:  iVariable$ = Environ(1)
    Do Until iVariable$ = ""
         iPosition% = InStr(iVariable$, "=")
         Cells(iCount%, 1) = Mid(iVariable$, 1, iPosition% - 1)
         Cells(iCount%, 2) = Mid(iVariable$, iPosition% + 1)
         
         iVariable$ = Environ(iCount%)
         iCount% = iCount% + 1
    Loop
    With Cells(1).Resize(, 2) 'Range("A1:B1")
         .Value = Array("Имя", "Значение")
         .Font.Bold = True
         .EntireColumn.AutoFit
    End With
    Application.ScreenUpdating = False
End Sub

Взято ЗДЕСЬ

[Юнлинг]

Сообщение от VictorM

Посмотрите вот ...

[/URL]

Оттуда я получу только 3 первые характеристики. Но для меня более важными являються остальные характеристики.
P.S. Ссылкой на сайт "http://msoffice.nm.ru/...." не могу воспользоваться сайт закрыт администратором компании.

[EducatedFool]

Посмотрите раздел Информация о компьютере здесь: http://www.vbnet.ru/faq/showall.asp

Список IP-адресов можно получить так:

Function Get_All_IP_Addresses() As Collection
    Set Get_All_IP_Addresses = New Collection
    Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
    Set colAdapters = objWMIService.ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = True")

    For Each objAdapter In colAdapters
        If Not IsNull(objAdapter.IPAddress) Then
            For i = 0 To UBound(objAdapter.IPAddress)
                Get_All_IP_Addresses.Add objAdapter.IPAddress(i)
            Next
        End If
    Next
End Function

Sub test_Get_All_IP_Addresses()
    For Each i In Get_All_IP_Addresses
        Debug.Print i
    Next
End Sub

Аналогично- с MAC-адресами:

Function Get_All_MAC_Addresses() As Collection
    Set Get_All_MAC_Addresses = New Collection: On Error Resume Next
    Set objWMIService = GetObject("winmgmts:\\.\root\cimv2")
    Set colAdapters = objWMIService.ExecQuery("SELECT * FROM Win32_NetworkAdapterConfiguration WHERE IPEnabled = True")

    For Each objAdapter In colAdapters
        If Not IsNull(objAdapter.IPAddress) Then
            For i = 0 To UBound(objAdapter.IPAddress)
                Get_All_MAC_Addresses.Add objAdapter.MacAddress(i), objAdapter.MacAddress(i)
            Next
        End If
    Next
End Function

Sub test_Get_All_MAC_Addresses()
    For Each i In Get_All_MAC_Addresses
        Debug.Print i
    Next
End Sub

[EducatedFool]

Для получения более подробной информации изучайте WMI:

Классы WMI для работы с оборудованием можно разделить на девять больших категорий:

классы для работы с устройствами охлаждения (Win32_Fan, Win32_TemperatureProbe и т.п.)
для работы с устройствами ввода (Win32_Keyboard, Win32_PointingDevice)
с дисками (Win32_CDROMDrive, Win32_DiskDrive, Win32_FloppyDisk)
с материнской платой/контроллерами/портами (Win32_MotherboardDevice, Win32_BIOS, Win32_PhysicalMemory, Win32_Processor и т.п.)
с сетью (главный - Win32_NetworkAdapter)
с питанием (Win32_Battery, Win32_PowerManagementEvent)
с печатью (Win32_Printer, Win32_PrintJob)
с модемами (Win32_POTSModem)
с видеоподсистемой (Win32_DesktopMonitor, Win32_DisplayConfiguration, Win32_VideoController, Win32_VideoSettings).


Практически все эти классы предназначены для возможности только получения информации на чтения, без возможности внесения изменений. Исключение составляют только:

класс Win32_Fan - возможность программным образом устанавливать скорость вращения вентилятора (если такая возможность поддерживается материнской платой);

класс Win32_LogicalDisk - при помощи него можно менять имя тома (свойство Volume Name)

класс Win32_NetworkAdapterConfiguration. У этого класса - десятки методов, которые позволяют менять сетевые настройки для адаптера программным образом.

Для получения прав доступа из системы используйте Win32_Account, Win32_UserAccount

Ниже перечислены некоторые другие классы для работы с операционной системой:

Win32_Share - позволяет создавать, удалять и настраивать параметры общих каталогов на компьютере. Настройка разрешений производится при помощи класса Win32_LogicalShareSecuritySetting;

Win32_StartupCommand - возможность посмотреть, какие команды выполняются при запуске Windows с информацией о том, из какой ветви реестра производится их запуск;

Win32_Account, Win32_UserAccount, Win32_Group - возможность получить доступ к учетным записям - локальным, если обращение идет к обычному компьютеру, или доменным, если обращение идет к контроллеру домена. В отличие от ADSI, при помощи этих объектов вы не сможете вносить изменения учетные записи - они предназначены только для чтения информации и мониторинга;

Win32_BootConfiguration - возможность получить информацию о параметрах загрузки Windows (все доступно только на чтение).

[Юнлинг]

EducatedFool

Огромное спасибо особенно на ссылки. Я получил массу инфы, от которой пришел в восторг!!!! Часть вопросов над которыми ломал голову там нашел ответы