Макрос для удаления строки

[julius]

Здравствуйте!
Никогда не занимался написанием макросов, вот решил попробовать, но сразу столкнулся с проблемой.
Нужно написать макрос, который проверяет значение в определенной ячейке таблицы и, если это значение равно нулю, то удаляет текущую строку.
Вот то, до чего я пока смог дойти:

If Cells(11, b) = 0 Then \Если ячейка 11B=0
Rows("11:11").Delete Shift:=xlUp \То нужно удалить 11 строку
Else
End If
End Sub

Программа выдает ошибку "Application-defined or object-defined error".
Судя по всему ошибка в первой строке, только не могу понять какая.
Помогите, пожалуйста, кто знает.
Заранее благодарен.

[IgorGO]

R=11
If Cells(r, 2) = 0 Then 'Если ячейка 11B=0
' или так: if range("B" & R) = 0 then
Rows(r).Delete Shift:=xlUp 'То нужно удалить 11 строку
Else
r = r+1
End if
осталось только придумать когда это все остановить, потому что когда R выйдет за пределы таблицы, ячейка (R, 2) всегда будет = 0, собственно вся строка будет пустая, а этот код будет их удалять, удалять и удалять...

[VictorM]

Sub DelNulRows() 'удалит пустые СТРОКИ
With ThisWorkbook.Worksheets(1)
     For iRow& = 10 To 1 Step -1
         If IsEmpty(.Cells(iRow&, "A").Value) = True Then .Rows(iRow&).Delete
     Next
End With
End Sub

Значение iRow& = 10 взято для примера.
Кол-во строк можно подсчитать и поместить в переменную.
***
Вот так сделано в рабочем проекте

Sub DelNulRows()    
    With ThisWorkbook.Worksheets("СкладМаг")
        iost = [A9]
        For iRow& = iost + 10 To 1 Step -1
            iadress = Cells(iRow&, "X").Address(0, 0)
            If iadress = "X10" Then Exit Sub
            zn = .Cells(iRow&, "X")
            If zn = 0 Then .Rows(iRow&).Delete
        Next
    End With
End Sub

Здесь проверяются на 0 ячейки столбца Х и удаляется строка.
Для подстраховки проверяется авдрес ячейки и если адрес Х10 (заголовок таблицы) все заканчивается.
Скорее всего не самый оптимальный вариант, но работает.

[julius]

Все спасибо! Теперь как надо работае. Буду усложнять алгоритм дальше.

[jungo]

Предлагаю такую заморочку, на случай если есть большое количество строк.
Собирает данные в "кучу" и стирает одним махом!
(подсказали тут на форуме).

Sub DELETE()  

Dim AllRows As Object, FirstCell As Object, FoundCell As Object

    Application.ScreenUpdating = False

    Set FirstCell = Columns("B").Find(what:=0, LookAt:=xlWhole)
    If FirstCell Is Nothing Then Exit Sub

    Set AllRows = Rows(FirstCell.Row)
    Set FoundCell = FirstCell

    Do
        Set FoundCell = Columns("B").FindNext(After:=FoundCell)
        Set AllRows = Union(Rows(FoundCell.Row), AllRows)
        If FoundCell.Address = FirstCell.Address Then Exit Do
    Loop
    AllRows.Delete
End Sub

[vitaminius@mail.ru]

товарищи помогите нужен макрос для excel'я
есть таблица 10 столбцов и дофига строк(2000-3000),
ну так вот из нее нужно удалить
строки в которых хотя-бы одна из десяти ячеек пустая
как обычно нужно еще вчера!!!
в макросах практически как свинья в апельсинах.....
заранее спасибо

[Hugo121]

Схематично так - без определения последней строки, чтоб легче понять:

Sub tt()
Dim i As Long
For i = 3000 To 1 Step -1
If Application.CountBlank(Range(Cells(i, 1), Cells(i, 10))) > 0 Then Rows(i).Delete
Next
End Sub

определение последней строки (по первой колонке):

Dim iLastRow As Long, i As Long
iLastRow = Cells(Rows.Count, 1).End(xlUp).Row
For i = iLastRow To 1 Step -1
...

[IgorGO]

Sub DelBlank()
  Dim r As Long, c As Long
  For r = Cells(Rows.Count, 1).End(xlUp).Row To 2 Step -1
    For c = 1 To Cells(1, Columns.Count).End(xlToLeft).Column
      If Cells(r, c) = "" Then Rows(r).Delete: Exit For
    Next
  Next
End Sub

теперь у Вас есть две процедуры

[vitaminius@mail.ru]

Спасибо Огромное! Все Отлично работает!!!! то что надо!!!

[leech]

Сообщение от jungo

Предлагаю такую заморочку, на случай если есть большое количество строк.
Собирает данные в "кучу" и стирает одним махом!
(подсказали тут на форуме).

Sub DELETE()  

Dim AllRows As Object, FirstCell As Object, FoundCell As Object

    Application.ScreenUpdating = False

    Set FirstCell = Columns("B").Find(what:=0, LookAt:=xlWhole)
    If FirstCell Is Nothing Then Exit Sub

    Set AllRows = Rows(FirstCell.Row)
    Set FoundCell = FirstCell

    Do
        Set FoundCell = Columns("B").FindNext(After:=FoundCell)
        Set AllRows = Union(Rows(FoundCell.Row), AllRows)
        If FoundCell.Address = FirstCell.Address Then Exit Do
    Loop
    AllRows.Delete
End Sub

может кто нибудь помочь переварить это все?
задача такая - надо удалить несколько строк. Циклом - скучно, нудно и главное долго. А вот оптом их удалять никак не получается
(т.е. нужен аналог удаления
Rows("A:L").Delete
где вместо явного указания строк используются переменные)