Собрать нужную информацию из нескольких столбцов в один

[Rmzn]

Доброй ночи! Помогите собрать нужную информацию из нескольких столбцов в один с разделительным символом *. Из столбцов где идут серия и номер паспорта, потом предметы и их результаты надо вывести в один столбец серию*номер* и резултаты.

[Rmzn]

Забыл прикрепить пример что должно получиться из чего

[nerv]

Function getInfo(ByRef rng As Range) As String
    getInfo = getSeries(rng.Cells(1).Value) & "*" & _
              getNumber(rng.Cells(1).Value) & _
              getSubject(rng.Cells(rng.Cells.Count).Value)
End Function


Private Function getSeries(ByRef text As String) As String
    Static re As Object
    If re Is Nothing Then
        Set re = CreateObject("vbscript.regexp")
        re.Pattern = "\d\d\s\d\d"
    End If
    On Error Resume Next
    getSeries = re.Execute(text).Item(0)
    getSeries = Replace(getSeries, " ", "")
End Function


Private Function getNumber(ByRef text As String) As String
    Static re As Object
    If re Is Nothing Then
        Set re = CreateObject("vbscript.regexp")
        re.Pattern = "\d{6}"
    End If
    On Error Resume Next
    getNumber = re.Execute(text).Item(0)
End Function


Private Function getSubject(ByRef text As String) As String
    Static re As Object
    Dim elem As Object
    If re Is Nothing Then
        Set re = CreateObject("vbscript.regexp")
        re.Pattern = "-\s?(\d+)"
        re.Global = True
    End If
    On Error Resume Next
    For Each elem In re.Execute(text)
        getSubject = getSubject & "*" & elem.Submatches(0)
    Next
End Function