div, что не так?

[220Volt]

Доброго дня!

      .386
      .model flat, stdcall
      option casemap :none   ; case sensitive
;#########################################################################
    .data
    divisor_8    db 10d       
    divisor_16   dw 10d     
    divisor_32   dd 10d 
;#########################################################################
    .code
start:
    mov eax, 16d
    div byte ptr [divisor_8]

    mov eax, 16d
    div word ptr [divisor_16]  ;Происходит какая-то ошибка, дальше не идет
    
    mov eax, 16d
    div dword ptr [divisor_32]
;-------------------------------------------------------------------------
end start

Отладчик замирает на div word ptr [divisor_16], дальше не идет. Я что-то не так написал или процессор не поддерживает такую инструкцию?

[Stilet]

http://www.kolasc.net.ru/cdo/program...mbler/div.html
Т.е.

    mov eax, 16d
    xor edx,edx

[Mikl___]

    mov ax, 16d
    div [divisor_8]
    xor dx,dx
    mov ax, 16d
    div [divisor_16]  ;Происходит какая-то ошибка, дальше не идет
    xor edx,edx
    mov eax, 16d
    div [divisor_32]

[220Volt]

Благодарю за ответы. xor dx,dx помогает, не понимаю почему (только разбираюсь с ассемблером). Не могли бы объяснить причину?
П.с. я понял что xor dx, dx обнуляет dx.

[Stilet]

Не могли бы объяснить причину?

А по той ссылке почитать что я дал?

если делитель размером в слово, то делимое должно быть расположено в паре регистров dx:ax

Поскольку перед делением ты не контролируешь значение в DX то соответственно в нем содержится какой то мусор, оставшийся от прошлых вычислений. А в купе с АХ это дает огромнейшее число, которое в свою очередь вызывает арифметическое переполнение.
Например в Ах число 10 в ДХ какое нить 1234656789
Итого: 123465678910. У процессора просто пупок развязывается когда он с такими числами пытается работать

[220Volt]

Сообщение от Stilet

А по той ссылке почитать что я дал?

Да

Сообщение от Stilet

Статья ошибочна, рекомендую изучить пример под отладчиком:

      .386
      .model flat, stdcall
      option casemap :none   ; case sensitive
;#########################################################################
    .data      
    divisor_16   dw 0fh 
    divisor_8   db 0fh       
;#########################################################################
    .code
start:
    xor edx, edx
    mov eax, 0ffh
    div byte ptr [divisor_8]

    xor edx, edx
    mov eax, 0ffffh
    div word ptr [divisor_16]

    mov edx, 0ffh
    mov eax, 0ffh
    div word ptr [divisor_16]

;-------------------------------------------------------------------------
end start

[Mikl___]

220Volt

Статья ошибочна, рекомендую изучить пример под отладчиком

и чем же справочник Юрова-Хорошенко тебе не угодил? и что нового можно увидеть в отладчике?

	xor edx, edx <-- для чего? делится содержимое ТОЛЬКО ах на содержимое divisor_8
	mov eax, 0ffh
	div byte ptr [divisor_8]; FF/F=11h в al=11h остаток ah=0
	xor edx, edx <-- здесь можно делать xor dx,dx -- делим содержимое dx:ax на divisor_16
	mov eax, 0ffffh <-- здесь можно mov ax,0ffffh
	div word ptr [divisor_16]; FFFF/F=1111h в ax =1111h остаток dx=0

всё в соответствии с тем, что написано в справочнике

• если делитель размером в байт, то делимое должно быть расположено в регистре ax. После операции частное помещается в al, а остаток — в ah;
• если делитель размером в слово, то делимое должно быть расположено в паре регистров dx:ax, причем младшая часть делимого находится в ax. После операции частное помещается в ax, а остаток — в dx;
• если делитель размером в двойное слово, то делимое должно быть расположено в паре регистров edx:eax, причем младшая часть делимого находится в eax. После операции частное помещается в eax, а остаток — в edx.

    mov edx, 0ffh
    mov eax, 0ffh
    div word ptr [divisor_16]; содержимое dx:ax на divisor_16

делим на калькуляторе FF00FF/F=11.0011h получили число больше, чем может войти в 16-ти разрядный регистр АХ — в результате переполнение и, как написал Stilet "У процессора просто пупок развязывается когда он с такими числами пытается работать" к этому справочнику не хватает строк, которые есть у другого классика по ассемблеру — Питера Абеля

• если делитель размером в байт, то делитель не должен быть больше или равен содержимому регистра AH;
• если делитель размером в слово, то делитель не должен быть больше или равен содержимому регистра DX;
• если делитель размером в двойное слово, то делитель не должен быть больше или равен содержимому регистра EDX.

ситуация излечивается следующим образом

.data
divisor_32   dd 0fh
.code
	mov edx, 0
	mov eax, 0ff00ffh
	div dword ptr [divisor_32]; FF00FF/0F=110011h частное EAX=110011h остаток EDX=0

[vadimych]

220Volt, с индукцией у Вас явно нелады.

[220Volt]

Mikl___
Если вас не затруднит, покажите ситуацию, когда делимое находится в паре ригистров ax и dx (с корректным завершением).

[220Volt]

Я понял, был не прав – статья верна. Спасибо за ответы