Обработка нажатия кнопки в Arduino

[zhenek_kreker]

Не помогает
В общем, сегодня после работы попробую с ручкой в руках на бумаге описать как программа действует. Буду признателен, если сумеет помочь. Вообще какая обычная тактика в таких случаях? Я так понимаю, что у меня ошибка может быть во всех трёх функциях: debounce(), setMode() и Blink(). Есть смысл их отлаживать по отдельности? Вынести, например, код Blink() в отдельную программу, которая бы моргала диодом безотносительно кнопки? Извините за нубские вопросы.
P.S. Надо было в институте не прогуливать программирование, блин.

[Croessmah]

Я тоже на работе сейчас, забыл ноут свой дома, так что сижу со смартфона за двумя рабочими компами . Скучно, делать нечего
В данном случае будет достаточно простейшего автомата. Если никто не ответит, то как приду домой, постараюсь объяснить. Конечно, всю теорию автоматов я не осилю, но простейший алгоритм вполне

[Croessmah]

Схема та же, что и у Вас. Сделал на три режима. Режимы меняют друг друга по очереди при нажатии кнопки.

int ButtonPin = 2;
int LedPin = 3;
boolean ledState = false ;
long mode1_interval = 100 ;
long mode2_interval = 300 ;
long mode3_interval = 700 ;


enum STATES
{
  START,
  MODE1,
  MODE2,
  MODE3
} ;


//Установка состояния светодиода
void set_led_state(boolean state)
{
  ledState = state;
  digitalWrite(LedPin, state);
}


//Возвращает состояние светодиода
boolean get_led_state()
{
  return ledState;
}




void setup()
{
  pinMode(LedPin, OUTPUT);
  pinMode(ButtonPin, INPUT);
  set_led_state(false);//Светилище выключено
}



//Функция определяет наличие сигнала на указанном входе.
boolean is_push(int pin)
{
  boolean state = digitalRead(pin);//Читаем состояние входа
  delay(10);//Задержка для сглаживания "дребезга". Поставил в 10, как у Вас.
  return (state && digitalRead(pin));//Читаем состояние снова и логическим И определяем было ли нажатие или это дребезг
}



void Blink(long interval, int LedPin)
{
  static long prev_time = 0 ;//Предыдущее время
  long time = millis();
  if( time - prev_time > interval ){
    prev_time = time;
    set_led_state(!get_led_state());//Инвертируем состояние светодиода
  }
}


//Обработчик режима 1
void mode1_handler()
{
  Blink(mode1_interval, LedPin);
}


//Обработчик режима 2
void mode2_handler()
{
  Blink(mode2_interval, LedPin);
}


//Обработчик режима 3
void mode3_handler()
{
  Blink(mode3_interval, LedPin);
}


//Изменения режима и возврат текущего режима
int state_logic(boolean change)
{
  static STATES state = START;//Начальный режим - START
  if(change){//Если режим необходимо сменить на следующий, то
    switch(state)//Смотрим какой сейчас режим включен
    {
    case START://Если START, 
      state = MODE1;//то меняем на MODE1
      break;
    case MODE1://Если MODE1, 
      state = MODE2;//то меняем на MODE2
      break;
    case MODE2://Если MODE2, 
      state = MODE3;//то меняем на MODE3
      break;
    case MODE3://Если MODE3, 
      state = MODE1;//то меняем на MODE1
      break;
    default://Во всех остальных случаях (ну может возникнут)
      state = START;//Возвращаемся к исходному режиму
    };
    set_led_state(false);//Гасим лампочку
  }
  return state;
}



//Функция определяет нужно ли сменить состояние
boolean need_change_state()
{
  static boolean lastButtonState = false;//Начальное состояние кнопки - выключена
  boolean push = is_push(ButtonPin) ;//Нажата ли кнопка?
  boolean change_state = push && !lastButtonState;//Кнопка нажата, а до этого была отжата???
  lastButtonState = push ;//Меняем состояние кнопки на текущее
  return change_state ;//возвращаем флаг необходимости смены режима
}



void loop()
{
  //Определяем какой режим включен
  //Передаем результат
  //need_change_state в state_logic
  //Для смены режима при необходимости
  switch(state_logic(need_change_state()))
  {
  case START://Если режим START, то
    break;//Ничего
  case MODE1://Если режим MODE1, то
    mode1_handler();//Запускаем обработчик режима 1
    break;
  case MODE2://Если режим MODE2, то
    mode2_handler();//Запускаем обработчик режима 2
    break;
  case MODE3://Если режим MODE3, то
    mode3_handler();//Запускаем обработчик режима 3
    break;
  };
}

конечно, много перемудрил, потому как особо не заморачивался.
Конечно, абстракции и структуру кода нужно сделать получше.
Тестировал на UNO R3

[zhenek_kreker]

Спасибо огромное!
Ваша логика программы довольно сильно отличается от моей. Я, кстати, вчера сумел заставить свою функцию Blink() работать - вы были правы, потребовалось вынести переменную LED_STATE в глобальные.
P.S. И ещё для меня стала открытием конструкция enum

[Croessmah]

Спасибо огромное!

Да пожалуйста, обращайтесь. Забыл выключить, почти сутки уже моргает

стала открытием конструкция

всё бывает в первый раз.