Наличие таблицы в БД

[Langoria]

Как написать на VBA в обработчике кнопки запрос:

если таблица с именем Name содержится в базе данных, то удалить её

[Teslenko_EA]

Здравствуйте Langoria.
Удалить таблицу можно подобным кодом:

Sub delTable()
    Const sQ = "DROP TABLE Name"
    On Error Resume Next
    CurrentDb.Execute sQ
    Select Case Err.Number
    Case 0: 'удаление выполнено
    Case 3376: 'таблица не существует
    Case 3211: 'таблица заблокирована (используется)
    End Select
    
'    Debug.Print Err.Number, Err.Description
'    MsgBox Err.Number & vbCrLf & Err.Description
    Err.Clear
End Sub

И хотя он не соответствует задаче "..если таблица .. содержится в базе данных, то удалить её .."
(т.е. не выполняет проверку существования таблицы, а сразу пытается удалить)
результат получается ожидаемый, его проверить можно прочитав код возвращаемой ошибки.

Евгений.
P.S. выкладывая вопрос не забывайте обращаться к тем кому Вы его адресуете,
не знаете как - можно просто поздоровавшись.

[Vovka_Ya]

Всем Доброго Дня!
Teslenko_EA, Вам отдельного, Доброго Дня!

У меня такой вопрос по предложенной процедуре - как ей передать аргументом имя таблицы, которую нужно удалить и после этого использовать его (имя таблицы) в SQL запросе?
Весь день мучаюсь, получаю ошибку Constant Expression Required. Пробовал и кавычки, и ByVal, и много разных вариантов. Чета все не клеится.

    Private Sub Restore_Click()
 'query the procedure for tblTest deleting
        delTable tblTest

Sub delTable(Name As String)
    Const sQ = "DROP TABLE " & Name & ""
    On Error Resume Next
    CurrentDb.Execute sQ
    Select Case Err.Number
    Case 0: 'удаление выполнено
    Case 3376: 'таблица не существует
    Case 3211: 'таблица заблокирована (используется)
    End Select
    
'    Debug.Print Err.Number, Err.Description
'    MsgBox Err.Number & vbCrLf & Err.Description
    Err.Clear
End Sub

Спс

[Vovka_Ya]

Вроде разобрался, вот так работает:

    Private Sub Restore_Click()
 'query the procedure for tblTest deleting
        delTable "[tblTest]"

Sub delTable(Name As String)
    Dim sQ As String
    sQ = "DROP TABLE " & Name
    On Error Resume Next
    CurrentDb.Execute sQ
    Select Case Err.Number
    Case 0: 'удаление выполнено
    Case 3376: 'таблица не существует
    Case 3211: 'таблица заблокирована (используется)
    End Select
    
'    Debug.Print Err.Number, Err.Description
'    MsgBox Err.Number & vbCrLf & Err.Description
    Err.Clear
End Sub

Спс

[Teslenko_EA]

Здравствуйте Vovka_Ya.
"..мучаюсь, получаю ошибку Constant Expression Required.."
"..Вроде разобрался.." - это хорошо что Вы поняли что константу изменить нельзя.
Но для практического применения лучше создать функцию и по её результату продолжать или прекращать выполнение кода

Sub Restore_Click()
        If Not delTable("[tblTest]") then Exit sub
        ...

Function delTable(sName As String) As Boolean
    Const sQ = "DROP TABLE " 
    On Error Resume Next
    CurrentDb.Execute sQ + sName
    If Err.number =0 Then delTable =true else Err.clear
End function

совет : откажитесь от использования зарезервированных в слов (в Вашем случае Name)
в качестве имен своих объектов и переменных, это избавит от проблем в будущем.
Евгений.

P.S.
на интересующую тему можно сослаться, не выкладывая в чужой теме свой вопрос,
придерживайтесь правила "один вопрос=одна тема".
все свои сообщения я подписываю в надежде, что обращаться ко мне будут по имени.

[Vovka_Ya]

Евгений, благодарю за рекомендацию.

P.S. Новую тему создавать не стал, т.к. цель была таже, что и у Langoria, но немного дополненная/уточненная
BR

[Myhaylo]

Имена всех существующих таблиц можно узнать так:

SELECT MSysObjects.Name FROM MSysObjects WHERE MSysObjects.Type=1

Т. е. можно обойтись и без обработчика ошибок:

Sub delTable(sName As String)
Iif Not IsNull(DLookup("Name", "MSysObjects", "Type=1 AND Name=""" + sName + """")) Then CurrentDb.Execute "DROP TABLE " & sName
End Sub

[Teslenko_EA]

Здравствуйте Myhaylo.
Предложенный Вами способ хорош, но утверждать: "..обойтись и без обработчика ошибок.." я бы не стал
Ошибку 3376 Ваша конструкция обходит, а как быть с другими возможными (?) например 3211,
для каждой создавать собственный обработчик?
думаю обработчик ошибок в подобной процедуре имеет право на жизнь.
Евгений.

P.S. для удобочитаемости выкладываемый код заключайте в тэги [соde] ... [/соde]
для этого на панели инструментов размещена кнопка #.