InputBox выдает ошибку

[serikov]

Всем доброго дня!
Посмотрите в чем у меня ошибка. При нажатии cancel вылетает рантаймовская 13 ошибка.

Private Sub CallUserform3_Click() 'select department via password
beg: psw = InputBox("Введите пароль вашего цеха")
Select Case psw
Case 1
dept = "ЦМИ"
Sheets("lists").Range("b2..b5").Nam e = "ceh"
Case 2
dept = "ЦСИ"
Sheets("lists").Range("c2..c5").Nam e = "ceh"
Case 3
dept = "ЦЗИ"
Sheets("lists").Range("d2..d5").Nam e = "ceh"
Case Else
GoTo beg
End Select

UserForm5.Caption = dept
UserForm5.Calendar.Value = Date
UserForm3.Hide
UserForm5.lbl_dept_name = dept
UserForm5.Show


End Sub

Спасибо.

[EducatedFool]

Может, переменная psw определена как числовая?
Определите переменную как String или Variant - и ошибки не будет.

Range("c2..c5")

Думал, что знаю синтаксис VBA...
Даже не предполагал, что так можно задавать диапазон ячеек.
Похоже, в Microsoft предусмотрели все возможные варианты записи адреса диапазона... (точек, как выяснилось, можно ставить сколько угодно)

[serikov]

Спасибо. Но проблема в другом. Ошибка выскакивает при отказе от ввода пароля прп нажатии кнопки cancel. Так код работает и ошибок не выдает. Если пишу в код обработчика ошибок, то получаю зацикливание процедуры, то есть пока код не введешь будешь тыкакаться в кнопку. Тоже не совсем гут.

[EducatedFool]

Если пишу в код обработчика ошибок, то получаю зацикливание процедуры, то есть пока код не введешь будешь тыкакаться в кнопку. Тоже не совсем гут.

Извините, но этот алготиртм придумали вы...
Скажите, как должно работать, - сделаем.

Попробуйте так:

Private Sub CallUserform3_Click()    'select department via password
    txt = InputBox("Введите пароль вашего цеха")
    Select Case txt
        Case 1: dept = "ЦМИ"
        Case 2: dept = "ЦСИ"
        Case 3: dept = "ЦЗИ"
        Case Else: Exit Sub ' для выхода из процедуры
            ' или End 'для остановки всех макросов
    End Select
    Sheets("lists").Range("b2..b5").Name = "ceh"

    UserForm5.Caption = dept
    UserForm5.Calendar.Value = Date
    UserForm3.Hide
    UserForm5.lbl_dept_name = dept
    UserForm5.Show
End Sub

[serikov]

Я вроде бы понятно пишу, проблема возникает при отказе от ввода пароля в inputbox, то есть пользователь вместо "ОК" нажимает кнопку "cancel". В этот момент вылетает ошибка. Ее и нужно победить, все остальное работает. Диалог ОК-cancel это стандартная VBA панелька. Почему ее вырубает ВОТ ВОПРОС.

[The_Prist]

А так:

Private Sub CallUserform3_Click()

beg:     psw = InputBox("Введите пароль вашего цеха")
    Select Case psw
    Case 1
        dept = "ЦМИ"
        Sheets("lists").Range("b2..b5").Name = "ceh"
    Case 2
        dept = "ЦСИ"
        Sheets("lists").Range("c2..c5").Name = "ceh"
    Case 3
        dept = "ЦЗИ"
        Sheets("lists").Range("d2..d5").Name = "ceh"
    Case ""
        If MsgBox("Не введен код! Закрыть форму?", vbYesNo) = vbYes Then
            End
        Else: Exit Sub
        End If
    Case Else
        MsgBox "Неверный код!", vbYesNo
        GoTo beg
    End Select

    UserForm5.Caption = dept
    UserForm5.Calendar.Value = Date
    UserForm3.Hide
    UserForm5.lbl_dept_name = dept
    UserForm5.Show
End Sub

[serikov]

Не помогло....

[The_Prist]

Сообщение от serikov

Не помогло....

Правда? У Вас переменной psw какой тип данных назначен? Что за ошибка? На какой строке ошибка?

Может имеет смысл так сделать?

Private Sub CallUserform3_Click()
dim psw as long
beg:     psw = val(InputBox("Введите пароль вашего цеха"))
    Select Case psw
    Case 1
        dept = "ЦМИ"
        Sheets("lists").Range("b2..b5").Name = "ceh"
    Case 2
        dept = "ЦСИ"
        Sheets("lists").Range("c2..c5").Name = "ceh"
    Case 3
        dept = "ЦЗИ"
        Sheets("lists").Range("d2..d5").Name = "ceh"
    Case 0
        If MsgBox("Не введен код! Закрыть форму?", vbYesNo) = vbYes Then
            End
        Else: Exit Sub
        End If
    Case Else
        MsgBox "Неверный код!", vbYesNo
        GoTo beg
    End Select

    UserForm5.Caption = dept
    UserForm5.Calendar.Value = Date
    UserForm3.Hide
    UserForm5.lbl_dept_name = dept
    UserForm5.Show
End Sub

[Skif-F]

А в других местах этого же файла InputBox работает нормально? Если нет, то попробуй в другой книге.
Если в другой книге работает, значит что-то у тебя с "References", а если не работает, то дело серьёзно!

[serikov]

The_Prist большой респект. Удалось обойти! СПАСИБО!!!!