Макрос вставки изображения в примечание

[htcreed]

Добрый день, прошу помощи у знатоков VBA.
Помогите поправить макрос, третий день не могу понять, как исправить ошибку.. Заранее благодарен!

Sub MyComBars()
    Application.CommandBars("cell").Reset
    With Application.CommandBars("cell").Controls.Add(Type:=1, Before:=5)
        .OnAction = "AddImage"
        .Caption = "Вставить изображение"
    End With
End Sub
 
Sub AddImage()
    Dim ImaFile$
 
    If Selection.Cells.Count > 1 Then Exit Sub
    With Application.FileDialog(msoFileDialogFilePicker)
        .Show
        If .SelectedItems.Count = 0 Then Exit Sub
        ImaFile = .SelectedItems(1)
    End With
    On Error GoTo nexterr
    ActiveCell.ClearComments
    ActiveCell.AddComment
        With .Shape
            .Fill.UserPicture (ImaFile)
            .Height = 340: .Width = 700
        End With
    Exit Sub
nexterr:
    MsgBox "Можно выбирать только изображения!", vbCritical, "Ошибка"
    ActiveCell.ClearComments
End Sub

[EducatedFool]

http://excelvba.ru/code/PictureInCellComment

Sub AddImage()
    Dim ImaFile$
    With Application.FileDialog(msoFileDialogFilePicker)
        .Show
        If .SelectedItems.Count = 0 Then Exit Sub
        ImaFile = .SelectedItems(1)
    End With
    
    On Error GoTo nexterr
    ActiveCell.ClearComments
    With ActiveCell.AddComment.Shape
        .Fill.UserPicture (ImaFile)
        .Height = 340: .Width = 700
    End With
    Exit Sub
nexterr:
    MsgBox "Можно выбирать только изображения!", vbCritical, "Ошибка"
    ActiveCell.ClearComments
End Sub

[htcreed]

Спасибо огромное. У меня еще один небольшой интерес, возможно ли что-то подобное собрать?

Function GETPHOTO(rCell As Range)
    On Error Resume Next
    GETPHOTO = rCell.Comment.Picture
    .Comment.Visible = True
    .Comment.Shape.CopyPicture xlScreen, xlBitmap
    .PasteSpecial
    .Comment.Visible = False
End Function

[EducatedFool]

Да, возможно.
Всё уже собрано до вас
В интернете можно найти готовый макрос под любую задачу, - и только чуточку допилить.