Ошибка пр обращении к макросу

[tae1980]

Похоже опять налетел на проблему типизированости данных. :(
Ни как не могу понять почему не вот эта конструкция выдает ошибку...

Sub Постобработка(Лист As Worksheets)
    'Постобработка.
    With Лист
        'Приводим ссылки на переменные в рабочее положение путем замены на листе "^п" на "=п".
        Cells.Replace What:="^п", Replacement:="=п", LookAt:=xlPart, SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, ReplaceFormat:=False
        With .PageSetup                            'Задаем отступы листа.
            .LeftMargin = Application.InchesToPoints(0.78740157480315)
            .RightMargin = Application.InchesToPoints(0.393700787401575)
            .TopMargin = Application.InchesToPoints(0.78740157480315)
            .BottomMargin = Application.InchesToPoints(0.78740157480315)
            .HeaderMargin = Application.InchesToPoints(0.511811023622047)
            .FooterMargin = Application.InchesToPoints(0.511811023622047)
        End With
    End With
    Участки.Activate                             'Делаем актиным лист Участки.
    Application.ScreenUpdating = True            'Включаем отображение изменений на экран.
End Sub

Sub test()
    tab_name = "Test"
    
    Application.ScreenUpdating = False            'Отключаем отображение текущих изменений на экран.
    Set Книга = Worksheets.Add                    'Создаем новый лист.
    Книга.Name = tab_name                         'Присваиваем ему имя.
    ActiveSheet.Move After:=Sheets(Sheets.Count)  'Перемещаем его в конец.
    Книга.Tab.ColorIndex = -4142                  'Обнуляем цвет ярлычка.
    Книга.Cells.ColumnWidth = 2                   'Ширина всех столбцов = 2.

'Что-то делаем
    
    Постобработка (Книга)
    
End Sub

[IgorGO]

предложу варианты:
1)
Sub Постобработка(Лист As Worksheets) заменить на Sub Постобработка(Лист As Worksheet) Worksheets - это коллекция а не лист. в процедуре test обьявить переменную Книга того же типа что и Лист - все покатит

2)
Sub Постобработка(Лист As Worksheets) заменить на Sub Постобработка(Лист)

[EducatedFool]

Попробуй так:

Sub Постобработка(Лист As Worksheet)    'Постобработка.
    With Лист
        .Cells.ColumnWidth = 2                   'Ширина всех столбцов = 2.
        'Приводим ссылки на переменные в рабочее положение путем замены на листе "^п" на "=п".
        .Cells.Replace What:="^п", Replacement:="=п", LookAt:=xlPart, SearchOrder:=xlByRows, MatchCase:=False, SearchFormat:=False, ReplaceFormat:=False
        With .PageSetup                            'Задаем отступы листа.
            .LeftMargin = Application.InchesToPoints(0.78740157480315)
            .RightMargin = Application.InchesToPoints(0.393700787401575)
            .TopMargin = Application.InchesToPoints(0.78740157480315)
            .BottomMargin = Application.InchesToPoints(0.78740157480315)
            .HeaderMargin = Application.InchesToPoints(0.511811023622047)
            .FooterMargin = Application.InchesToPoints(0.511811023622047)
        End With
    End With
End Sub

Sub test()
    Application.ScreenUpdating = False            'Отключаем отображение текущих изменений на экран.
    tab_name = "Test": Dim Книга As Worksheet
    Set Книга = Worksheets.Add(, Sheets(Sheets.Count))    'Создаем новый лист и Перемещаем его в конец.
    Книга.Name = tab_name                          'Присваиваем ему имя.

    'Что-то делаем
    Постобработка Книга
    Участки.Activate                             'Делаем актиным лист Участки.
End Sub

PS: Application.ScreenUpdating = True в конце макроса ставить необязательно (в отличии от Application.DisplayAlerts и т.п.)

[tae1980]

Сообщение от EducatedFool

Попробуй так:

Sub Постобработка(Лист As Worksheet)    'Постобработка.
......  
End Sub

PS: Application.ScreenUpdating = True в конце макроса ставить необязательно (в отличии от Application.DisplayAlerts и т.п.)

Спасибо! Все работает.