Проверка массивов

[Aleks2215]

Имеются 3 одномерных массива в столбец
q0___q1___q2
q1___q0___q1
q2___q2___q3
Как сделать проверку, что если в первом столбце нет элемента, соответствующего элементам или элементу во втором и третьем столбце( в данном случае это q3, т.к. он не встречается в первом столбце), то выполняется какое то действие. Подскажите пожалуйста

[Hugo121]

Через словарь или коллекцию?
Создаём коллекцию из первого столбца, затем перебором элементов пытаемся добавить второй и третий столбец. Как только добавилось - выполняется какое то действие.
Со словарём можно проверить наличие элемента.

[Aleks2215]

По словарю это через like? можешь показать, как через коллекцию проверить, а то я с этим еще не сталкивался)

[Hugo121]

Нет, словарь - это Scripting.Dictionary
Коллекция - пример:

Function UniqueValues(ByVal arr) As Collection
' функция получает в качестве параметра массив любой размерности
' возвращает коллекцию уникальных НЕПУСТЫХ значений
Set UniqueValues = New Collection: On Error Resume Next
For Each v In arr
v = Trim(v): If Len(v) Then UniqueValues.Add CStr(v), CStr(v)
Next v
End Function

Алгоритм работы примерно одинаковый - добавляются уникальные, потом проверяется наличие.
Конкретный пример писать пока нет времени, а другие примеры тут уже были не раз.

Написал:

Option Explicit

Sub check()
    Dim a(), b(), c(), oDict As Object, i As Long, Temp As String

    a = Sheets(1).Range("A1:A" & Sheets(1).Range("A" & Rows.Count).End(xlUp).Row).Value
    Set oDict = CreateObject("Scripting.Dictionary")
    For i = 1 To UBound(a)
        Temp = Trim(a(i, 1))
        If Not oDict.Exists(Temp) Then
            oDict.Add Temp, CStr(1)
        End If
    Next

    b = Sheets(1).Range("B1:B" & Sheets(1).Range("B" & Rows.Count).End(xlUp).Row).Value
    For i = 1 To UBound(b)
        Temp = Trim(b(i, 1))
        If Not oDict.Exists(Temp) Then MsgBox "Alarma! " & Temp
    Next

    c = Sheets(1).Range("C1:C" & Sheets(1).Range("C" & Rows.Count).End(xlUp).Row).Value
    For i = 1 To UBound(c)
        Temp = Trim(c(i, 1))
        If Not oDict.Exists(Temp) Then MsgBox "Alarma! " & Temp
    Next

End Sub