Сбор данных с нескольких файлов

[hamlook]

Доброго вам времени.
Мне необходимо постоянно копировать одни и те же данные с многих файлов в одну таблицу. На вашем форуме нашел нужный макрос и подкорректировал под свои нужды.
В принципе все работает как мне надо, но немного не хватает.
Подскажите пожалуйста как сделать макрос, чтобы данные, которые уже есть в общей таблице, по новой не копировались? Ориентир - по номеру акта (ячейка В4). То есть если данные с акта №44 уже внесены в общую таблицу, то повторно они попасть туда не должны, даже если данный акт находится в папке.

[Казанский]

С минимальным изменением кода:

Sub Main()
    Dim path As String, file As String, arg As String, i As Long, x
    Application.ScreenUpdating = False
    With Application.FileDialog(msoFileDialogFolderPicker)
        .Title = "Укажите рабочую папку": .Show
        If .SelectedItems.Count = 0 Then Exit Sub Else path = .SelectedItems(1) & "\"
    End With
    file = Dir(path & "*.xls"): i = Cells(Rows.Count, 1).End(xlUp).Row + 1
    Do While file <> ""
        x = ExecuteExcel4Macro("'" & path & "[" & file & "]" & "Лист1'!" & Range("B4").Range("A1").Address(, , xlR1C1))
        If IsError(Application.Match(x, Columns("B"), 0)) Then
            Cells(i, 1) = Cells(i - 1, 1) + 1
            Cells(i, 2) = x
            Cells(i, 3) = ExecuteExcel4Macro("'" & path & "[" & file & "]" & "Лист1'!" & Range("A10").Range("A1").Address(, , xlR1C1))
            Cells(i, 4) = ExecuteExcel4Macro("'" & path & "[" & file & "]" & "Лист1'!" & Range("B10").Range("A1").Address(, , xlR1C1))
            Cells(i, 5) = ExecuteExcel4Macro("'" & path & "[" & file & "]" & "Лист1'!" & Range("C10").Range("A1").Address(, , xlR1C1))
            i = i + 1
        End If
        file = Dir
    Loop
End Sub

[hamlook]

Спасибо большое! Великолепно работает!!!

[hamlook]

Не учел один момент.
В актах не всегда одна строка данных.., то есть всегда разное количество строк. А иногда еще и с разрывами на два листа. Возможно такое реализовать?