Выделить текст и посадить на него закладку

[ac1-caesar]

Уважаемые форумчане!

Пожалуйста, подскажите что делаю не так?
Есть таблица, в первом столбце данные.
Нужно добавить закладку на текст ячейки первого столбца, чтобы при создании перекрестной ссылки появлялся текст закладки.
Делаю так, но получается в закладку берется не текст ячейки, а вся ячейка.
И при создании перекрестной ссылки, выбрав "текст закладки", появляется вся ячейка.

Sub AddBookmarkToTaskCard()

Dim oTable As Word.Table
Dim iCellValue As String, BookmarkName As String
Dim iRowsCount As Integer, i As Long
On Error Resume Next

    For Each oTable In ThisDocument.Tables 'Просматриваем в каждой таблице
        If Left(oTable.Cell(1, 1).Range.Text, 11) = "TASK NUMBER" Then
            iRowsCount = oTable.Rows.Count 'Считаем количество строк в таблице
            For i = 2 To iRowsCount
                iCellValue = Replace(oTable.Cell(i, 1).Range.Text, vbCr, "") 'Убираем все переносы в ячейке
                iCellValue = Left(iCellValue, Len(iCellValue) - 2) 'Убираем два последних знака (непонятно почему появляются лишние знаки)
                oTable.Cell(i, 1).Range.Text = iCellValue 'Вставляем текст в ячейку
                BookmarkName = Replace(oTable.Cell(i, 1).Range.Text, "-", "_") 'Меняем знак "-" на "_" для имени закладки
                ActiveDocument.Bookmarks.Add Range:=oTable.Cell(i, 1).Range, Name:=BookmarkName 'Вставляем закладку на текст ячейки
            Next i
        End If
    Next oTable

End Sub

Тема открыта на Cyberforum

[Step_UA]

Видимо для диаппазона закладки нужно использовать только диппазон текста, без спецзнака

Sub AddBookmarkToTaskCard()

Dim oTable As Word.Table
Dim iCellValue As String, BookmarkName As String
Dim iRowsCount As Integer, i As Long
Dim R As Range
On Error Resume Next

    For Each oTable In ThisDocument.Tables 'Просматриваем в каждой таблице
        If Left(oTable.Cell(1, 1).Range.Text, 11) = "TASK NUMBER" Then
            iRowsCount = oTable.Rows.Count 'Считаем количество строк в таблице
            For i = 2 To iRowsCount
                Set R = oTable.Cell(i, 1).Range ' Диаппазон ячейки
                R.End = R.End - 1   ' диаппазон текста ячейки без спецсимвола
                iCellValue = Replace(R.Text, vbCr, "") 'Убираем все переносы в ячейке
                R.Text = iCellValue 'Вставляем текст
                BookmarkName = Replace(iCellValue, "-", "_") 'Меняем знак "-" на "_" для имени закладки
                ActiveDocument.Bookmarks.Add Range:=R, Name:=BookmarkName 'Вставляем закладку на текст ячейки
            Next i
        End If
    Next oTable

End Sub

[ac1-caesar]

Step_UA, вот спасибо, выручили!
А то уже и .Find прикручивал, результат тот же.

[Вождь]

Если планируется редактирование таблицы, что содержит закладки, то советую присмотреться к закладкам уже после правки. Не дружат закладки со вставкой / удалением строк, столбцов, ячеек.

[ac1-caesar]

Как раз с этим и столкнулся, предварительно были созданы закладки, после редактирования таблицы все исчезли. На ячейку получалось посадить закладку, а на текст ячейки подсказал Step_UA. Теперь норма!