не могу найти ошибку

[Nix128]

Здравствуйте!
помогите пожалуйста разобраться с кодом.

Private Sub Worksheet_Change(ByVal Target As Range)

    If Target.Column = 2 Then
Sheets("Счет").Select
n1 = 19
Dim tovar(20)
Dim kol(20)
Dim rub(20)
For n = 0 To 20
tovar(n) = Cells(n1, 2)
kol(n) = Cells(n1, 7)
rub(n) = Cells(n1, 8)
If tovar(n) = "" Then n = 20
n1 = n1 + 1
Next n
n1 = 16

For n = 0 To 20
фактура.Cells(n1, 3).Value = kol(n)
фактура.Cells(n1, 4).Value = rub(n)
If tovar(n) = "" Then n = 20
n1 = n1 + 1
Next n
n1 = 22
Sheets("Накладная").Select
For n = 0 To 20
Cells(n1, 10) = kol(n)
Cells(n1, 11) = rub(n)
If tovar(n) = "" Then n = 20
n1 = n1 + 1
Next n
inn:
Sheets("Счет").Select
inn = Cells(13, 3)
Nam = Cells(12, 3)
Sheets("Счет-фактура").Select
Cells(10, 2) = Nam
Cells(12, 2) = inn
Sheets("Счет").Select
End If
End Sub

при записи на лист данных код работает с начала.
помогите пожалуйста.



___________
Код нужно оформлять по правилам:
тегом [CODE]..[/СODE] (это кнопочка с решёточкой #)
Не забывайте об этом!
Модератор.

[Alex_ST]

Сразу, не вникая, что и куда пишется:
1. А где у вас заполняются данными массивы?
Вы же их только объявляете

Dim tovar(20)
Dim kol(20)
Dim rub(20)

но не заполняете. Поэтому сразу идёт выход из всех циклов, которые, кстати, лучше делать не присваиванием счётчикам цикла последнего значения, а операторами Exit For

2. Как-то странно вы пытаетесь обратиться к ячейкам листа "фактура"

фактура.Cells(n1, 3).Value = kol(n)
фактура.Cells(n1, 4).Value = rub(n)

может быть, всё-таки

Sheets("фактура").Cells(n1, 3).Value = kol(n)
Sheets("фактура").Cells(n1, 4).Value = rub(n)

[Nix128]

For n = 0 To 20
tovar(n) = Cells(n1, 2)
kol(n) = Cells(n1, 7)
rub(n) = Cells(n1, 8)
If tovar(n) = "" Then n = 20
n1 = n1 + 1
Next n
вот здесь.
но почему идет выход на начало програмы
когда я хочу записать в ячейку листа фактура.

[Alex_ST]

Без примера гадать трудно...
Ну, например так:
Код у вас размещён в стандартном модуле или модуле листа?
Выражение типа

tovar = Cells(1, 2)

, размещённое в коде модуля листа, вернёт в tovar значения из ячейки В1 ЭТОГО ЖЕ ЛИСТА!
Если код размещён в стандартном модуле, то ОБЯЗАТЕЛЬНО нужно перед Cells указывать, с какого листа брать данные.
Пройдите код в пошаговом режиме. Проверьте значения, заносимые в массивы. скорее всего у вас сразу же в первом проходе цикла пишется

tovar(0)=""

, а потому и идёт выход из цикла.

[Nix128]

посмотрите косяк.Пожалуйста!!

[Alex_ST]

Ну, например, так:

Private Sub Worksheet_Change(ByVal Target As Range)
   Dim TOVAR As Range, KOLVO As Range, CENA As Range
   Dim INN, NAM As String
   If Not Intersect(Target, Range("B19:B38")) Is Nothing _
      Or Not Intersect(Target, Range("G19:G38")) Is Nothing _
      Or Not Intersect(Target, Range("H19:H38")) Is Nothing Then

      With Sheets("Счет")
         INN = .Range("C13")
         NAM = .Range("C12")
         Set TOVAR = .Range("B19:B38")
         Set KOLVO = .Range("G19:G38")
         Set CENA = .Range("H19:H38")
      End With

      With Sheets("Счет-фактура")
         .Range("B10").Value = NAM
         .Range("B12").Value = INN
         .Range("A16:A35").Value = TOVAR.Value
         .Range("C16:C35").Value = KOLVO.Value
         .Range("D16:D35").Value = CENA.Value
      End With

      With Sheets("Накладная")
         .Range("B22:B41").Value = TOVAR.Value
         .Range("J22:J41").Value = KOLVO.Value
         .Range("K22:K41").Value = CENA.Value
      End With

   End If
End Sub

[Nix128]

Большое спасибо.
Но я вроде тоже нашел надо просто отключить обработку событий.
но Ваша прога намного лучше
Еще раз СПАСИБО.

Тема закрыта.

[Alex_ST]

Ну, и ещё в качестве бонуса:
- подправил формулы (СУММ короче, чем много плюсиков)
- добавил очень удобную пользовательскую функцию для вывода суммы прописью (но чтобы она работала, в Ёкселе должны быть разрешены макросы)

P.S. Формулы я обычно в своих таблицах выделяю синим шрифтом: на распечатке всё равно не видно, а на дисплее видно, куда данные не нужно вносить с клавиатуры.

[Nix128]

Огромное спасибо выручил.