Наложить определенные ограничения на ячейки

[rico1271]

Доброго времени суток, уважаемые гуру и посетители форума. Я немного дружу с компьютером, делаю для работы полезные считалки. Но хочется довести одну работу до ума. Не сочтите за хамство, помогите.
Разбираюсь с VB, но сложно, блин...
Итак, есть оборудование. Если оно в работе, на его мощность могут накладываться ограничения, его можно переводить в К-режим (К-режим это условность, что бы не забивать Вам голову лишней информацией). Мощность = (Мощность в номальном режиме) + (Дополнительная мощность в К-режиме) - (Ограничение мощности).
Если оборудование в работе, то я могу ставить галку "К-режим", вводить в ячейку ограничение мощности.
Если я отключаю оборудование в резерв, в ремонт, то в ячейке "Ограничение" должен быть установлен 0 и невозможность поставить другое значение. Галочка, привязанная к ячейке "К-режим" должна быть сброшена нет возможности ее установить.
Если я снова включаю оборудование, то снова могу манипулировать этими ячейками.
Я смог сделать макрос, который скидывает значения ячеек, нашел макрос, который накладывает ограничения, но блин, не хватает ума собрать их в кучу, работает либо одно либо другое.
Макрос не стал выкладывать в этом файле, дабы не позориться.
Заранее спасибо.

[Aleksandr H.]

Сообщение от rico1271

Макрос не стал выкладывать в этом файле, дабы не позориться.

Вот это зря. Пользователи любят именно помогать с готовым, а не делать всю работу вместо ТС

[rico1271]

Ок, выкладываю с макросом, который сбрасывает значения ячеек при отключении оборудования. Только сильно не смейтесь.

[rico1271]

Другой файл с макросом, который блокирует ячейки.

[rico1271]

Забыл файл прикрепить, простите.

[rico1271]

Второй макрос нашел в интернете на одном из форумов, как адаптировать для моей задачи ума не хватает. Он накладывает блокировку на ячейку "ограничение" на 1 единицу.

[Aleksandr H.]

Я бы такое набыдлокодил на первое время. Есть более разумные решения, но...их находят со временем.

в код страницы Лист1

Private Sub Worksheet_Change(ByVal Target As Range)
    PerformClick Target
End Sub

Sub Assign()
' ЗАПУСКАТЬ ПОСЛЕ ОТКРыТИЯ КНИГИ или ПОВЕСИТЬ НА auto_open
  Dim CB As CheckBox
  For Each CB In ActiveSheet.CheckBoxes
    CB.OnAction = "CheckBoxChange"
  Next
End Sub

Sub enableevent()
' запускать если возник косяк при выполнении макроса. Перехват событий листа.
    Application.EnableEvents = True
End Sub

в код модуля Module1

Option Explicit

Sub CheckBoxChange()
    Dim trgt As Range
    Set trgt = ActiveSheet.Range(ActiveSheet.CheckBoxes(Application.Caller).LinkedCell)
    If Not (trgt Is Nothing) Then PerformClick trgt
End Sub

Sub PerformClick(Target As Range)
    Dim Stroka As Integer
   Dim Stolbec As Integer
   
   Stroka = Target.Row
   Stolbec = Target.Column
   Application.EnableEvents = False
   If Not (Intersect(Range("D3:D5"), Target) Is Nothing) Then
        If Target.Value <> "В работе" Then
            Target.Offset(0, 1) = 0
            Target.Offset(0, -1) = False
        Else
            Target.Offset(0, -1) = True
        End If
    ElseIf Not (Intersect(Range("E3:E5,C2:C5"), Target) Is Nothing) Then
        If Cells(Target.Row, "D").Value <> "В работе" Then
            Cells(Target.Row, "C") = False
            Cells(Target.Row, "E") = 0
        End If
   End If
   Application.EnableEvents = True
End Sub

[rico1271]

Александр, Вы просто волшебник! Работает!!!
Не сочтите за наглость, можете объяснить логику работы кода.
Мне с Вашими объяснениями будет проще разобраться с нюансами
и окончательно адаптировать к своей задаче.
В любом случае большое, огромное СПАСИБО! Удачи и мира Вам и нашим народам!

[Aleksandr H.]

Sub Assign()
End Sub

так как я не нашел как добраться к событиям CheckBox'ов, а изменение статуса CheckBox не перехватывалось в Worksheet_Change, было решено поискать как реализовать "ручную" подписку на
событие "клика" на CheckBox. В результате получил код, который надо запускать при старте книги.
Для данного примера запускал вручную, если бы пришлось такое запускать каждый день, то, скорее всего, нашел бы в инете решение как это обойти.

Sub Assign()
End Sub

сообственно обработчик нажатия на CheckBox. Получает адрес ячейки, к которой привязан CheckBox и передает ее в метод обработки.

Sub CheckBoxChange()
End Sub

вспомогательной метод, который надо запускать если вдруг возникла ошибка во время выполнения обработки изменений на листе.
т.к. там отключается реакция екселя на события.

Sub enableevent()
End Sub

передаем в метод обработки ячеейк ячейку которая изменялась

Private Sub Worksheet_Change(ByVal Target As Range)
End Sub

Sub PerformClick(Target As Range)
   ' Dim Stroka As Integer мусор!! можно удалить
   ' Dim Stolbec As Integer мусор!! можно удалить
   
   ' Stroka = Target.Row мусор!! можно удалить
   ' Stolbec = Target.Column мусор!! можно удалить
   Application.EnableEvents = False ' отключить события, что-бы не зациклиться
   
   ' был изменен статус оборудования
   ' изменить соседние ячейки   
   If Not (Intersect(Range("D3:D5"), Target) Is Nothing) Then 
        If Target.Value <> "В работе" Then
            Target.Offset(0, 1) = 0
            Target.Offset(0, -1) = False
        Else
            Target.Offset(0, -1) = True
        End If
	' был изменен статус CheckBox вручную или же с помощью выбора мышом.
	' делаем соответсвующие изменения
    ElseIf Not (Intersect(Range("E3:E5,C2:C5"), Target) Is Nothing) Then
        If Cells(Target.Row, "D").Value <> "В работе" Then
            Cells(Target.Row, "C") = False
            Cells(Target.Row, "E") = 0
        End If
   End If
   Application.EnableEvents = True ' включаем события
End Sub

[rico1271]

Спасибо, разобрался, уже переделал под свою конкретную задачу, Sub Assign() повесил на автооткрытие. Удачи ВАМ!