Уменьшение шрифта пустых строк в документе

[Gilvanov]

Добрый день! Помогите, плиз, у меня следующая ситуация - есть документ из 60 листов, в котором нужно уменьшить шрифт пустых строк. Как можно это сделать не вручную?

[Sasha_Smirnov]

Если все пустые строки — это только знак абзаца ¶ (без пробелов), можно так:

Sub Макрос1()
Dim p As Word.Paragraph

    For Each p In ActiveDocument.Paragraphs
        With p.Range.Characters
                If .Count = 1 Then      'если абзац пуст (только 1 знак: абзац)
                    .Last.Font.Size = 6 'высота (кегль) шрифта
'                Else
'                    MsgBox "Этот абзац не пустой."
                End If
        End With
    Next

End Sub

Пробуйте.

[Скрипт]

Gilvanov, выложите документ Word с примерными данными и на основе этого документа поясните, что должен сделать макрос.

[Gilvanov]

Только добрался до дома. Выкладываю страницу файла.
В документ вставлен список балансовых счетов. Между абзацев остались пустые строки, вот у них и нужно уменьшить шрифт.

[Gilvanov]

Sasha_Smirnov, спасибо большое Все сработало как надо.
Скрипт спасибо за отзывчивость.

[Скрипт]

Макрос работает с таблицей, в которой находится курсор.
Если код будет медленно работать, то можно сначала перейти в режим "Черновик" (в Word 2010 в правом нижнем углу есть кнопки для выбора режима). Если вручную неудобно переходить, то можно добавить строку в код, которая будет это делать автоматически. А затем можно обратно возвращаться в нужный режим.

Sub Procedure_1()

    Dim myTable As Word.Table
    Dim i As Long
    
    '1. Даём таблице, в которой находится курсор, имя "myTable".
        'Через это имя будем обращаться к таблице.
    Set myTable = Selection.Tables(1)

    'С помощью цикла с переменной "i" просматриваем все строки в таблице.
    For i = 1 To myTable.Rows.Count Step 1
        
        '2. Смотрим, сколько символов в строке таблицы.
        'myTable.Rows(i).Range.Text - это текст во всей строке таблицы.
        'С помощью "Len" узнаём сколько символов в строке.
            'В каждой ячейке таблицы всегда есть два символа:
                '1) один символ видно, если включен режим отображения
                    'непечатаемых символов. Этот символ в виде кружка.
                    'Порядковый номер в ANSI-таблице 13;
                '2) второй символ вообще никогда не видно.
                    'Порядковый номер в ANSI-таблице 7;
        'myTable.Rows(i).Cells.Count - количество символов в ячейке.
        '+ 2, т.к. в конце каждой строки есть ещё два символа, как и в ячейке.
        'Если в строке только специальные символы, то значит, что строка пустая.
        If Len(myTable.Rows(i).Range.Text) = myTable.Rows(i).Cells.Count * 2 + 2 Then
            '3. Изменяем размер шрифта в строке.
            myTable.Rows(i).Range.Font.Size = 6
            '4. Изменяем высоту строки.
            'wdRowHeightExactly - это "точно".
            myTable.Rows(i).HeightRule = wdRowHeightExactly
            'CentimetersToPoints(0.2) - в скобках размеры указаны в сантиметрах.
            myTable.Rows(i).Height = Application.CentimetersToPoints(0.2)
        End If
    Next i

End Sub

Примечание

Код может не будет работать, если в таблице будут объединённые ячейки.