Посчитать количество битов в состоянии 0 для каждого символа.

[7in]

vadimych, мы нули считаем, а не единицы, поэтому нужна

[waleri]

Можно заинвертировать и считать единицы...

[7in]

Сообщение от waleri

Можно заинвертировать и считать единицы...

Что заинвертировать?
shr al,1 + adc dx,0 считает единицы.
shr al,1 + cmc + adc dx,0 считает нули.
cmc - это инвертирование флага CF, нужно для нулей, для единиц ничего инвертировать не надо.
Если речь об этом, конечно

[Аватар]

Такой еще хитрый алгоритм без условных переходов есть. Не asm, но все прозрачно. Счиает единицы

var a,b,c: Byte;
...
    a:=b;                     //в b исходный байт
    c:=a and $55;
    a:=((a shr 1) and $55)+c;
    c:=a and $33;
    a:=((a shr 2) and $33)+c;
    c:=a and $0F;
    a:=((a shr 4) and $0F)+c; //результат в a

[waleri]

Сообщение от 7in

Что заинвертировать?

AL, чтоб экономить одну инстукцию в цикле, всегда считая единицы.

[7in]

waleri, это да!

Аватар, огонь!
Перевёл в asm:

  ; исходное число в al (если надо считать нули, пишем здесь not al)
  mov ah,al
  and ah,55h  ; ah=al and 55h
  shr al,1
  and al,55h
  add al,ah   ; al=((al shr 1) and 55h)+ah
  mov ah,al
  and ah,33h  ; ah=al and 33h
  shr al,2
  and al,33h
  add al,ah   ; al=((al shr 2) and 33h)+ah
  mov ah,al
  and ah,0Fh  ; ah=al and 0Fh
  shr al,4
  and al,0Fh
  add al,ah   ; al=((al shr 4) and 0Fh)+ah
  ; результат в al

Проверил на всех 256 числах - работает!

[7in]

Немного оптимизировал (на 3 байта)

; Подсчёт количества единичных битов в числе
; Вход: AL = число
; Выход: AL = результат (кол-во единичных битов)
Bit1Count proc
  ;not al  ; раскомментируйте эту строку, если нужно считать нули, а не единицы
  mov ah,55h
  and ah,al  ; ah=al and 55h
  shr al,1
  and al,55h
  add al,ah   ; al=((al shr 1) and 55h)+ah
  mov ah,33h
  and ah,al  ; ah=al and 33h
  shr al,2
  and al,33h
  add al,ah   ; al=((al shr 2) and 33h)+ah
  mov ah,0Fh
  and ah,al  ; ah=al and 0Fh
  shr al,4
  and al,0Fh
  add al,ah   ; al=((al shr 4) and 0Fh)+ah
  ret
Bit1Count endp

Вот двойная процедура:

;-------------------------------------------------------------------------------
; Подсчёт количества нулевых или единичных битов в числе (2 процедуры)
; Вход: AL = число
; Выход: AL = результат (кол-во битов)
; Изменяет регистр AH
;-------------------------------------------------------------------------------
; Подсчёт количества нулевых битов в числе
Bit0Count proc
  not al  ; считаем нули, а не единицы
;-------------------------------------------------------------------------------
; Подсчёт количества единичных битов в числе
Bit1Count proc
  mov ah,55h
  and ah,al  ; ah=al and 55h
  shr al,1
  and al,55h
  add al,ah   ; al=((al shr 1) and 55h)+ah
  mov ah,33h
  and ah,al  ; ah=al and 33h
  shr al,2
  and al,33h
  add al,ah   ; al=((al shr 2) and 33h)+ah
  mov ah,0Fh
  and ah,al  ; ah=al and 0Fh
  shr al,4
  and al,0Fh
  add al,ah   ; al=((al shr 4) and 0Fh)+ah
  ret
Bit1Count endp
Bit0Count endp

[vadimych]

А, нули, ну тогда пардон, недосмотрел. Хотя можно всё равно без cmc.

mov cx,8
mov dl,cl
mov al,1
@@:
shr al,1
sbb dl,0
loop @b

Как-то так.

[Son Of Pain]

Кстати, в новых процессорах никак не успокоящиеся чуваки из Интел запилили инструкцию, которая считает количество единиц в операнде. Можно ее использовать и вычитать результат из 8 )

[Mikl___]

7in,

1. если поискать на сайбере, то я там несколько вариантов подсчета бит приводил
   • Подсчитать количество единичных бит в числе
   • Посчитать количество нулевых битов в каждом элементе массива и вывести общее количество
   • Дан массив из 8 байт. Рассматривая его, как массив из 64 бит, посчитать количество единиц

   Сообщение от 7in

   мы нули считаем, а не единицы, поэтому нужна

   подсчитать количество единиц, а потом количество_нулей = количество_байт х 8 - количество_единиц
2. по поводу Хочу сделать универсальный "компилятор" вот готовое решение