простейшее оконное приложение

[sergej735]

Я хочу создать простейшее оконное приложение.
Но не знаю как это можно сделать, помогите пожалуйста.

[Пепел Феникса]

http://tinyurl.com/69sbgxo
тут достаточно инфы.

[R71MT]

Скачай FASM, там есть готовые шаблоны. Для ознакомления в полне достаточно. Так-же, можно научиться и в WinAsm Studio, у него тоже есть готовые решения...

[*PB*]

Сообщение от sergej735

Я хочу создать простейшее оконное приложение.
Но не знаю как это можно сделать, помогите пожалуйста.

Не сложная, оконная программа на WinAPI.

Procedure WindowCallback(hWnd, Msg, wParam, lParam)
  Shared hButton
  
  Select Msg
    Case #WM_COMMAND
       If hButton = lParam
         MessageBox_(hWnd,"Ну что ж за день сегодня такой?"+Chr(10)+"Все меня закликали бедную!","Бедная я кнопко!",64)
       EndIf
    Case #WM_CLOSE 
      DestroyWindow_(hWnd) 
    Case #WM_DESTROY 
      PostQuitMessage_(0) : Result  = 0 
    Default 
      Result  = DefWindowProc_(hWnd, Msg, wParam, lParam) 
  EndSelect 
  
  ProcedureReturn Result 
EndProcedure  
 
InitCommonControls_()
DefaultFont = GetStockObject_(#DEFAULT_GUI_FONT)
 
WindowClass.s    = "PureBasic_Win" 
wc.WNDCLASSEX 
wc\cbsize        = SizeOf(WNDCLASSEX) 
wc\lpfnWndProc   = @WindowCallback() 
wc\hCursor       = LoadCursor_(0, #IDC_ARROW) 
wc\hbrBackground = #COLOR_WINDOW
wc\lpszClassName = @WindowClass 
RegisterClassEx_(@wc) 
 
Win_x=GetSystemMetrics_(#SM_CXSCREEN)/2-100
Win_y=GetSystemMetrics_(#SM_CYSCREEN)/2-50
 
hWndMain  = CreateWindowEx_(0, WindowClass, "Мелкая прога API", #WS_SYSMENU | #WS_MINIMIZEBOX, Win_x, Win_y, 200, 120, 0, 0, 0, 0)
 
Text.s="Бинарник этой проги довольно мелкий и не требует дополнительных DLL для своей работы"
hText=CreateWindowEx_(0,"Static", Text, #WS_CHILD | #WS_VISIBLE, 10,10,180,54, hWndMain, 0, 0, 0)
SendMessage_(hText, #WM_SETFONT, DefaultFont, 1)
 
hButton=CreateWindowEx_(0, "Button", "Типа кнопко", #WS_CHILD | #WS_VISIBLE, 100,64,80,24, hWndMain, 0, 0, 0) 
SendMessage_(hButton, #WM_SETFONT, DefaultFont, 1)
 
 
ShowWindow_(hWndMain,  #SW_SHOWDEFAULT) 
UpdateWindow_(hWndMain); 
 
While GetMessage_(msg.MSG, #Null, 0, 0 ) 
  TranslateMessage_(msg) 
  DispatchMessage_(msg) 
Wend
End

Размер скомпилированной программы - 4 КБ.
Скачать http://programmersforum.ru/attachmen...7&d=1306252886

Если это показалось сложным, то вот то же самое, но без явного использования WinAPI

OpenWindow(0,0,0,200,94,"Мелкая прога",#PB_Window_MinimizeGadget|#PB_Window_ScreenCentered)
CreateGadgetList(WindowID(0))
Text.s="Бинарник этой проги довольно мелкий и не требует дополнительных DLL для своей работы"
TextGadget(0,10,10,180,54,Text)
ButtonGadget(2,100,64,80,24,"Типа кнопко")

Repeat
  Event = WaitWindowEvent()
  If Event = #PB_Event_Gadget
    If EventGadget() = 2
      MessageRequester("Бедная я кнопко!", "Ну что ж за день сегодня такой?"+Chr(10)+"Все меня закликали бедную!")
    EndIf
  EndIf
Until Event = #PB_Event_CloseWindow

Размер исполняемого файла - 15 КБ.
Скачать http://programmersforum.ru/attachmen...9&d=1306272271