Перевод из FASM в I8086

[flu3xz]

Доброго времени суток, нужно перевести код программы из TASM в программу, которая выполнялась бы в эмуляторе i8086.(Данная программа в словах с четным номером должна изменять порядок букв на обратный.)

.686             ; директива визначення типу мікропроцесора
.model flat,stdcall  ; завдання лінійної моделі пам’яті
                     ; та угоди ОС Windows
option casemap:none  ; відмінність малих та великих літер
include \masm32\include\windows.inc
include \masm32\include\kernel32.inc
;include \masm32\include\fpu.inc
include \masm32\include\user32.inc        ; для MessageBox
includelib \masm32\lib\user32.lib
includelib \masm32\lib\kernel32.lib
BSIZE equ 30 
.data
mas1        db  'abc wer tyd oop yhf tdd kjs llj'
        db  0dh, 0ah
;mas2       db  31 dup(0)
cWritten    dd  ?
stdout      dd  ?
.code
_Start:
    invoke  GetStdHandle, STD_OUTPUT_HANDLE
    mov stdout, eax
    invoke  WriteConsoleA, stdout, ADDR mas1, sizeof mas1+2, ADDR cWritten, 0
 
    cld             ; напрям- вгору
    mov ecx, sizeof mas1    ;* длина строки с массивом
    mov dl, 01010101b       ;* чёт/нечет
    mov bl, ' '         ;* пробел - разделитель элементов массива
    mov edi, offset mas1    ; адреса 1-го масиву
@@scan:
    test    ecx, ecx
    mov al, bl          ; поместить пробел в al
    jz  @@end_scan      ; выйти, если достигнут конец строки (массива)
    mov esi, edi        ; сохранить в esi указатель на начало текущего слова
    repne   scasb           ; найти следующий пробел (или конец массива)
    je  @F          ; если пробел найден - перепрыгнуть
    inc edi         ; подправить edi для правильного вычисления длины слова (если достигнут конец строки)
@@:
    ror dl, 1           ; повернуть "барабан" в dl, соcтоящий из единичных и нулевых бит на одну позицию
    jc  @@scan          ; если перенесён единичный бит, то слово нечетное - продолжить сканирование
    push    ecx
    push    edi
    mov ecx, edi
    sub ecx, esi        ; ecx=количеству букв в слове плюс пробел
    dec edi         ; [edi]=пробел (или символ за концом строки)
    dec ecx         ; ecx=количеству букв в слове
    dec edi         ; [edi]=последний символ слова
    shr ecx, 1          ; ecx=количеству необходимых обменов букв
    jz  @@pop
@@:
    mov al, [esi]
    xchg    al, [edi]
    mov [esi], al
    dec edi
    inc esi
    dec ecx
    jnz @B
@@pop:
    pop edi
    pop ecx
    jmp @@scan
@@end_scan:
 
    invoke  WriteConsoleA, stdout, ADDR mas1, sizeof mas1+2, ADDR cWritten, 0
 
    push    1800h
    call    Sleep                  ; API-функция задержки изображения
 
    invoke  ExitProcess, 0
    end _Start

[p51x]

а фасм то где?

[flu3xz]

.model flat
разве не идет как у tasm? да и последующее написание

[flu3xz]

Сообщение от flu3xz

invoke WriteConsoleA, stdout, ADDR mas1, sizeof mas1+2, ADDR cWritten, 0

такое написание я в tasm видел.

[flu3xz]

Сообщение от p51x

а фасм то где?

извиняюсь это tasm не так написал.

[Pavia]

А разве в тасаме есть invoke ?

[p51x]

include \masm32\include\windows.inc

ни на что не наводит?..

[flu3xz]

я учусь работать только в эмуляторе 8086, и при виде таких символов я понятия не имею что с этим делать, собственно поэтому и обратился сюда

[7in]

.model small  ; завдання лінійної моделі пам’яті
                     ; та угоди ОС Windows
.stack 100h
.data
mas1        db  'abc wer tyd oop yhf tdd kjs llj'
Lmas1=$-mas1
        db  0dh, 0ah, '$'
;mas2       db  31 dup(0)
cWritten    dd  ?
stdout      dd  ?

.code
_Start:

    mov ax,@data
    mov ds,ax
    mov es,ax
    
    mov ah,9
    lea dx,mas1
    int 21h        ; вывод
 
    cld             ; напрям- вгору
    mov cx, Lmas1    ;* длина строки с массивом
    mov dl, 01010101b       ;* чёт/нечет
    mov bl, ' '         ;* пробел - разделитель элементов массива
    mov di, offset mas1    ; адреса 1-го масиву
@@scan:
    test    cx, cx
    mov al, bl          ; поместить пробел в al
    jz  @@end_scan      ; выйти, если достигнут конец строки (массива)
    mov si, di        ; сохранить в esi указатель на начало текущего слова
    repne   scasb           ; найти следующий пробел (или конец массива)
    je  @@1          ; если пробел найден - перепрыгнуть
    inc di         ; подправить edi для правильного вычисления длины слова (если достигнут конец строки)
@@1:
    ror dl, 1           ; повернуть "барабан" в dl, соcтоящий из единичных и нулевых бит на одну позицию
    jc  @@scan          ; если перенесён единичный бит, то слово нечетное - продолжить сканирование
    push    cx
    push    di
    mov cx, di
    sub cx, si        ; ecx=количеству букв в слове плюс пробел
    dec di         ; [edi]=пробел (или символ за концом строки)
    dec cx         ; ecx=количеству букв в слове
    dec di         ; [edi]=последний символ слова
    shr cx, 1          ; ecx=количеству необходимых обменов букв
    jz  @@pop
@@2:
    mov al, [si]
    xchg    al, [di]
    mov [si], al
    dec di
    inc si
    dec cx
    jnz @@2
@@pop:
    pop di
    pop cx
    jmp @@scan
@@end_scan:
 
    mov ah,9
    lea dx,mas1
    int 21h        ; вывод

    mov ax,8600h
    mov cx,100
    xor dx,dx
    int 15h         ; пауза
 
    mov ax,4C00h
    int 21h         ; выход

end _Start

Комменты самостоятельно правь уже.
p.s. По сути, поменял все eax,ecx,esi... на ax,cx,si...
Ну и переписал заголовки, инициализацию ds,es, вывод, паузу, выход... всё работает

[flu3xz]

огромное спасибо!