Не работает ВПР3 (VLOOKUP3)

[strannick]

Добрый день, уважаемые форумчане!
Не хочет работать формула массива VLOOKUP3 именно с этим значением Rado (пример во вложении, таблица на первом листе, формула на втором). Само значение скопировал из рабочего файла, таблица практически аналогичная. С другими значениями в этой же таблице работает нормально. Пробовал разные варианты с форматами, очищал, удалял, вводил вручную. Автопересчет включен. Что не так, подскажите? Заранее спасибо.

[nilem]

Попробуйте увеличить размер выходного массива, типа
Dim Out(10000) As Variant

[Hugo121]

Лучше вероятно даже так:

ReDim Out(0 To Table.Rows.Count - 1) As Variant

P.S.
А ещё лучше так - в 5 раз быстрее на этом примере, плюс ещё пару недочётов исправил:

Function VLOOKUP3(Table As Range, SearchColumnNum As Integer, _
                  SearchValue As Variant, ResultColumnNum As Integer)
'улучшенная функция ВПР вводится как формула массива
'ищет указанной значение в указанном столбце и выводит все соответствия из указанного столбца
    Dim i&, j&
    Dim a
    ReDim Out(1 To Table.Rows.Count, 1 To 1) As Variant

    a = Table.Value
    For i = 1 To Table.Rows.Count
        If a(i, SearchColumnNum) = SearchValue Then
            j = j + 1
            Out(j, 1) = a(i, ResultColumnNum)
        End If
    Next i
    VLOOKUP3 = Out
End Function

[strannick]

Сообщение от nilem

Попробуйте увеличить размер выходного массива, типа
Dim Out(10000) As Variant

Точно! Это я не досмотрел.

[strannick]

Сообщение от Hugo121

Лучше вероятно даже так:

ReDim Out(0 To Table.Rows.Count - 1) As Variant

P.S.
А ещё лучше так - в 5 раз быстрее на этом примере, плюс ещё пару недочётов исправил:

Function VLOOKUP3(Table As Range, SearchColumnNum As Integer, _
                  SearchValue As Variant, ResultColumnNum As Integer)
'улучшенная функция ВПР вводится как формула массива
'ищет указанной значение в указанном столбце и выводит все соответствия из указанного столбца
    Dim i&, j&
    Dim a
    ReDim Out(1 To Table.Rows.Count, 1 To 1) As Variant

    a = Table.Value
    For i = 1 To Table.Rows.Count
        If a(i, SearchColumnNum) = SearchValue Then
            j = j + 1
            Out(j, 1) = a(i, ResultColumnNum)
        End If
    Next i
    VLOOKUP3 = Out
End Function

Определенно быстрее! Огромное спасибо!