Панель инструментов средствами Win API - CreateWindowEx

[IKh]

Здравствуйте.

Объясните пожалуйста, можно ли создать панель инструментов в окне приложения созданного на Delphi средствами Win API - CreateWindowEx.

В описании функции CreateWindowEx говориться, что для создания панели инструментов без кнопок можно использовать функцию CreateWindowEx указывая имя класса окна TOOLBARCLASSNAME.

Подскажите последователность, как это можно сделать в приложении на Delphi.

[*PB*]

Конечно можно.
Вот пример создания панели инструментов с использованием CreateWindowEx.

Procedure nxCreateTB(hWndParent, buttonx, buttony, flags) ; This Command creates a Toolbar and assigns the TB to the Window with the Handle hwnd.
  Protected prop=0, icc.INITCOMMONCONTROLSEX, hTb=0, hTt=0
  Protected *nxTB._nxToolbar
  ;Check the parent handle.
  If IsWindow_(hWndParent)
    ;Allocate enough memory for a _nxToolbar structure.
    *nxTB=AllocateMemory(SizeOf(_nxToolbar))
    If *nxTB
      icc\dwSize = SizeOf(INITCOMMONCONTROLSEX)
      icc\dwICC = #ICC_BAR_CLASSES
      InitCommonControlsEx_(icc)  ;Just in case!
      ;Check the flags and set defaults.
      If flags=-1
        flags = #nxTB_TBstyleTRANSPARENT|#nxTB_TBstyleFLAT|#nxTB_TBstyleTOP
      EndIf
      ;Create the toolbar.
      hTb = CreateWindowEx_(0, "ToolbarWindow32", 0, (flags|#nxTB_TBstyleFLAT|#WS_CHILD|#CCS_NODIVIDER),0,0,0,0,hWndParent,-10000,0,0)
      If hTb
        SendMessage_(hTb, #TB_BUTTONSTRUCTSIZE, SizeOf(TBBUTTON), 0) 
        SendMessage_(hTb,#TB_SETBITMAPSIZE,0, buttonx&$FFFF + (buttony&$FFFF)<<16)
        SendMessage_(hTb,#TB_SETBUTTONSIZE,0, buttonx&$FFFF + (buttony&$FFFF)<<16)
        SendMessage_(hTb,#TB_AUTOSIZE,0,0)
        ;Set extended styles.
        SendMessage_(hTb,#TB_SETEXTENDEDSTYLE,0,#TBSTYLE_EX_MIXEDBUTTONS|#TBSTYLE_EX_DRAWDDARROWS|#TBSTYLE_EX_DOUBLEBUFFER|#TBSTYLE_EX_HIDECLIPPEDBUTTONS)
        ;Create tooltip control.  We do not use a default one as supplied by #TBSTYLE_TOOLTIPS as
        ;this requires us to then subclass the toolbar's parent window in order to supply the
        ;tooltip text.
        hTt = CreateWindowEx_(#WS_EX_TOPMOST, "ToolTips_Class32", 0,#WS_POPUP|#TTS_ALWAYSTIP|#TTS_BALLOON|#TTS_NOPREFIX,#CW_USEDEFAULT,#CW_USEDEFAULT,#CW_USEDEFAULT,#CW_USEDEFAULT ,hTb, 0, 0,0)
        If hTt
          SendMessage_(hTt,#TTM_SETMAXTIPWIDTH,0,250)
          ;Create a window property for the toolbar to store the pointer to the _nxToolbar structure.
          prop=SetProp_(hTb, #PROP$, *nxTB)
          If prop
            ;Subclass the toolbar.
            *nxTB\oldWinProc=SetWindowLong_(hTb, #GWL_WNDPROC, @nxCallback())
            *nxTB\buttonwidth=buttonx
            *nxTB\buttonheight=buttony
            *nxTB\hTt=hTt
            ShowWindow_(hTb,#SW_SHOWNORMAL)    
          Else
            DestroyWindow_(hTb)
            hTb = 0 ;Signals an error.
            FreeMemory(*nxTB)
          EndIf
        Else
          DestroyWindow_(hTb)
          hTb = 0 ;Signals an error.
          FreeMemory(*nxTB)
        EndIf
      Else ;Error!
        FreeMemory(*nxTB)
      EndIf
    EndIf
  EndIf
  ProcedureReturn hTb ;Will = 0 if an error occurred.
EndProcedure

Во вложении весь набор файлов и скомпилированный пример.