Подмножества списка, равные заданной сумме (Prolog)

[dobry_chelovek]

Товарищи, добрый день.
Есть задача:
Определите предикат
subsum(+Set,+Sum,?SubSet)
такой, что Set является списком чисел, SubSet - подмножеством этих чисел, а сумма чисел в SubSet равна Sum, например:
?- subsum([1,2,5,3,2],5,Sub).
Sub = [1,2,2];
Sub=[2,3];
Sub=[5];
...
Есть код, который решает задачу, но остается проблема с удалением одинаковых ответов. Как можно это организовать?

p([],0,[]). 
p([H|T],N,[H|T1]):- H =< N,N1 is N-H,p(T,N1,T1). 
p([_|T],N,T1):- p(T,N,T1).

[Black Fregat]

Формально это не одинаковые ответы, в них двойки - разные.
Разве условие задачи требует отсеивать эти повторения?
Боюсь, в две строчки это не выйдет.

Хотя..

subsum(Set, Sum, SubSet) :-
	subsum(Set, Sum, [], SubSet).

subsum([], 0, _, []).
subsum([H|T], N, Skip, [H|T1]) :-
	not(member(H, Skip)),
	H =< N,
	N1 is N-H,
	subsum(T, N1, Skip, T1).
subsum([H|T], N, Skip, T1) :-
	subsum(T, N, [H|Skip], T1).

?- subsum([1,2,5,3,2], 5, Sub).
Sub = [1, 2, 2] ;
Sub = [2, 3] ;
Sub = [5] ;
false.

[dobry_chelovek]

Спасибо. Я же правильно понимаю, что таким образом мы вносим по очереди в список Skip те элементы, для которых все варианты в дальнейшем исчерпаны и для которых просмотр не имеет смысла? А каким образом в SWI Prolog можно вызывать ответы до false не пользуясь точкой с запятой или кнопкой Next в онлайн версии?

[Black Fregat]

Сообщение от dobry_chelovek

для которых просмотр не имеет смысла?

Точнее - для которых выбор будет вести к повторам.
Повторы возникают из-за дублей одинаковых элементов в списке.
Смысл решения в том, что мы перестаём включть в список элементы, хотя бы один раз пропущенные

Сообщение от dobry_chelovek

каким образом в SWI Prolog можно вызывать ответы до false не пользуясь точкой с запятой или кнопкой Next

Не знаю. Можно смоделировать:

 ?- subsum([1,2,5,3,2], 5, Sub), write(Sub), nl, fail.
[1,2,2]
[2,3]
[5]
false.