Ошибка 429 при использовании Call

[HenryO]

Друзья,
есть процедура, которая в отдельности отлично запускается, т.е. вот эта:

Sub ВставкаОтчетаWord()
    GetObject(, "Word.Application").Run "ФормированиеОтчетов.ВставкаОтчетаИзExcel"
End Sub

Т.к. эта процедура является составляющим элементом, то при попытке вызова из другой процедуры выдает ошибку 429 "ActiveX component can't create object"

Sub ОткрытьФайл()
Dim oShell As Object
Set oShell = CreateObject("Shell.Application")
oShell.shellexecute ThisWorkbook.Path & "\Шаблон отчетов.docm"

Call ВставкаОтчетаWord 'Место ошибки!!

End Sub

Вместо команды Call пытался подставить GetObject(, "Word.Application").Run "ФормированиеОтчетов.ВставкаОтчетаИ зExcel" , но выдает ту же ошибку.

[Казанский]

Дело в том, что метод shellexecute не ждет выполнения команды, программа продолжается дальше, и в момент выполнения GetObject(, "Word.Application") Ворд еще не открыт.
Лучше контролировать открытие файла из программы:

Sub ОткрытьФайл()
Dim oWord As Object, bWordNotRunning As Boolean
On Error Resume Next
Set oWord = GetObject(, "Word.Application")
If Err Then 'Ворд не запущен
    Set oWord = CreateObject("Word.Application")
    bWordNotRunning = True
End If
On Error GoTo 0
oWord.documents.Open ThisWorkbook.Path & "\Шаблон отчетов.docm"

oWord.Run "ФормированиеОтчетов.ВставкаОтчетаИзExcel"

'...

If bWordNotRunning Then oWord.Quit 'если Ворд не был запущен - закрыть его
End Sub

[HenryO]

Спасибо за вариант решения проблемы.
У меня также получилось решить его вчера с помощью выдержки Паузы перед началом выполнения след.команды

Sub ГенерацияОтчетов()
Dim oShell As Object
Set oShell = CreateObject("Shell.Application")
oShell.shellexecute ThisWorkbook.Path & "\Шаблон отчетов.docm"

Application.Wait (Now + TimeValue("0:00:05"))
GetObject(, "Word.Application").Run "ФормированиеОтчетов.СохранениеОтчетов4"

End Sub

Но согласен, что выдержка паузы оценочный вариант, поэтому предпочтительнее, конечно, ваш вариант.