Сводная таблица из нескольких листов

[4uvak111]

Здравствуйте, столкнулся с небольшой проблемой при реализации сводной таблицы из нескольких листов.
Начальные навыки программирования есть, и логику понимаю, но с Visual basic сталкиваюсь впервые, поэтому и возникли некоторые сложности.

Итак, задача: имеется несколько листов с однородными данными, количество листов периодически добавляется.
Шаблон находится здесь: http://rghost.ru/37869477

В этой же книге есть сводный лист, где содержится краткая информация из каждого листа - наименование, дата, план.

Как понимаю, проще на сводном листе сделать кнопку "обновить", чтобы по нажатию на ней выводились некоторые ячейки из всех остальных листов. В принципе, на "сводном листе" в книге по ссылке выше указано, что хотелось бы получить

Главный вопрос - как это реализовать?

Форум немного почитал, ответа не нашел. Консолидация данных тоже не подходит - выводит вместо текстовых значений единицу.

[nilem]

попробуйте так

Sub ertert()
Dim x, y(), wsh As Worksheet, i As Long
ReDim y(1 To ThisWorkbook.Worksheets.Count - 1, 1 To 4)

For Each wsh In ThisWorkbook.Worksheets
    If Not wsh Is ActiveSheet Then
        x = wsh.Range("B2:D10").Value
        i = i + 1
        y(i, 1) = i
        y(i, 2) = x(1, 3)
        y(i, 3) = x(7, 3)
        y(i, 4) = x(9, 3)
    End If
Next wsh
Range("A2:D" & Cells(Rows.Count, 1).End(xlUp).Row + 1).ClearContents
[a2:d2].Resize(i).Value = y
End Sub

[4uvak111]

nilem, отлично, как раз то что нужно!
Только что исправить в макросе, чтобы дату вставляло не из ячейки d8, а из с10?

И еще, можно ли макросом создавать для каждой строки кнопку, которая будет открывать тот лист, из которого берутся данные для этой строки?

[nilem]

Наверное, лучше гиперссылки вместо кнопок. Вот так попробуйте

Sub ertert()
Dim x, y(), wsh As Worksheet, i As Long, r As Range
ReDim y(1 To ThisWorkbook.Worksheets.Count - 1, 1 To 5)

For Each wsh In ThisWorkbook.Worksheets
    If Not wsh Is ActiveSheet Then
        x = wsh.Range("B2:D10").Value
        i = i + 1: y(i, 1) = i: y(i, 2) = x(1, 3)
        y(i, 3) = x(9, 2): y(i, 4) = x(9, 3): y(i, 5) = wsh.Name
    End If
Next wsh
Range("A2:E" & Cells(Rows.Count, 1).End(xlUp).Row + 1).ClearContents
[a2:e2].Resize(i).Value = y
For Each r In [e2].Resize(i)
    r.Hyperlinks.Add anchor:=r, Address:="", SubAddress:="'" & r.Value & "'" & "!B2"
Next r
End Sub

[4uvak111]

nilem, спасибо огромное, очень помогло!

Кстати, еще вопрос. Вставка листа выполняется с помощью макроса

Sub ВставкаЛиста()
'
' ВставкаЛиста Макрос
'
    Sheets("Сводный лист").Select
    Sheets.Add Type:= _
        "C:\Users\Администратор\AppData\Roaming\Microsoft\Шаблоны\Лист.xltm"
End Sub

Но шаблон листа вставляется всегда в начало книги. Что нужно сделать, чтобы новый шаблон листа всегда вставлялся вторым, сразу после "Сводного листа"?

[nilem]

Так и пишем: сразу после "Сводного листа"

Sheets.Add After:=Sheets("Сводный лист"), Type:=...

[4uvak111]

nilem, вновь выручаешь! Спасибо!
И еще вопрос, как правильно сделать так, чтобы вместо "Администратора" в пути подставлялся текущий пользователь? Или может быть можно как то реорганизовать книгу, чтобы она безболезненно работала на разных ПК?
В данный момент, придется всем пользователям сохранить шаблон листа в соответствующей папке.

Кстати, на 2010 все работало отлично, а вот на 2007 офисе не взлетело. 2007 офис пытался вместо файла Лист.xtlm найти Лист1.xtml, потом Лист11.xtml...

[nilem]

Имхо, лучше хранить шаблон в самой книге в виде скрытого листа. Тогда вставить новый лист можно как-то так:

Sub InsSheet()
With Sheets("шаблон")
    .Visible = xlSheetVisible
    .Copy After:=Sheets("Сводный лист")
    .Visible = xlSheetHidden
End With
ActiveSheet.Name = "орг-ция" & ThisWorkbook.Worksheets.Count
End Sub

А в предыдущем коде нужно подправить:

Sub ertert()
.....
For Each wsh In ThisWorkbook.Worksheets
    If Not wsh Is ActiveSheet Then
        If Not wsh.Name = "шаблон" Then
            ...........
        End If
    End If
Next wsh
.......

[4uvak111]

nilem, блин, как классно, когда все работает... Примного тебе благодарен!

[4uvak111]

Такс, пожалуй последнее исправление, которое придется внести - это чтобы с планом выводился и отчет, в таком же порядке как и на всех остальных листах, т.е. на сводном получится №, наименование, дата отчета, отчет, ссылка на лист - в первой строке, а во второй - дата плана, план.