Сумма прописью в нескольких местах защищенного документа.

[Serge_Bliznykov]

подтверждаю. Это всё из-за того, что Вы используете устаревший тип полей.
проблема возникает c Function GetCurrentFF() As Word.FormField:

попробуйте заменить код на такой:

Option Explicit

Sub WriteToTextFF(fieldName, writeText)
    With GetCurrentFF(fieldName)
        If .Type = wdFieldFormTextInput Then
            .Result = writeText
        End If
    End With
lbl_Exit:
    Exit Sub
End Sub
 
Private Function GetCurrentFF(fieldName) As Word.FormField
    Dim rngFF, fldFF
    Set rngFF = Selection.Range
    rngFF.Expand wdParagraph
    For Each fldFF In rngFF.FormFields
        Set GetCurrentFF = fldFF
        If GetCurrentFF.Name = fieldName Then
          Exit For
        End If
    Next fldFF
lbl_Exit:
    Exit Function
End Function


Sub setPropis()
    Dim bm As Bookmark
    Dim sText As String, textPropis As String
    
    Set bm = ActiveDocument.Bookmarks("chislo")
    sText = Trim(bm.Range.text)
    
    If InStr(sText, "FORMTEXT") > 0 Then
      sText = Trim(Mid(sText, 9))
    End If
    
    textPropis = ""
    ' Если в поле не число, то просто копирование данных из первого поля во второе.
    If IsNumeric(sText) = False Then
        textPropis = sText
    ' Если в поле число, то превращение числа в пропись.
    Else
        textPropis = "(" & mod_Propis.Main(CDbl(sText)) & ")."
    End If
    
    ' запись результатов в поля
    ActiveDocument.Bookmarks("propis").Select
    Call WriteToTextFF("propis", textPropis)
    
    ActiveDocument.Bookmarks("propis1").Select
    Call WriteToTextFF("propis1", textPropis)
    
    ActiveDocument.Bookmarks("chislo1").Select
    Call WriteToTextFF("chislo1", sText)
    
End Sub

[irina181]

Всё решилось. Несколько другой вариант. Может кому-то пригодится. Файл во вложении. Всем спасибо.

[Serge_Bliznykov]

Сообщение от irina181

Несколько другой вариант.

красиво.

Private Function GetFormfield(bm As Bookmark) As FormField
    For Each GetFormfield In bm.Range.FormFields
        Exit Function
    Next GetFormfield
End Function

я вот, например, даже не понимаю, как работает функция, если в ней не прописано возвращаемое значение! Может быть, мне кто-то объяснит, как это работает?
Какой-то хитрый "хак" VBA используется, по всей видимости...

[irina181]

Ответ можно получить тут https://forumvba.ru/index.php?board=4.0

[Serge_Bliznykov]

Сообщение от irina181

Ответ можно получить тут

спасибо за ссылку.
Но, вряд ли я пойду регистрироваться на другом форуме, чтобы получить объяснение.
Может быть, мне кто-то здесь ответит.
А если не ответит, значит, не судьба мне узнать, как работает функция в VBA без return...

добавлено

всё. я понял.
вот здесь ключ:

Private Function GetFormfield(bm As Bookmark) As FormField
    For Each GetFormfield In bm.Range.FormFields
        Exit Function
    Next GetFormfield
End Function

цикл For Each и присваивает значение функции.

[irina181]

Думаю тему можно закрыть. Спасибо за помощь.

[Serge_Bliznykov]

Всегда пожалуйста!

p.s. А тему пока я закрывать не буду. может быть, позже кому-то ещё пригодится...