Выделение цветом нескольких фрагментов текста

[caute]

Выделил пять фрагментов текста, покрасил в желтый все пять одним кликом. Макрорекордер выдал:

Selection.Range.HighlightColorIndex = wdYellow

Однако при использовании этого макроса желтым становится только последний выделенный фрагмент. Как изменить команду, чтобы пожелтели все пять выделенных?

[Вождь]

Например, поиском:

Sub A()
    Options.DefaultHighlightColorIndex = wdYellow
    With Selection.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Forward = True
        .Wrap = wdFindStop
        '.Text = "^t"
        .Replacement.Highlight = True
        .Format = True
        .Execute Replace:=Word.wdReplaceAll
    End With
End Sub

[caute]

что-то этот код не работает, ноль реакции (Word 2003)
'.Text = "^t" - а что эта строка делает?

[Казанский]

У меня тоже не сработало (Word 2007). Но направление мысли правильное. Я записал команду поиска замены "*" на пусто + выделение цветом, подстановочные знаки.
При запуске красит все выделенные фрагменты, в тот цвет, который выбран.

Sub Макрос4()
'
' Макрос4 Макрос
'
'
  Selection.Find.ClearFormatting
  Selection.Find.Replacement.ClearFormatting
  Selection.Find.Replacement.Highlight = True
  With Selection.Find
    .Text = "*"
    .Replacement.Text = ""
    .Forward = True
    .Wrap = wdFindStop
    .Format = True
    .MatchCase = False
    .MatchWholeWord = False
    .MatchAllWordForms = False
    .MatchSoundsLike = False
    .MatchWildcards = True
  End With
  Selection.Find.Execute Replace:=wdReplaceAll
End Sub

[caute]

работает, спасибо!

[caute]

работает, спасибо!
не понял, как тут поменять цвет, но это не так уж мне и надо

[Казанский]

Добавьте в начало как у Вождя

Options.DefaultHighlightColorIndex = wdYellow

[Вождь]

Сообщение от caute

что-то этот код не работает, ноль реакции (Word 2003)
'.Text = "^t" - а что эта строка делает?

Опечатка. Надо "^?" - любой знак. Если заменить и убрать комментарий, то работает в Word 2003:

Sub A()
    Options.DefaultHighlightColorIndex = wdGreen ' цвет менять здесь
    With Selection.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Forward = True
        .Wrap = wdFindStop
        .Text = "^?"
        .Replacement.Highlight = True
        .Format = True
        .Execute Replace:=Word.wdReplaceAll
    End With
End Sub

Можно и так:

Sub A2()
    Options.DefaultHighlightColorIndex = wdRed ' цвет менять здесь
    With Selection.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Forward = True
        .Wrap = wdFindStop
        .MatchWildcards = True
        .Text = "*"
        .Replacement.Highlight = True
        .Format = True
        .Execute Replace:=Word.wdReplaceAll
    End With
End Sub

[Казанский]

При поиске "^?" без подстановочных знаков или "*" с подстановочными знаками поиск-замена происходит по одному символу, что при большом размере выбранного текста приводит к торможению. В строке состояния выводится, например, "300 изменений" (по числу символов).
Я пытался найти способ сделать поиск "жадным" (в терминах regular expressions - greedy), чтобы он находил весь выделенный фрагмент. Использование "?@" или "?{1;}" в режиме подстановочных знаков результата не дает. Получилось при использовании "[!^01]{1;}" (символ с кодом 1 вряд ли встретится в тексте).
Оказалось, что в этом случае размер найденного куска составляет максимум 255 символов. То есть если каждый из выделенных фрагментов будет не более 255 символов, "изменений" будет столько, сколько фрагментов. Если фрагмент окажется длиннее 255 символов, в нем произойдет 2 и более изменений.
Но все же так заметно быстрее, чем по одному символу.

[Вождь]

Сообщение от Казанский

...символ с кодом 1 вряд ли встретится в тексте...

Этим символом Word метит место вставки объекта

Сообщение от Казанский

...длиннее 255 символов...

255 - это общее ограничение поиска (Find.Text, Replacement.Text)