Варианты поиска номера строки

[LeCrunch]

Использую большой макрос, который производит последовательную обработку из Excel документов Word (с поздней привязкой). В числе прочих операций нахожу в документе по нужному слову строку, выделяю её и произвожу дальнейшие необходимые действия с ней (просто обратиться по номеру не получается, т.к. из-за различия документов, этот № может меняться).

...
With wdDoc.Content.Find
    .ClearFormatting
    .Text = "СЛОВО"
    .Forward = True
    .wrap = 1 ' Const wdFindContinue = 1
    .MatchWildcards = False
    If .Execute = True Then
        .Parent.Select
        WDApp.Selection.expand 5 ' Const wdLine = 5
        Stroka = WDApp.Selection.Text
    End If
End With
...

Однако столкнулся с тем, что при обработке большого количества документов (от сотни и более) макрос начинает сбоить и давать ошибочные результаты, относящиеся именно к результатам этого участка кода, что может даже приводить к некорректному завершению работы Word (при этом нужные рекомендации обеспечиваются - документы/объекты закрываются, объекты обнуляются/уничтожаются, но - ...)

Хотелось бы обойти эту проблему - т.е. просьба подсказать ещё варианты нахождения № строки по нужному слову в документе Word

[Вождь]

Попробуйте без Selection. Например так:

Dim wdRange As Word.Range
    
    Set wdRange = wdDoc.Range(0, 0)
    With wdRange.Find
        .ClearFormatting
        .Replacement.ClearFormatting
        .Forward = True
        .Wrap = 1 ' Word.WdFindWrap.wdFindContinue
        .Text = "СЛОВО"
        .Execute Replace:=0 '  Word.WdReplace.wdReplaceNone
    End With
    If wdRange.Find.Found = True Then
        wdRange.SetRange Start:=wdRange.Words.First.Start, _
                         End:=wdRange.Words.Last.End
        Stroka = wdRange.Text
    End If

[LeCrunch]

Спасибо за идею, но т.к. нужно выделять не слово, а всю строку, то отредактировал и макрос работает пока без сбоев

With wdDoc
...
    Dim wdRng1 As Object
    Set wdRng1 = .Range
    With wdRng1
        If .Find.Execute("СЛОВО") Then _
            .expand Unit:=3 ' Const wdSentence = 3
        Stroka = .Text
    End With
...
End With

И вопросы - в частности:
Т.к. автоматизация идет в поздней привязке, то переменную wdRng1 (в Watches видную при выполнении макроса как Variant/Object/Range) пришлось объявить объектом (на Word.Range, WDApp.Range, wdDoc.Range - ругается..) - это правильно?
У меня еще в нескольких местах будет похожий поиск - т.е. лучше для каждого делать wdRng свой?

И несмотря на данное решение - действительно ли, что при общих советах для Excel VBA избегать Select, Selection, Copy, для Word VBA наличие в правильном коде подобных команд - это нормальное явление?

[Вождь]

Сообщение от LeCrunch

...на Word.Range, WDApp.Range, wdDoc.Range - ругается...

Подключите Word-овские библиотеки к своему проекту в Excel, не будет ругаться. А так - да, надо объявлять как Object или Variant.

Сообщение от LeCrunch

...лучше для каждого делать wdRng свой...

Можно и один. Вообще, надо смотреть код, и оптимизировать...

Сообщение от LeCrunch

...при общих советах для Excel VBA избегать ...Selection...

Я стараюсь избегать Selection в Word, где возможно. По-моему, так и быстрее и надежнее.