Выборка данных

[Liilla]

Добрый день!
Задача: есть данные в Лист 1 и данные в Лист 2, необходимо сравнить их и отсеить дубликаты. И в Листе 3 отразить лишь данные ячеек, которые не идентичны с дубликатами в Листе1 и Листе2.
Лист 1(86,88,99,93,87,94)
Лист 2(89,94,97,86,77,78)
Лист 3(88,99,93,87,89,97,77,78)

[vikttur]

Мне файлы переводить жалко. Свой дадите?

[Hugo121]

Очень родственная задача - можно брать макросы и чуть переделать под эту задачу:
http://www.planetaexcel.ru/forum.php?thread_id=27042

[Liilla]

конечно

[vikttur]

Раз уж назвался груздем...

[Liilla]

Большое спасибо, за ответы, я тогда попробую все варианты отбора

[Hugo121]

Вот, скомпоновал из двух макросов Николая по ссылке выше.
В примере запускается по кнопке.
Результат не сортирован, можно в принципе кодом массив отсортировать, или после выгрузки уже на листе. Это если нужно.

Алгоритм такой -
1.Берём один диапазон в массив, перекладываем всё в словарь.
2.Берём в массив второй диапазон (перезаписываем в этот же массив, заменяя уже ненужное содержимое).
3.Создаём пустой массив rez для результатов - по длине как сумма этих двух массивов, чтоб хватило места в любом случае.
3.Перебором массива x сверяем со словарём - если такого элемента в словаре нет, то пишем в массив результатов, если есть - то удаляем из словаря (тут узкое место - повторов в x быть не должно, иначе нужно доработать код).
4.Перебором словаря дописываем в rez оставшиеся в словаре данные.
5.Выгружаем результат.


P.S. Лучше такой вариант (http://www.programmersforum.ru/attac...d=1307206034):

Option Explicit

Sub Liilla()
    Dim x, rez(), i&, j&, oDict1 As Object, oDict2 As Object, el

    Set oDict1 = CreateObject("Scripting.Dictionary")
    oDict1.CompareMode = vbTextCompare
    Set oDict2 = CreateObject("Scripting.Dictionary")
    oDict2.CompareMode = vbTextCompare

    x = Sheets("Лист1").Range("A2:B" & Sheets("Лист1").Cells(Rows.Count, 1).End(xlUp).Row).Value
    For i = 1 To UBound(x): oDict1.Item(x(i, 1)) = x(i, 2): Next

    x = Sheets("Лист2").Range("A2:B" & Sheets("Лист2").Cells(Rows.Count, 1).End(xlUp).Row).Value
    For i = 1 To UBound(x): oDict2.Item(x(i, 1)) = x(i, 2): Next

    ReDim rez(1 To oDict1.Count + oDict2.Count, 1 To 2)

    For Each el In oDict1.keys
        If Not oDict2.Exists(el) Then
            j = j + 1
            rez(j, 1) = el
            rez(j, 2) = oDict1.Item(el)
        End If
    Next

    For Each el In oDict2.keys
        If Not oDict1.Exists(el) Then
            j = j + 1
            rez(j, 1) = el
            rez(j, 2) = oDict2.Item(el)
        End If
    Next


If j = 0 Then Exit Sub

With Sheets("Лист3").[a2:b2].Resize(j)
    .ClearContents: .Value = rez
End With
End Sub

Принцип тот же, но сперва данные перекладываются в два словаря, чем исключается влияние повторов. Потом словари сверяются один с другим - отсутствующие перекладываются в результирующий массив.

[Liilla]

Большое спасибо, за код
Я единственное, написала пример некорректный. Вообще в строках еще значения всякие, а выборка проходит лишь по нескольким столбцам. Я в данный код пробовала добавить остальные столбцы, необязательно, что значения в них совпадают со значениями в других Листах , то есть остальная информация в строках, а выскакивает ошибка.

[Hugo121]

Вот, сколько раз говорили - давайте реальное расположение данных. Если бы сразу было всё ясно, код возможно был бы другой, ну а теперь приходится так выкручиваться (если колонок много, то немного муторно в код добавлять их обработку):

Option Explicit

Sub Liilla()
    Dim x, rez(), i&, j&, oDict1 As Object, oDict2 As Object, el

    Set oDict1 = CreateObject("Scripting.Dictionary")
    oDict1.CompareMode = vbTextCompare
    Set oDict2 = CreateObject("Scripting.Dictionary")
    oDict2.CompareMode = vbTextCompare

    x = Sheets("Лист1").Range("A2:C" & Sheets("Лист1").Cells(Rows.Count, 1).End(xlUp).Row).Value
    For i = 1 To UBound(x): oDict1.Item(x(i, 1)) = x(i, 2) & "|" & x(i, 3): Next

    x = Sheets("Лист2").Range("A2:C" & Sheets("Лист2").Cells(Rows.Count, 1).End(xlUp).Row).Value
    For i = 1 To UBound(x): oDict2.Item(x(i, 1)) = x(i, 2) & "|" & x(i, 3): Next

    ReDim rez(1 To oDict1.Count + oDict2.Count, 1 To 3)

    For Each el In oDict1.keys
        If Not oDict2.Exists(el) Then
            j = j + 1
            rez(j, 1) = el
            rez(j, 2) = Split(oDict1.Item(el), "|")(0)
            rez(j, 3) = Split(oDict1.Item(el), "|")(1)
        End If
    Next

    For Each el In oDict2.keys
        If Not oDict1.Exists(el) Then
            j = j + 1
            rez(j, 1) = el
            rez(j, 2) = Split(oDict2.Item(el), "|")(0)
            rez(j, 3) = Split(oDict2.Item(el), "|")(1)
        End If
    Next

If j = 0 Then Exit Sub

With Sheets("Лист3").[a2:c2].Resize(j)
    .ClearContents: .Value = rez
End With
End Sub