AutoClicker

[FullVenic]

Так как я нуб помогите создать программу облегчающую ввод комментов желательно на бейсике чтото типо етого:
Если юзер нажал клавижу ;
тогда
компютер меняет язык на руский .
если юзер опять нажмет ету клавищу то возвратить англ...
не подумайте что программа тупая но бівают проблеммы со сменой языка и пока ты думаешь о чемто другом пока переведешь знак на языковую панель то ета прога делает все за тебя.

[Vikenty]

вроде есть такие программы Punto Switcher.
или нужен исходник?

[FullVenic]

Ну... я просто не знаю как сделать так чтоб компютер сам нажал клавишу стрл + шифт и посмотрел переключился ли язык.

[*PB*]

желательно на бейсике

Вот программа на бейсике, отображающая текущую раскладку клавиатуры с помощью значка в трее и светодиода "Scroll Lock" на клавиатуре.

Global LayoutTemp, Count=0, Layout1

Procedure ScrollLock(State)  ; Изменение состояния светодиода "Scroll Lock" на клавиатуре
If GetKeyState_(#VK_SCROLL)=State
 keybd_event_(#VK_SCROLL,$45,1,0)
 keybd_event_(#VK_SCROLL,$45,3,0)
EndIf
EndProcedure


Procedure GetLayoutWindowActive()    ; Процедура вызывается по таймеру, каждые 200 мс.
 WindowsHandle=GetForegroundWindow_() ; Хендл активного окна
 ProcessId=GetWindowThreadProcessId_(WindowsHandle,0) ; ИД процесса активного окна
 Layout=GetKeyboardLayout_(ProcessId)                 ; Раскладка клавиатуры активного окна

 If Count=0
  If  LayoutTemp<> Layout
   LayoutTemp=Layout
   Count=1
  EndIf 
 ElseIf Count=1
  Count=0
  If LayoutTemp=Layout
   If Layout=68748313                ; Русская раскладка
    ChangeSysTrayIcon(1,ImageID(0))
    SysTrayIconToolTip(1, "Русский")
    ScrollLock(0)                     ; Изменение состояния светодиода "Scroll Lock" на клавеатуре
   ElseIf Layout=67699721            ; Английская раскладка
    ChangeSysTrayIcon(1,ImageID(1))
    SysTrayIconToolTip(1, "Английский")
    ScrollLock(1)                     ; Изменение состояния светодиода "Scroll Lock" на клавеатуре
   EndIf
  EndIf
 EndIf
 
EndProcedure



 OpenWindow(0,2,2,20,20,"",#PB_Window_Invisible) ; Создание невидимого окна
 
 CatchImage(0, ?RuIcon, 894)                     ; Загрузка иконок из исполняемого файла
 CatchImage(1, ?EnIcon, 894)
 
 AddSysTrayIcon(1,WindowID(0),ImageID(0))        ; Создание значка в трее
 SysTrayIconToolTip(1, "Русский")
 
 If CreatePopupMenu(0)                           ; Создание контекстного меню
  MenuItem(1,"Закрыть")
 EndIf
 
 SetTimer_(WindowID(0),1,200,@GetLayoutWindowActive() ) ; Запуск таймера, для процедуры GetLayoutWindowActive()
 
 Repeat                  ; Главный цикл Repeat - ForEver
 Event=WaitWindowEvent()  ; ИД события в программе
 Menu=EventMenu()
 Type=EventType()
 
  If Event=#PB_Event_SysTray         ; Событие в ртрее
   If Type=#PB_EventType_RightClick  ; клик правой кнопкой мышки
    DisplayPopupMenu(0,WindowID(0) ) ; Отображение контекстного меню
   EndIf
  EndIf
  
  If Event=#PB_Event_Menu And Menu=1 ; Событие в меню
   Break                             ; Прерывание цикла
  EndIf
   
 ForEver
 KillTimer_(WindowID(0),1)
 End

  
DataSection
 RuIcon:
  IncludeBinary "Ru.ico"
 RuIconend:
  
 EnIcon:
  IncludeBinary "En.ico"
 EnIconend:
EndDataSection

Во вложении исходник со значками и скомпилированая программа.

[FullVenic]

ладно... етого я не пониаю кто посоветует где взять книгу для новичков... типа изучитель языка бейсик

[Crivel]

http://www.visual.2000.ru/develop/vb/books-vb/

http://depositfiles.com/ru/files/yd9wtky1d

Автор сообщения не несёт ответственность, за предоставленные ссылки.

FullVenic, а вам советую познать, что такое гугль и как им пользоваться:
http://www.google.ru


ОФФТОП:
FullVenic, я тоже раньше в ДО играл. Советую бота не писать

[*PB*]

кто посоветует где взять книгу для новичков... типа изучитель языка бейсик

Вот http://pure-basic.narod.ru/docs.html

[FullVenic]

хоть в глаз стреляй не вижу [url]http://www.visual.2000.ru/develop/vb/books-vb/вот сдесь книг которые можно скакчать

[Crivel]

хоть в глаз стреляй не вижу [url]http://www.visual.2000.ru/develop/vb/books-vb/вот сдесь книг которые можно скакчать

А теперь смотрим пост №5:

ладно... етого я не пониаю кто посоветует где взять книгу для новичков... типа изучитель языка бейсик

И где здесь написано, что вам нужна именно ссылка на скачивание книги? вы просто спросили где взять, и какие книги по бэйсику есть. Я вам дал ссылку на список литературы. А если вы хорошо прочитали мой пост, там есть ссылка на скачивание:
http://depositfiles.com/ru/files/yd9wtky1d

Так же, форумчанин *PB*, дал вам ссылку.

[KonstantinRogozhin]

Сообщение от *PB*

Вот программа на бейсике, отображающая текущую раскладку клавиатуры с помощью значка в трее и светодиода "Scroll Lock" на клавиатуре.

Для меня полезная программа, пасибо)