FASM (assembler). Удалить пробелы в начале и в конце строки

[Zart]

Задали в универе программу именно на FASM, помогите кто сможет.
Задана строка, удалить из неё пробелы в начале и в конце строки и вывести (через консоль желательно).
Буду ооочень признателен, если к основным строкам кода будут написаны комментарии с описанием действия.

[Zart]

На крайний случай хотя бы на MASMе помогите написать...

[JTG]

FORMAT PE CONSOLE
include 'win32axp.inc'

.data
        string db '        ABCDEF        ',0

.code
start:

    mov     eax, string     ; адрес строки в eax
    mov     ecx, eax        ; и в ecx
    push    eax             ; и в стек (пригодится позже)

;        ________ABCDEF________0
;     eax^ecx

; пропускаем начальные пробелы
skip_lead:                 ;                                   <--+
    mov     dl, [ecx]       ; читаем байт                          |
    inc     ecx             ; увеличиваем позицию на 1             |
    cmp     dl, 32          ; байт в этой позиции = 32 (пробел)?   |
    je      skip_lead       ; да, проверяем следующий -------------+
    dec     ecx             ; нет, уменьшаем обратно позицию на 1
    dec     eax             ;      уменьшаем позицию eax на 1

;        ________ABCDEF________0
;    eax^       ^ecx

; "сдвигаем" строку влево, начиная с позиции ecx, затирая ведущие пробелы
shift_left:                ;                                         <--+
    mov     dl, [ecx]       ; читаем байт (начиная с первого не-пробела) |
    inc     eax             ; увеличиваем позицию в eax на 1             |
    inc     ecx             ; увеличиваем позицию в eсx на 1             |
    mov     [eax], dl       ; копируем этот байт в начало строки         |
    or      dl, dl          ; байт = 0 (последний в строке)?             |
    jnz     shift_left      ; нет, возвращаемся и копируем следующий ----+
    pop     ecx             ; достаём из стека адрес первого символа строки и кладём в ecx

;         ABCDEF________________0
;      ecx^                     ^eax

; пропускаем хвостовые пробелы

skip_trail:
    dec     eax             ; уменьшаем eax на 1                     <--+
    cmp     byte[eax], 32   ; байт байт в этой позиции = 32 (пробел)?   |                              
    je      skip_trail      ; да, проверяем предыдущий -----------------+                                  
    inc     eax             ; нет, отступаем на 1 вправо
    mov     byte[eax], 0    ; записываем 0 (конец строки)

;         ABCDEF0_______________0
;      ecx^     ^eax

   sub      eax, ecx                               ; отнимем от eax ecx, получим в eax длину строки
   xchg     eax, ecx                               ; поменяем местами с ecx
   invoke   GetStdHandle, STD_OUTPUT_HANDLE        ; получаем в eax - дескриптор консоли
   invoke   WriteConsole, eax, string, ecx, 0, 0   ; выводим в консоль символы строки string в количестве ecx штук
   invoke   Sleep, 5000                            ; пауза 5 сек
   invoke   ExitProcess, 0                         ; выход

.end start

[Zart]

Огромное спасибо!!! С комментариями прям вообще супер. Теперь полностью понял как со строками работать в FASM.

[Zart]

А может ещё пожалуйста объяснить как сначала строку считать с файла, а потом уже полученную без пробелов записать в тот же файл.