Передача параметров в функцию

[ruslan_123]

Добрый день!
Впервые столкнулся с VBA
Проблема:
есть цикл
for i = 29 to 38
бла
бла
бла
фнкция1[A29:M29]
Next
фнкция1(ByRef ra As Range)

не могу сообразить, как вместо А29 и М29
передать Аі-тое и Мі-тое
Помогите!!!

[doober]

 Range("A" & i & ":M" & i )

[Казанский]

set ra=range("A" & i & ":M" & i)
' или
set ra=range("A" & i).resize(,13)
' или
set ra=range(cells(i,1), cells(i,13))
' или
set ra=intersect(rows(i), range("A:M"))
' или
set ra=range(i & ":" & i & " A:M")

фнкция1 ra

[ruslan_123]

ошибка 424
object required

[ruslan_123]

Вот весь код
Private Sub Worksheet_Activate()
Dim i As Long: Application.ScreenUpdating = False
For i = 12 To 21
If Cells(i, 1) = " " Then
Rows(i).Hidden = True
Else
Rows(i).Hidden = False: Rows(i).AutoFit
End If
Next
For i = 29 To 38
If Cells(i, 1) = " " Then
Rows(i).Hidden = True
Else
Rows(i).Hidden = False: Rows(i).AutoFit
Set ra = Range("A" & i & ":M" & i)
AutoFitMergedCellRowHeight (ra) ??????
End If
Next
End Sub


Sub AutoFitMergedCellRowHeight(ByRef ra As Range)
Dim CurrCell As Range, cell As Range, ma As Range: Dim col As Range, ro As Range
For Each ro In ra.Rows
maxRH = 0
For Each cell In ro.Cells
If cell.MergeCells And cell.Address = cell.MergeArea.Cells(1).Address Then
Debug.Print cell.Address
Set ma = cell.MergeArea: newCW = 0
With ma
cw = .Columns(1).ColumnWidth: .UnMerge
For Each col In .EntireColumn: newCW = newCW + col.ColumnWidth: Next
.Columns(1).ColumnWidth = newCW: .EntireRow.AutoFit
rh = .EntireRow.RowHeight: If rh > maxRH Then maxRH = rh
.Merge: .Columns(1).ColumnWidth = cw
End With
End If
Next cell
If maxRH > 0 Then ro.EntireRow.RowHeight = maxRH
Next ro
End Sub

[EducatedFool]

Dim ra As Range: Set ra = Range("A" & i & ":M" & i)
        AutoFitMergedCellRowHeight ra

или так:

Rows(i).Hidden = False: Rows(i).AutoFit
            AutoFitMergedCellRowHeight Range("A" & i & ":M" & i)

[ruslan_123]

Большое спасибо всем

[nerv]

Из этой же оперы http://www.planetaexcel.ru/forum.php...llnum_forum=97