Заполнение xlValidateList значениями массива

[Miguel Sanchez]

Уважаемые эксперты! Подскажите технологию заполнения списка проверки данных элементами массива или списком констант через VBA, по аналогии вставки списка значений через стандартный диалог "проверка данных" -> "список"
Пробую так:

Option Explicit
Dim list_monht As Variant
Dim nitem
Dim titem
Sub mylist_month()
list_monht = Array("январь", "февраль", "март") 'ну и т.д.
Workbooks(ThisWorkbook.Name).Active Sheet.UsedRange.Item(1).Select
With Selection.Validation
.Delete
.Add Type:=xlValidateList, AlertStyle:=xlValidAlertStop, Operator:= _
xlBetween, Formula1:= ******ЗДЕСЬ ЗАГВОЗДКА*****
.IgnoreBlank = True
.InCellDropdown = True
End With

Как переписать массив list_monht в ValidateList? Помогите!

[nilem]

Попробуйте:

Sub mylist_month()
Dim list_month() As Variant
list_month = Array("январь", "февраль", "март", "апрель")    'ну и т.д.
With ThisWorkbook.ActiveSheet.UsedRange.Item(1).Validation
    .Delete
    .Add Type:=xlValidateList, Formula1:=Join(list_month, ",")
End With
End Sub

[Miguel Sanchez]

nilem! Угу, заработала! Спасибо премногое!
И еще вопросик, вдогонку - а можно ли возвращать индекс выбранного элемента в списке xlValidateList, подобно:

PHP код:

nitem = ActiveSheet.Controls.ControlFormat.ListIndex
titem = ActiveSheet.Controls.ControlFormat.List(nitem)
Cells(n, m).Value = Left(titem, 1) 


[nilem]

Вот такое придумалось (в модуль листа, проверяем яч. А1):

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address(0, 0) <> "A1" Then Exit Sub
If Intersect(Target, Cells.SpecialCells(-4174)) Is Nothing Then Exit Sub
Dim i&, list_month
list_month = Split(Target.Validation.Formula1, ";")
Application.EnableEvents = False
For i = 0 To UBound(list_month)
    If Target = list_month(i) Then Target.Next = i + 1: Exit For
Next
Application.EnableEvents = True
End Sub

[Miguel Sanchez]

Интересный подход...
Не все понятно, правда, - при беглом просмотре. Щас скопирую и буду пробовать.
Спасибо за оперативную помощь!

PS
Как я понял, спец.пропертей у этого объекта нет - ну чтоб сразу по currently selected item ретурнуть index элемента.
Рылся в хелпе и ничего не нашел... может плохо рылся....

[Hugo121]

А так:

Option Explicit

Dim list_month() As Variant

Private Sub Worksheet_Change(ByVal Target As Range)
If Target.Address(0, 0) <> "A1" Then Exit Sub
Dim x As Integer
If Intersect(Target, Cells.SpecialCells(-4174)) Is Nothing Then Exit Sub
x = WorksheetFunction.Match(Target, list_month, 0)
MsgBox x
Application.EnableEvents = True
End Sub

Sub mylist_month()
list_month = Array("январь", "февраль", "март", "апрель")    'ну и т.д.
With ThisWorkbook.ActiveSheet.UsedRange.Item(1).Validation
    .Delete
    .Add Type:=xlValidateList, Formula1:=Join(list_month, ",")
End With
End Sub

[Miguel Sanchez]

Private Sub Worksheet_Change никак не реагирует на изменения.

Target.Address равен А1, SpecialCells(-4174) в той же ячейке, а почему-то ничего не происходит...

Причем, само событие Private Sub Worksheet_Change не перехватывается, т.к. для проверки поставил

Private Sub Worksheet_Change(ByVal Target As Range)
msgbox Target.Address
.........

Может у меня со средой VBA что-то не так, где-то что-то включить/выключить... галочки какие проставить в параметрах ексела или в references dll-ки какой нет???

[Hugo121]

Вполне может быть, что у Вас сбойнул код после
Application.EnableEvents = False
и соответственно
Application.EnableEvents = True
не прошло, поэтому и перестали обрабатываться события.

[Miguel Sanchez]

Виноват, накосячил... - Private Sub Worksheet_Change вставил в общий модуль, а не в модуль листа!
Поправил и все заработало!
Спасибо всем!

[Hugo121]

Я это название макроса никогда не вставляю и не набираю - вдруг какая ошибка, например а или о кириллицей
Они ведь есть в выпадающем списке в редакторе - никогда не ошибёшься.