Выделенный элемент у Dropdown

[motorway]

Как у DropDown'а (выпад. списка) получить свойство "отмеченный элемент" (Selected Element), чтобы можно было передать др. функции? Точнее, нужно сделать при выборе некоторого элемента списка вызов функции с передачей номера отмеченного элемента. Элементы могут добавляться в список

[SAS888]

Такого свойства нет, но получить можно.
Пусть выпадающий список находится в ячейке "A1".
1. Чтобы при выборе значения из списка вызывалась функция и в качестве параметра в нее передавалось выбранное значение, в модуль соответствующего листа вставьте код:

Private Sub Worksheet_Change(ByVal Target As Range)
    If Target.Address = [A1].Address Then MsgBox View(Target.Value)
End Sub

Function View(s As String) As String
    View = "Вызов функции с параметром " & Chr(34) & s & Chr(34)
End Function

Естественно, сама функция приведена для примера.
2. Если же в качестве параметра нужно передать номер элемента в списке, то возможны 2 варианта:
1) Если список задан непосредственно (значениями, через ";"), то, например, так:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim i As Integer, a
    If Target.Address <> [A1].Address Then Exit Sub
    a = Split(Target.Validation.Formula1, ";")
    For i = LBound(a) To UBound(a)
        If a(i) = Target.Value Then MsgBox View(CStr(i + 1))
    Next
End Sub

2) Если список задан диапазоном, содержащим значения, тогда, например, так:

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim x As Range, i As Integer
    If Target.Address <> [A1].Address Then Exit Sub
    Set x = Range(Target.Validation.Formula1): i = 1
    For Each Cell In x
        If Cell.Value = Target.Value Then MsgBox View(CStr(i)) Else i = i + 1
    Next
End Sub

P.S. Обратите внимание, что в моих примерах, номер элемента списка, перед передачей в функцию преобразовывается в тип String (т.к. этого требует функция). Вы же, в свою очередь, сделайте так, как Вам требуется.

[motorway]

У меня получилось вывести номер позиции в списке просто через Dropdowns(1).Value. Если же нужно сам текст, то можно завести массив со значениями списка при их добавлении.