Функции VBA для проверки правописания

[tumanovalex]

Подскажите, пожалуйста, есть ли в VBA функции для проверки правописания. Хотелось бы попробовать программно проверить большой текстовой файл с русским тестом, найти в нем слова, отстуствующие в словаре или неправильно написанные, сохранить файл с комментариями и возможными вариантами замены этих слов.

[shanemac51]

в свое время стандартные F7 меня не устроили

была написана прога
-выделение слова
-автозапись новых в словарь
-просмотр словаря новых слов
-выявление грубятины
-перевод фамилий-имен-отч в Фамилий-Имен-Отч
-перевод ооокрона в ООО "Крона"(ооокрона набивалось без пробела)
-вставка стандартных кусков(согласовано, утверждаю, должности и лица)
гли00 переводился в Главный инженер Иванов И.И.

[tumanovalex]

А какие функции VBA отвечают за работу со словарем? Вы работали только со своим словарем (словарем пользователя) или со словарем Word?

[Aent]

CheckSpelling Method

See AlsoApplies ToExampleSpecificsCheckSpelling method as it applies to the Application and Global objects.

Checks a string for spelling errors. Returns a Boolean to indicate whether the string contains spelling errors. True if the string has no spelling errors.

expression.CheckSpelling(Word, _
   CustomDictionary, _
   IgnoreUppercase, _
   MainDictionary, CustomDictionary2, CustomDictionary3, CustomDictionary4, CustomDictionary5, CustomDictionary6, CustomDictionary7, CustomDictionary8, CustomDictionary9, CustomDictionary10)

expression Required. An expression that returns an Application or Global object.
Word Required String. The text whose spelling is to be checked.
CustomDictionary Optional Variant. Either an expression that returns a Dictionary object or the file name of the custom dictionary.
IgnoreUppercase Optional Variant. True if capitalization is ignored. If this argument is omitted, the current value of the IgnoreUppercase property is used.
MainDictionary Optional Variant. Either an expression that returns a Dictionary object or the file name of the main dictionary.
CustomDictionary2 – CustomDictionary10 Optional Variant. Either an expression that returns a Dictionary object or the file name of an additional custom dictionary. You can specify as many as nine additional dictionaries.

CheckSpelling method as it applies to the Document and Range objects.

Begins a spelling check for the specified document or range. If the document or range contains errors, this method displays the Spelling and Grammar dialog box (Tools menu), with the Check grammar check box cleared. For a document, this method checks all available stories (such as headers, footers, and text boxes).

expression.CheckSpelling(CustomDictionary, _
    IgnoreUppercase, _
    AlwaysSuggest, _
    CustomDictionary2, _
    CustomDictionary3, _
    CustomDictionary4, _
    CustomDictionary5, _
    CustomDictionary6, _
    CustomDictionary7, _
    CustomDictionary8, _
    CustomDictionary9, _
    CustomDictionary10)

expression Required. An expression that returns a Document or Range object.
CustomDictionary Optional Variant. Either an expression that returns a Dictionary object or the file name of the custom dictionary.
IgnoreUppercase Optional Variant. True if capitalization is ignored. If this argument is omitted, the current value of the IgnoreUppercase property is used.
AlwaysSuggest Optional Variant. True for Microsoft Word to always suggest alternative spellings. If this argument is omitted, the current value of the SuggestSpellingCorrections property is used.
CustomDictionary2 – CustomDictionary10 Optional Variant. Either an expression that returns a Dictionary object or the file name of an additional custom dictionary. You can specify as many as nine additional dictionaries.

Example
As it applies to the Range object.

This example begins a spelling check on all available stories of the active document.

Set range2 = Documents("MyDocument.doc").Sections(2).Range
range2.CheckSpelling IgnoreUpperCase:=False, _
    CustomDictionary:="MyWork.Dic", _
    CustomDictionary2:="MyTechnical.Dic"

Так же смотрите в HELP по объектной модели Word VBA описание
SpellingSuggestions Collection Object
GetSpellingSuggestions Method
SpellingErrorType Propery
ShowSpellingErrors Property
Dictionary Object
ActiveSpellingDictionary Property

К сожалению, последний удобный HELP по Word VBA был в 2003 офисе.

[tumanovalex]

Как я понял, эти функции позволяют работать только со своими (пользовательскими) словарями. А как работать со словарем Word, внедренным в него?

[Aent]

Неправильно поняли.
Неужели так сложно внимательно прочитать HELP и попробовать самому ?

Sub DisplaySuggestions()
    Dim sugList As SpellingSuggestions
    Dim sug As SpellingSuggestion
    Dim strSugList As String
    Dim strWord As String
    strWord = "карова"
    Set sugList = GetSpellingSuggestions(Word:=strWord, SuggestionMode:=wdSpellword)
    If sugList.Count = 0 Then
        MsgBox "Проверяемое слово корректно"
    Else
        For Each sug In sugList
            strSugList = strSugList & vbTab & sug.Name & vbLf
        Next sug
        MsgBox "Варианты для слова """ & strWord & """:" & vbLf & strSugList
    End If
End Sub

[Ципихович Эндрю]

помоему тоже самое только вид сбоку:

Sub Проверяем_орфографию_грамматику_слова()

Проверяемое_слово = "хаем"
'проверяем грамматику, точку и пробел надо ставить у проверяемого слова
If Application.CheckGrammar(Проверяемое_слово & ". ") = True Then
MsgBox "Проверяемое слово: " & Проверяемое_слово & " без ошибок!"
Else
MsgBox$ "Проверяемое слово: " & Проверяемое_слово & " подчёркнуто зелёной волнистой линией"
'применимо для Word 2007, бывает версия Word 2007 "12.0.4518"
If Left$(Application.Build, 2) = "12" Then Проверка_грамматики (Проверяемое_слово)
End If

'проверяем орфографию
If Application.CheckSpelling(Проверяемое_слово) Then
   MsgBox "Проверяемое слово: " & Проверяемое_слово & " без ошибок!"
Else
   Dim sugList As SpellingSuggestions
   Dim sug As SpellingSuggestion
   Dim strSugList As String
   'Spelling Suggestions орфография предложения
   Set sugList = GetSpellingSuggestions(Word:=Проверяемое_слово, SuggestionMode:=wdSpellword)
   
   If sugList.Count = 0 Then
       MsgBox "Предложения замены слову: " & Проверяемое_слово & " нет"
   Else
       For Each sug In sugList
           strSugList = strSugList & vbTab & sug.Name & vbLf
       Next sug
       MsgBox "Предложения для замены слова: " & Проверяемое_слово & vbLf & strSugList
   End If
End If

End Sub

Function Проверка_грамматики(Проверяемое_слово)
       
       Dim Doc As Document
       Set Doc = Documents.Add(, True, , False)
       Doc.Content.Text = Проверяемое_слово
       Do Until Doc.GrammarChecked
           DoEvents
       Loop
       For i = 1 To Doc.Content.Words.Count
           Doc.Content.Words(i).Select
           ПервыйЭлементКонтекстногоМеню = Doc.CommandBars("Grammar").Controls(1).Caption
           If ПервыйЭлементКонтекстногоМеню <> "&Грамматика..." Then
               Exit For
           End If
       Next
       Doc.Close False
       
       MsgBox ПервыйЭлементКонтекстногоМеню
       
 End Function

[tumanovalex]

Спасибо большое, буду разбираться

[Ципихович Эндрю]

кстати уловите разницу между моим примером и примером Аэнта, отпишитесь