Как передаётся сообщение окна? MASM

[максхи]

Вот секция code кода из учебника:

.CODE
start:
    invoke GetModuleHandle, NULL
    mov    hInstance,eax
    invoke GetCommandLine
    mov CommandLine,eax
    invoke WinMain, hInstance,NULL,CommandLine, SW_SHOWDEFAULT
    invoke ExitProcess,eax

WinMain proc hInst:HINSTANCE, hPrevInst:HINSTANCE, CmdLine:LPSTR,
CmdShow:DWORD
    LOCAL wc:WNDCLASSEX
    LOCAL msg:MSG
    LOCAL hwnd:HWND
    mov   wc.cbSize,SIZEOF WNDCLASSEX
    mov   wc.style, CS_HREDRAW or CS_VREDRAW
    mov   wc.lpfnWndProc, OFFSET WndProc
    mov   wc.cbClsExtra,NULL
    mov   wc.cbWndExtra,NULL
    push  hInst
    pop   wc.hInstance
    mov   wc.hbrBackground,COLOR_WINDOW+1
    mov   wc.lpszMenuName,NULL
    mov   wc.lpszClassName,OFFSET ClassName
    invoke LoadIcon,NULL,IDI_APPLICATION
    mov   wc.hIcon,eax
    mov   wc.hIconSm,eax
    invoke LoadCursor,NULL,IDC_ARROW
    mov   wc.hCursor,eax
    invoke RegisterClassEx, addr wc

    invoke CreateWindowEx,NULL,ADDR ClassName,ADDR AppName,\
           WS_OVERLAPPEDWINDOW,CW_USEDEFAULT,\

           CW_USEDEFAULT,CW_USEDEFAULT,CW_USEDEFAULT,NULL,NULL,\
           hInst,NULL
    mov   hwnd,eax
    invoke ShowWindow, hwnd,SW_SHOWNORMAL
    invoke UpdateWindow, hwnd
        .WHILE TRUE
               invoke GetMessage, ADDR msg,NULL,0,0
               .BREAK .IF (!eax)
               invoke TranslateMessage, ADDR msg
               invoke DispatchMessage, ADDR msg
        .ENDW
        mov     eax,msg.wParam
        ret
WinMain endp

WndProc proc hWnd:HWND, uMsg:UINT, wParam:WPARAM, lParam:LPARAM
    LOCAL hdc:HDC
    LOCAL ps:PAINTSTRUCT
    LOCAL rect:RECT
    .IF uMsg==WM_DESTROY
        invoke PostQuitMessage,NULL
    .ELSEIF uMsg==WM_PAINT
        invoke BeginPaint,hWnd, ADDR ps
        mov    hdc,eax
        invoke GetClientRect,hWnd, ADDR rect
        invoke DrawText, hdc,ADDR OurText,-1, ADDR rect, \
                DT_SINGLELINE or DT_CENTER or DT_VCENTER
        invoke EndPaint,hWnd, ADDR ps
    .ELSE
        invoke DefWindowProc,hWnd,uMsg,wParam,lParam
        ret
    .ENDIF
    xor   eax, eax

Но я не понимаю, когда в umsg передаётся WM_PAINT.
Это должно происходить в invoke TranslateMessage, ADDR msg
invoke DispatchMessage, ADDR msg, похоже судя по другому коду.
Но непонятно, как.
В этой строке это задаётся

mov   wc.lpfnWndProc, OFFSET WndProc

?

[p51x]

Сообщение от максхи

Это должно происходить в invoke TranslateMessage, ADDR msg

Не должно.

Translates virtual-key messages into character messages. The character messages are posted to the calling thread's message queue, to be read the next time the thread calls the GetMessage or PeekMessage function.

Сообщение от максхи

invoke DispatchMessage, ADDR msg, похоже судя по другому коду.

Именно.

Dispatches a message to a window procedure. It is typically used to dispatch a message retrieved by the GetMessage function.

Но непонятно, как.

По hwnd берет класс окна, из класса берет

lpfnWndProc

и вызывает

[максхи]

У одногруппника такой код:

.ELSEIF uMsg==WM_CREATE
        invoke CreateWindowEx, WS_EX_CLIENTEDGE, addr EditClass, 0,\
                WS_CHILD or WS_VISIBLE or WS_BORDER or ES_LEFT,\
                20, 30, 280, 25, hWnd, Edit_1, hInstance, 0
        mov hEdit_1, eax
        invoke SetFocus, hEdit_1
        invoke CreateWindowEx, 0, addr ButtonClass, addr ButtonText_1,\
                WS_CHILD or WS_VISIBLE or BS_DEFPUSHBUTTON,\
                80, 120, 160, 25, hWnd, Button_1, hInstance, 0
        mov hButton_1, eax
    .ELSEIF uMsg==WM_COMMAND
        mov eax, wParam
        ;(код обработки строк и вывода вырезал)
        .ENDIF

То есть вопрос: от чего зависит, WM_PAINT или WM_CREATE будет в umsg?

[p51x]

От того, что происходит, естественно.
WM_CREATE

Sent when an application requests that a window be created by calling the CreateWindowEx or CreateWindow function. (The message is sent before the function returns.) The window procedure of the new window receives this message after the window is created, but before the window becomes visible.

WM_PAINT

The WM_PAINT message is sent when the system or another application makes a request to paint a portion of an application's window. The message is sent when the UpdateWindow or RedrawWindow function is called, or by the DispatchMessage function when the application obtains a WM_PAINT message by using the GetMessage or PeekMessage function.