Макрос текущего времени и привязка его к кнопке

[Severny]

Доброго всем времени суток!
Решил вот написать макрос который проставляет текущее время и привязать его к кнопке (типа "Обновить")
Вот сам макрос для времени:

Sub ВставкаТекущегоВремени() ' Вставка текущего времени
    Set IR = Selection
    For Each iCell In IR
        ActiveCell.FormulaR1C1 = "=NOW()"
    Next
End Sub

Объясните пожалуйста почему он не проставляет ТДАТА во все ячейки выделеного диапазона?

[The_Prist]

Сообщение от Severny

Объясните пожалуйста почему он не проставляет ТДАТА во все ячейки выделеного диапазона?

Потому что Вы только в активную ячейку формулу проставляете. Несколько раз. Ровно столько раз, сколько будет пройден цикл. Найдите отличия.

Sub ВставкаТекущегоВремени() ' Вставка текущего времени
    Set IR = Selection
    For Each iCell In IR
        iCell.FormulaR1C1 = "=NOW()"
    Next
End Sub

А проще делать так, без цикла:

Sub ВставкаТекущегоВремени() ' Вставка текущего времени
    Selection.FormulaR1C1 = "=NOW()"
End Sub

[Severny]

Сообщение от The_Prist

Потому что Вы только в активную ячейку формулу проставляете. Несколько раз. Ровно столько раз, сколько будет пройден цикл.
...
А проще делать так, без цикла:

Sub ВставкаТекущегоВремени() ' Вставка текущего времени
    Selection.FormulaR1C1 = "=NOW()"
End Sub

Спасибо Вам!
Вы знаете, понял что у меня не правильно, но уже было позно, Вы ответили
Вот мое после доусовершенствования:

Sub ВставкаТекущегоВремени() ' Вставка текущего времени
    Set IR = Selection
    For Each iCell In IR
        Selection.FormulaR1C1 = "=NOW()"
        Selection.NumberFormat = "dd/mm/yyyy""//""h:mm:ss"
    Next
End Sub

Но послушаюсь Вашего совета, обойдусь без цикла.
А вопрос такого характера: как заставить этот макрос обновлятся каждую секунду, что бы получились идущие часы?

[The_Prist]

Сообщение от Severny

А вопрос такого характера: как заставить этот макрос обновлятся каждую секунду, что бы получились идущие часы?

Sub ВставкаТекущегоВремени() ' Вставка текущего времени
    Selection.FormulaR1C1 = "=NOW()"
    Selection.NumberFormat = "dd/mm/yyyy""//""h:mm:ss"
    Call Refresh_Time
End Sub
Sub Refresh_Time()
    ActiveSheet.Calculate
    Application.OnTime Now + TimeValue("00:00:01"), "Refresh_Time"
End Sub

Смысл в формуле теряется, если надо обновлять каждую секунду. :-) Можно сразу значения времени заносить в ячейки.

Dim rRng As Range
Sub ВставкаТекущегоВремени() ' Вставка текущего времени
    Set rRng = Selection: rRng = Now
    rRng.NumberFormat = "dd/mm/yyyy""//""h:mm:ss"
    Call Refresh_Time
End Sub
Sub Refresh_Time()
    rRng = Now
    Application.OnTime Now + TimeValue("00:00:01"), "Refresh_Time"
End Sub

[Severny]

Сообщение от The_Prist

Смысл в формуле теряется, если надо обновлять каждую секунду. :-) Можно сразу значения времени заносить в ячейки.

Dim rRng As Range
Sub ВставкаТекущегоВремени() ' Вставка текущего времени
    Set rRng = Selection: rRng = Now
    rRng.NumberFormat = "dd/mm/yyyy""//""h:mm:ss"
    Call Refresh_Time
End Sub
Sub Refresh_Time()
    rRng = Now
    Application.OnTime Now + TimeValue("00:00:01"), "Refresh_Time"
End Sub

Не обновляет почему-то каждую секунду.

[VictorM]

А если так, поместите в модуль Эта книга код

Sub Start()
    Call Refresh_Time
End Sub

теперь обновляет

[Severny]

Сообщение от VictorM

А если так, поместите в модуль Эта книга код

Sub Start()
    Call Refresh_Time
End Sub

теперь обновляет

Утвержтает, что не может найти макрос Refresh_Time.

[The_Prist]

Сообщение от Severny

Утвержтает, что не может найти макрос Refresh_Time.

Уже странно. Если так утверждает - значит у него есть на то основания.
Вы явно размещаете код не там, где надо. Код надо поместить в стандартный модуль. Затем просто запустить процедуру ВставкаТекущегоВремени. И будет Вам счастье.

[Severny]

Давайте начнем сначала:
Когда я вставляю этот код:

Sub ВставкаИдущегоВремени() ' Вставка текущего времени
    Dim rRng As Range
    Set rRng = Selection: rRng = Now
    rRng.NumberFormat = "dd/mm/yyyy""//""h:mm:ss"
    Call RefreshTime
End Sub

Sub RefreshTime()
    rRng = Now
    Application.OnTime Now + TimeValue("00:00:01"), "RefreshTime"
End Sub
Sub Start()
    Call RefreshTime
End Sub

в Эта книга пишет то что я описывал выше.
Если тот самый код вставляю в Module1 то Sub RefreshTime() выполняется но этого не видно в ячейке. Видно по мигающему с частотой в секунду курсору. Что я делаю не так?

[The_Prist]

Сообщение от Severny

в Эта книга пишет то что я описывал выше.
Если тот самый код вставляю в Module1 то Sub RefreshTime() выполняется но этого не видно в ячейке. Видно по мигающему с частотой в секунду курсору. Что я делаю не так?

Вы неверно вставляете в модуль объявление переменной:

Dim rRng As Range

Эта строка должа идти перед всеми процедурами модлуя(в области объявлений). А никак не внутри одной процедуры. Посмотрите внимательно выложенный мной код и найдите разницу в моем и Вашем с учетом написанного мной в этом посте про переменную.

Добавлю ликбез небольшой:
переменные разделяются на несколько типов по области действия: переменные модуля, переменные процедуры, переменные глобальные и переменные публичные.

Так вот: в нашем случае мы имеем дело - в Вашем коде с переменной процедуры. Т.е. Вы объявлили переменную rRng внутри процедуры ВставкаИдущегоВремени. А т.к. она объявлена через Dim(а не Static, но это другая история), то её значение стирается по завершении процедуры, в которой она объявлена. Таким образом, Вы один раз присваиваете значение этой переменной, меняете значение и процедура завершается, обнулив эту переменную.
Но ведь переменная эта у нас и в другой процедуре используется - RefreshTime. Вот и получается, что во второй процедуре Вы не можете изменить значение нужной ячейки, т.к. данные по ней уже стерты из памяти.

Если же объявить как я написал выше - в области объявлений - то значение переменной будет сохраняться во всех процедурах в пределах того модуля, внутри которого объявлена.