удаление неиспользуемых стилей

[caute]

имеется макрос - то работает нормально, то выдаёт
Нажата кнопка 'End'
Run-time error '4198'
Дебаггер подсвечивает строку: ActiveDocument.Styles(st).Delete
весь код целиком таков:

Sub Удалить_лишние_стили()
Dim st As Style
Application.ScreenUpdating = False
With ActiveDocument.Content.Find
    .Text = ""
    .Replacement.Text = ""
    .ClearFormatting
End With
For Each st In ActiveDocument.Styles
    If Not ActiveDocument.Styles(st).BuiltIn And ActiveDocument.Styles(st).InUse Then
        With ActiveDocument.Content.Find
            .Style = st
            StatusBar = "Поиск стиля: " & st
            If .Execute(findText:="", Wrap:=wdFindContinue) = False Then
                ActiveDocument.Styles(st).Delete
            End If
        End With
    End If
Next
ActiveDocument.Content.Find.ClearFormatting
Application.ScreenUpdating = True
StatusBar = "Поиск завершен"
End Sub

[shanemac51]

Sub Удалить_лишние_стили_120119_0938()
''удаления в коллекциях проводится от хвоста к началу
Dim st, js
Application.ScreenUpdating = False
With ActiveDocument.Content.Find
    .Text = ""
    .Replacement.Text = ""
    .ClearFormatting
End With
js = ActiveDocument.Styles.Count
Do While js > 1
js = js - 1
st = ActiveDocument.Styles(js).NameLocal

    If Not ActiveDocument.Styles(st).BuiltIn And ActiveDocument.Styles(st).InUse Then
        With ActiveDocument.Content.Find
            .Style = st
            StatusBar = "Поиск стиля: " & st
            If .Execute(findText:="", Wrap:=wdFindContinue) = False Then
                ActiveDocument.Styles(st).Delete
                Debug.Print js, st
            End If
        End With
    End If
Loop
ActiveDocument.Content.Find.ClearFormatting
Application.ScreenUpdating = True
StatusBar = "Поиск завершен"
End Sub

[caute]

увы, косяк остался

[Вождь]

Не встречал такого. Присмотритесь к стилю. Имя? Один и тот же? Сами создали или Word, автоматом? Дайте образец.

[Пименов Александр]

Косяк макроса потому, что встроенные стили удалить нельзя их можно только скрыть из меню Стили:
Если заменить
ActiveDocument.Styles(st).Delete
на
ActiveDocument.Styles(st).Visibilit y = True, то ошибку выдавать не будет, если же оставлять ActiveDocument.Styles(st).Delete, то надо писать обработчик ошибки

[caute]

вообще, макрос часть стилей удаляет благополучно, прежде чем выдать ошибку. Вот образец.doc
Замена на

ActiveDocument.Styles(st).Visibility = True

приводит к утере трудоспособности.

В принципе, если случай сложный, то не стоит возиться - в большинстве доков макрос работает хорошо. В крайнем случае всегда можно ручками дочистить.

[Вождь]

Сообщение от Пименов Александр

...встроенные стили удалить нельзя...

Макрос их уже отсеивает, проверкой...

[Вождь]

Сообщение от caute

...Вот Вложение 46721...

В образце имеется проблемный стиль "Знак знак". Команда Delete его удаляет, как бы, но и ошибку выдает тоже. Глюк какой-то. Проверял макросом:

Sub Удалить_стили()
    Debug.Print "<<< Старт " & Now
Dim myStyle As Word.Style
Dim i&, N1&, N2&
Dim S$
    N1 = 0: N2 = 0
    For i = ActiveDocument.Styles.Count To 1 Step -1
        Set myStyle = ActiveDocument.Styles(i)
        If myStyle.BuiltIn = True Then
        ElseIf myStyle.InUse <> True Then
        Else
            S = myStyle.NameLocal
            With ActiveDocument.Content.Find
                .ClearFormatting
                .Replacement.ClearFormatting
                .Format = True
                .Style = S
                .Execute Replace:=Word.wdReplaceNone
                If .Found = True Then
                Else
                    On Error Resume Next
                    myStyle.Delete
                    If Err.Number <> 0 Then
                        N2 = N2 + 1
                        Debug.Print _
                            "- Ошибка " & CStr(Err.Number) & " (" & Err.Description & ")" & _
                            " при удалении стиля """ & S & """"
                    End If
                    If IsObjectValid(myStyle) Then
                        Debug.Print "- Не был удален стиль """ & S & """"
                    Else
                        N1 = N1 + 1
                        Debug.Print "+ Удален стиль """ & S & """"
                    End If
                End If
            End With
        End If
    Next i
    Debug.Print "= Удалено: " & CStr(N1)
    Debug.Print "= Ошибок: " & CStr(N2)
    Debug.Print ">>> Финиш " & Now
End Sub

[Пименов Александр]

Значит оставить в макросе On Error

[caute]

вы правы: затык был в этом дурацком стиле "знак знак". Он у меня давно в нормале маячит, хотя я его не создавал и никогда им не пользовался. Не без труда удалось-таки его удалить нафиг - макрос тут же заработал! спасибо за решение.
А вот этот код выше - стоит ли им заменить прежний? ваша версия макроса имеет иммунитет к ошибкам стилей, так я понял? или чего-то недопонял?

кстати, мой макрос наряду с лишними стилями почему-то удаляет иногда и нелишние (неоднократно используемые в документе). Можно ли как-то это поправить?